arch/blackfin/kernel/vmlinux.lds.S

   1 /*
   2  * File:         arch/blackfin/kernel/vmlinux.lds.S
   3  * Based on:     none - original work
   4  * Author:
   5  *
   6  * Created:      Tue Sep 21 2004
   7  * Description:  Master linker script for blackfin architecture
   8  *
   9  * Modified:
  10  *               Copyright 2004-2007 Analog Devices Inc.
  11  *
  12  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  13  *
  14  * This program is free software; you can redistribute it and/or modify
  15  * it under the terms of the GNU General Public License as published by
  16  * the Free Software Foundation; either version 2 of the License, or
  17  * (at your option) any later version.
  18  *
  19  * This program is distributed in the hope that it will be useful,
  20  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  21  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22  * GNU General Public License for more details.
  23  *
  24  * You should have received a copy of the GNU General Public License
  25  * along with this program; if not, see the file COPYING, or write
  26  * to the Free Software Foundation, Inc.,
  27  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  28  */
  29
  30 #define VMLINUX_SYMBOL(_sym_) _##_sym_
  31
  32 #include <asm-generic/vmlinux.lds.h>
  33 #include <asm/mem_map.h>
  34 #include <asm/page.h>
  35 #include <asm/thread_info.h>
  36
  37 OUTPUT_FORMAT("elf32-bfin")
  38 ENTRY(__start)
  39 _jiffies = _jiffies_64;
  40
  41 SECTIONS
  42 {
  43         . = CONFIG_BOOT_LOAD;
  44         /* Neither the text, ro_data or bss section need to be aligned
  45          * So pack them back to back
  46          */
  47         .text :
  48         {
  49                 __text = .;
  50                 _text = .;
  51                 __stext = .;
  52                 TEXT_TEXT
  53                 SCHED_TEXT
  54                 LOCK_TEXT
  55                 KPROBES_TEXT
  56                 *(.text.*)
  57                 *(.fixup)
  58
  59                 . = ALIGN(16);
  60                 ___start___ex_table = .;
  61                 *(__ex_table)
  62                 ___stop___ex_table = .;
  63
  64                 __etext = .;
  65         }
  66
  67         /* Just in case the first read only is a 32-bit access */
  68         RO_DATA(4)
  69
  70         .bss :
  71         {
  72                 . = ALIGN(4);
  73                 ___bss_start = .;
  74                 *(.bss .bss.*)
  75                 *(COMMON)
  76                 ___bss_stop = .;
  77         }
  78
  79         .data :
  80         {
  81                 __sdata = .;
  82                 /* This gets done first, so the glob doesn't suck it in */
  83                 . = ALIGN(32);
  84                 *(.data.cacheline_aligned)
  85
  86 #if !L1_DATA_A_LENGTH
  87                 . = ALIGN(32);
  88                 *(.data_l1.cacheline_aligned)
  89 #endif
  90
  91                 DATA_DATA
  92                 *(.data.*)
  93                 CONSTRUCTORS
  94
  95                 /* make sure the init_task is aligned to the
  96                  * kernel thread size so we can locate the kernel
  97                  * stack properly and quickly.
  98                  */
  99                 . = ALIGN(THREAD_SIZE);
 100                 *(.init_task.data)
 101
 102                 __edata = .;
 103         }
 104
 105         /* The init section should be last, so when we free it, it goes into
 106          * the general memory pool, and (hopefully) will decrease fragmentation
 107          * a tiny bit. The init section has a _requirement_ that it be
 108          * PAGE_SIZE aligned
 109          */
 110         . = ALIGN(PAGE_SIZE);
 111         ___init_begin = .;
 112
 113         .init.text :
 114         {
 115                 . = ALIGN(PAGE_SIZE);
 116                 __sinittext = .;
 117                 INIT_TEXT
 118                 __einittext = .;
 119         }
 120         .init.data :
 121         {
 122                 . = ALIGN(16);
 123                 INIT_DATA
 124         }
 125         .init.setup :
 126         {
 127                 . = ALIGN(16);
 128                 ___setup_start = .;
 129                 *(.init.setup)
 130                 ___setup_end = .;
 131         }
 132         .initcall.init :
 133         {
 134                 ___initcall_start = .;
 135                 INITCALLS
 136                 ___initcall_end = .;
 137         }
 138         .con_initcall.init :
 139         {
 140                 ___con_initcall_start = .;
 141                 *(.con_initcall.init)
 142                 ___con_initcall_end = .;
 143         }
 144         SECURITY_INIT
 145         .init.ramfs :
 146         {
 147                 . = ALIGN(4);
 148                 ___initramfs_start = .;
 149                 *(.init.ramfs)
 150                 ___initramfs_end = .;
 151         }
 152
 153         __l1_lma_start = .;
 154
 155 #if L1_CODE_LENGTH
 156 # define LDS_L1_CODE *(.l1.text)
 157 #else
 158 # define LDS_L1_CODE
 159 #endif
 160         .text_l1 L1_CODE_START : AT(LOADADDR(.init.ramfs) + SIZEOF(.init.ramfs))
 161         {
 162                 . = ALIGN(4);
 163                 __stext_l1 = .;
 164                 LDS_L1_CODE
 165                 . = ALIGN(4);
 166                 __etext_l1 = .;
 167         }
 168
 169 #if L1_DATA_A_LENGTH
 170 # define LDS_L1_A_DATA  *(.l1.data)
 171 # define LDS_L1_A_BSS   *(.l1.bss)
 172 # define LDS_L1_A_CACHE *(.data_l1.cacheline_aligned)
 173 #else
 174 # define LDS_L1_A_DATA
 175 # define LDS_L1_A_BSS
 176 # define LDS_L1_A_CACHE
 177 #endif
 178         .data_l1 L1_DATA_A_START : AT(LOADADDR(.text_l1) + SIZEOF(.text_l1))
 179         {
 180                 . = ALIGN(4);
 181                 __sdata_l1 = .;
 182                 LDS_L1_A_DATA
 183                 __edata_l1 = .;
 184
 185                 . = ALIGN(4);
 186                 __sbss_l1 = .;
 187                 LDS_L1_A_BSS
 188
 189                 . = ALIGN(32);
 190                 LDS_L1_A_CACHE
 191
 192                 . = ALIGN(4);
 193                 __ebss_l1 = .;
 194         }
 195
 196 #if L1_DATA_B_LENGTH
 197 # define LDS_L1_B_DATA  *(.l1.data.B)
 198 # define LDS_L1_B_BSS   *(.l1.bss.B)
 199 #else
 200 # define LDS_L1_B_DATA
 201 # define LDS_L1_B_BSS
 202 #endif
 203         .data_b_l1 L1_DATA_B_START : AT(LOADADDR(.data_l1) + SIZEOF(.data_l1))
 204         {
 205                 . = ALIGN(4);
 206                 __sdata_b_l1 = .;
 207                 LDS_L1_B_DATA
 208                 __edata_b_l1 = .;
 209
 210                 . = ALIGN(4);
 211                 __sbss_b_l1 = .;
 212                 LDS_L1_B_BSS
 213
 214                 . = ALIGN(4);
 215                 __ebss_b_l1 = .;
 216         }
 217
 218         /* Force trailing alignment of our init section so that when we
 219          * free our init memory, we don't leave behind a partial page.
 220          */
 221         . = LOADADDR(.data_b_l1) + SIZEOF(.data_b_l1);
 222         . = ALIGN(PAGE_SIZE);
 223         ___init_end = .;
 224
 225         __end =.;
 226
 227         STABS_DEBUG
 228
 229         DWARF_DEBUG
 230
 231         /DISCARD/ :
 232         {
 233                 EXIT_TEXT
 234                 EXIT_DATA
 235                 *(.exitcall.exit)
 236         }
 237 }