2 * setup.S Copyright (C) 1991, 1992 Linus Torvalds
4 * setup.s is responsible for getting the system data from the BIOS,
5 * and putting them into the appropriate places in system memory.
6 * both setup.s and system has been loaded by the bootblock.
8 * This code asks the bios for memory/disk/other parameters, and
9 * puts them in a "safe" place: 0x90000-0x901FF, ie where the
10 * boot-block used to be. It is then up to the protected mode
11 * system to read them from there before the area is overwritten
14 * Move PS/2 aux init code to psaux.c
15 * (troyer@saifr00.cfsat.Honeywell.COM) 03Oct92
17 * some changes and additional features by Christoph Niemann,
18 * March 1993/June 1994 (Christoph.Niemann@linux.org)
20 * add APM BIOS checking by Stephen Rothwell, May 1994
21 * (sfr@canb.auug.org.au)
23 * High load stuff, initrd support and position independency
24 * by Hans Lermen & Werner Almesberger, February 1996
25 * <lermen@elserv.ffm.fgan.de>, <almesber@lrc.epfl.ch>
27 * Video handling moved to video.S by Martin Mares, March 1996
28 * <mj@k332.feld.cvut.cz>
30 * Extended memory detection scheme retwiddled by orc@pell.chi.il.us (david
31 * parsons) to avoid loadlin confusion, July 1997
33 * Transcribed from Intel (as86) -> AT&T (gas) by Chris Noe, May 1999.
34 * <stiker@northlink.com>
36 * Fix to work around buggy BIOSes which don't use carry bit correctly
37 * and/or report extended memory in CX/DX for e801h memory size detection
38 * call. As a result the kernel got wrong figures. The int15/e801h docs
39 * from Ralf Brown interrupt list seem to indicate AX/BX should be used
40 * anyway. So to avoid breaking many machines (presumably there was a reason
41 * to orginally use CX/DX instead of AX/BX), we do a kludge to see
42 * if CX/DX have been changed in the e801 call and if so use AX/BX .
43 * Michael Miller, April 2001 <michaelm@mjmm.org>
45 * New A20 code ported from SYSLINUX by H. Peter Anvin. AMD Elan bugfixes
46 * by Robert Schwebel, December 2001 <robert@schwebel.de>
49 #include <asm/segment.h>
50 #include <linux/utsrelease.h>
51 #include <linux/compile.h>
56 /* Signature words to ensure LILO loaded us right */
60 INITSEG = DEF_INITSEG # 0x9000, we move boot here, out of the way
61 SYSSEG = DEF_SYSSEG # 0x1000, system loaded at 0x10000 (65536).
62 SETUPSEG = DEF_SETUPSEG # 0x9020, this is the current segment
63 # ... and the former contents of CS
65 DELTA_INITSEG = SETUPSEG - INITSEG # 0x0020
68 .globl begtext, begdata, begbss, endtext, enddata, endbss
81 # This is the setup header, and it must start at %cs:2 (old 0x9020:2)
83 .ascii "HdrS" # header signature
84 .word 0x0204 # header version number (>= 0x0105)
85 # or else old loadlin-1.5 will fail)
86 realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
87 start_sys_seg: .word SYSSEG
88 .word kernel_version # pointing to kernel version string
89 # above section of header is compatible
90 # with loadlin-1.5 (header v1.5). Don't
93 type_of_loader: .byte 0 # = 0, old one (LILO, Loadlin,
94 # Bootlin, SYSLX, bootsect...)
95 # See Documentation/i386/boot.txt for
98 # flags, unused bits must be zero (RFU) bit within loadflags
100 LOADED_HIGH = 1 # If set, the kernel is loaded high
101 CAN_USE_HEAP = 0x80 # If set, the loader also has set
102 # heap_end_ptr to tell how much
103 # space behind setup.S can be used for
105 # Only the loader knows what is free
106 #ifndef __BIG_KERNEL__
112 setup_move_size: .word 0x8000 # size to move, when setup is not
113 # loaded at 0x90000. We will move setup
114 # to 0x90000 then just before jumping
115 # into the kernel. However, only the
116 # loader knows how much data behind
117 # us also needs to be loaded.
119 code32_start: # here loaders can put a different
120 # start address for 32-bit code.
121 #ifndef __BIG_KERNEL__
122 .long 0x1000 # 0x1000 = default for zImage
124 .long 0x100000 # 0x100000 = default for big kernel
127 ramdisk_image: .long 0 # address of loaded ramdisk image
128 # Here the loader puts the 32-bit
129 # address where it loaded the image.
130 # This only will be read by the kernel.
132 ramdisk_size: .long 0 # its size in bytes
137 heap_end_ptr: .word modelist+1024 # (Header version 0x0201 or later)
138 # space from here (exclusive) down to
139 # end of setup code can be used by setup
140 # for local heap purposes.
143 cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
144 # If nonzero, a 32-bit pointer
145 # to the kernel command line.
146 # The command line should be
147 # located between the start of
148 # setup and the end of low
149 # memory (0xa0000), or it may
150 # get overwritten before it
151 # gets read. If this field is
152 # used, there is no longer
153 # anything magical about the
154 # 0x90000 segment; the setup
155 # can be located anywhere in
156 # low memory 0x10000 or higher.
158 ramdisk_max: .long (-__PAGE_OFFSET-(512 << 20)-1) & 0x7fffffff
159 # (Header version 0x0203 or later)
160 # The highest safe address for
161 # the contents of an initrd
163 trampoline: call start_of_setup
165 # The offset at this point is 0x240
166 .space (0xeff-0x240+1) # E820 & EDD space (ending at 0xeff)
167 # End of setup header #####################################################
170 # Bootlin depends on this being done early
175 #ifdef SAFE_RESET_DISK_CONTROLLER
176 # Reset the disk controller.
182 # Set %ds = %cs, we know that SETUPSEG = %cs at this point
183 movw %cs, %ax # aka SETUPSEG
185 # Check signature at end of setup
186 cmpw $SIG1, setup_sig1
189 cmpw $SIG2, setup_sig2
194 # Routine to print asciiz string at ds:si
206 prtsp2: call prtspc # Print double space
207 prtspc: movb $0x20, %al # Print single space (note: fall-thru)
209 # Part of above routine, this one just prints ascii al
220 beep: movb $0x07, %al
223 no_sig_mess: .string "No setup signature found ..."
228 # We now have to find the rest of the setup code/data
230 movw %cs, %ax # SETUPSEG
231 subw $DELTA_INITSEG, %ax # INITSEG
234 movb (497), %bl # get setup sect from bootsect
235 subw $4, %bx # LILO loads 4 sectors of setup
236 shlw $8, %bx # convert to words (1sect=2^8 words)
238 shrw $3, %bx # convert to segment
240 movw %bx, %cs:start_sys_seg
241 # Move rest of setup code/data to here
242 movw $2048, %di # four sectors loaded by LILO
250 movw %cs, %ax # aka SETUPSEG
252 cmpw $SIG1, setup_sig1
255 cmpw $SIG2, setup_sig2
269 movw %cs, %ax # aka SETUPSEG
270 subw $DELTA_INITSEG, %ax # aka INITSEG
272 # Check if an old loader tries to load a big-kernel
273 testb $LOADED_HIGH, %cs:loadflags # Do we have a big kernel?
274 jz loader_ok # No, no danger for old loaders.
276 cmpb $0, %cs:type_of_loader # Do we have a loader that
278 jnz loader_ok # Yes, continue.
280 pushw %cs # No, we have an old loader,
282 lea loader_panic_mess, %si
287 loader_panic_mess: .string "Wrong loader, giving up..."
290 # Get memory size (extended mem, kB)
294 #ifndef STANDARD_MEMORY_BIOS_CALL
296 # Try three different memory detection schemes. First, try
297 # e820h, which lets us assemble a memory map, then try e801h,
298 # which returns a 32-bit memory size, and finally 88h, which
302 # the memory map from hell. e820h returns memory classified into
303 # a whole bunch of different types, and allows memory holes and
304 # everything. We scan through this memory map and build a list
305 # of the first 32 memory areas, which we return at [E820MAP].
306 # This is documented at http://www.acpi.info/, in the ACPI 2.0 specification.
308 #define SMAP 0x534d4150
311 xorl %ebx, %ebx # continuation counter
312 movw $E820MAP, %di # point into the whitelist
313 # so we can have the bios
314 # directly write into it.
317 movl $0x0000e820, %eax # e820, upper word zeroed
318 movl $SMAP, %edx # ascii 'SMAP'
319 movl $20, %ecx # size of the e820rec
320 pushw %ds # data record.
322 int $0x15 # make the call
323 jc bail820 # fall to e801 if it fails
325 cmpl $SMAP, %eax # check the return is `SMAP'
326 jne bail820 # fall to e801 if it fails
328 # cmpl $1, 16(%di) # is this usable memory?
331 # If this is usable memory, we save it by simply advancing %di by
335 movb (E820NR), %al # up to 128 entries
344 cmpl $0, %ebx # check to see if
345 jne jmpe820 # %ebx is set to EOF
350 # memory size is in 1k chunksizes, to avoid confusing loadlin.
351 # we store the 0xe801 memory size in a completely different place,
352 # because it will most likely be longer than 16 bits.
353 # (use 1e0 because that's what Larry Augustine uses in his
354 # alternative new memory detection scheme, and it's sensible
355 # to write everything into the same place.)
358 stc # fix to work around buggy
359 xorw %cx,%cx # BIOSes which don't clear/set
360 xorw %dx,%dx # carry on pass/error of
361 # e801h memory size call
362 # or merely pass cx,dx though
363 # without changing them.
368 cmpw $0x0, %cx # Kludge to handle BIOSes
369 jne e801usecxdx # which report their extended
370 cmpw $0x0, %dx # memory in AX/BX rather than
371 jne e801usecxdx # CX/DX. The spec I have read
372 movw %ax, %cx # seems to indicate AX/BX
373 movw %bx, %dx # are more reasonable anyway...
376 andl $0xffff, %edx # clear sign extend
377 shll $6, %edx # and go from 64k to 1k chunks
378 movl %edx, (0x1e0) # store extended memory size
379 andl $0xffff, %ecx # clear sign extend
380 addl %ecx, (0x1e0) # and add lower memory into
383 # Ye Olde Traditional Methode. Returns the memory size (up to 16mb or
384 # 64mb, depending on the bios) in ax.
392 # Set the keyboard repeat rate to the max
397 # Check for video adapter and its parameters and allow the
398 # user to browse video modes.
399 call video # NOTE: we need %ds pointing
406 movw %cs, %ax # aka SETUPSEG
407 subw $DELTA_INITSEG, %ax # aka INITSEG
425 # Check that there IS a hd1 :-)
435 movw %cs, %ax # aka SETUPSEG
436 subw $DELTA_INITSEG, %ax # aka INITSEG
445 # check for Micro Channel (MCA) bus
446 movw %cs, %ax # aka SETUPSEG
447 subw $DELTA_INITSEG, %ax # aka INITSEG
450 movw %ax, (0xa0) # set table length to 0
453 int $0x15 # moves feature table to es:bx
459 movw %cs, %ax # aka SETUPSEG
460 subw $DELTA_INITSEG, %ax # aka INITSEG
465 addw $2, %cx # table length is a short
469 movw $0x10, %cx # we keep only first 16 bytes
475 #ifdef CONFIG_X86_VOYAGER
476 movb $0xff, 0x40 # flag on config found
479 int $0x15 # put voyager config info at es:di
481 movw $0x40, %si # place voyager info in apm table
493 # Check for PS/2 pointing device
494 movw %cs, %ax # aka SETUPSEG
495 subw $DELTA_INITSEG, %ax # aka INITSEG
497 movb $0, (0x1ff) # default is no pointing device
498 int $0x11 # int 0x11: equipment list
499 testb $0x04, %al # check if mouse installed
502 movb $0xAA, (0x1ff) # device present
505 #if defined(CONFIG_X86_SPEEDSTEP_SMI) || defined(CONFIG_X86_SPEEDSTEP_SMI_MODULE)
506 movl $0x0000E980, %eax # IST Support
507 movl $0x47534943, %edx # Request value
516 #if defined(CONFIG_APM) || defined(CONFIG_APM_MODULE)
517 # Then check for an APM BIOS...
518 # %ds points to the bootsector
519 movw $0, 0x40 # version = 0 means no APM BIOS
520 movw $0x05300, %ax # APM BIOS installation check
523 jc done_apm_bios # Nope, no APM BIOS
525 cmpw $0x0504d, %bx # Check for "PM" signature
526 jne done_apm_bios # No signature, no APM BIOS
528 andw $0x02, %cx # Is 32 bit supported?
529 je done_apm_bios # No 32-bit, no (good) APM BIOS
531 movw $0x05304, %ax # Disconnect first just in case
533 int $0x15 # ignore return code
534 movw $0x05303, %ax # 32 bit connect
536 xorw %cx, %cx # paranoia :-)
538 xorl %esi, %esi # ...
541 jc no_32_apm_bios # Ack, error.
543 movw %ax, (66) # BIOS code segment
544 movl %ebx, (68) # BIOS entry point offset
545 movw %cx, (72) # BIOS 16 bit code segment
546 movw %dx, (74) # BIOS data segment
547 movl %esi, (78) # BIOS code segment lengths
548 movw %di, (82) # BIOS data segment length
549 # Redo the installation check as the 32 bit connect
550 # modifies the flags returned on some BIOSs
551 movw $0x05300, %ax # APM BIOS installation check
553 xorw %cx, %cx # paranoia
555 jc apm_disconnect # error -> shouldn't happen
557 cmpw $0x0504d, %bx # check for "PM" signature
558 jne apm_disconnect # no sig -> shouldn't happen
560 movw %ax, (64) # record the APM BIOS version
561 movw %cx, (76) # and flags
564 apm_disconnect: # Tidy up
565 movw $0x05304, %ax # Disconnect
567 int $0x15 # ignore return code
572 andw $0xfffd, (76) # remove 32 bit support bit
578 # Now we want to move to protected mode ...
579 cmpw $0, %cs:realmode_swtch
582 lcall *%cs:realmode_swtch
591 # Now we move the system to its rightful place ... but we check if we have a
592 # big-kernel. In that case we *must* not move it ...
593 testb $LOADED_HIGH, %cs:loadflags
594 jz do_move0 # .. then we have a normal low
596 # .. or else we have a high
598 jmp end_move # ... and we skip moving
601 movw $0x100, %ax # start of destination segment
602 movw %cs, %bp # aka SETUPSEG
603 subw $DELTA_INITSEG, %bp # aka INITSEG
604 movw %cs:start_sys_seg, %bx # start of source segment
607 movw %ax, %es # destination segment
608 incb %ah # instead of add ax,#0x100
609 movw %bx, %ds # source segment
616 cmpw %bp, %bx # assume start_sys_seg > 0x200,
617 # so we will perhaps read one
618 # page more than needed, but
619 # never overwrite INITSEG
620 # because destination is a
621 # minimum one page below source
625 # then we load the segment descriptors
626 movw %cs, %ax # aka SETUPSEG
629 # Check whether we need to be downward compatible with version <=201
630 cmpl $0, cmd_line_ptr
631 jne end_move_self # loader uses version >=202 features
632 cmpb $0x20, type_of_loader
633 je end_move_self # bootsect loader, we know of it
635 # Boot loader doesnt support boot protocol version 2.02.
636 # If we have our code not at 0x90000, we need to move it there now.
637 # We also then need to move the params behind it (commandline)
638 # Because we would overwrite the code on the current IP, we move
639 # it in two steps, jumping high after the first one.
644 cli # make sure we really have
645 # interrupts disabled !
646 # because after this the stack
648 subw $DELTA_INITSEG, %ax # aka INITSEG
654 subw %ax, %dx # this will go into %ss after
658 movw $INITSEG, %ax # real INITSEG
660 movw %cs:setup_move_size, %cx
661 std # we have to move up, so we use
662 # direction down because the
667 subw $move_self_here+0x200, %cx
670 ljmp $SETUPSEG, $move_self_here
673 movw $move_self_here+0x200, %cx
679 end_move_self: # now we are at the right place
682 # Enable A20. This is at the very best an annoying procedure.
683 # A20 code ported from SYSLINUX 1.52-1.63 by H. Peter Anvin.
684 # AMD Elan bug fix by Robert Schwebel.
687 #if defined(CONFIG_X86_ELAN)
688 movb $0x02, %al # alternate A20 gate
689 outb %al, $0x92 # this works on SC410/SC520
697 A20_TEST_LOOPS = 32 # Iterations per wait
698 A20_ENABLE_LOOPS = 255 # Total loops to try
701 #ifndef CONFIG_X86_VOYAGER
704 # First, see if we are on a system with no A20 gate.
709 # Next, try the BIOS (INT 0x15, AX=0x2401)
712 pushfl # Be paranoid about flags
719 # Try enabling A20 through the keyboard controller
720 #endif /* CONFIG_X86_VOYAGER */
724 #ifndef CONFIG_X86_VOYAGER
725 call a20_test # Just in case the BIOS worked
726 jnz a20_done # but had a delayed reaction.
729 movb $0xD1, %al # command write
733 movb $0xDF, %al # A20 on
737 #ifndef CONFIG_X86_VOYAGER
738 # Wait until a20 really *is* enabled; it can take a fair amount of
739 # time on certain systems; Toshiba Tecras are known to have this
746 loop a20_kbc_wait_loop
748 # Final attempt: use "configuration port A"
750 inb $0x92, %al # Configuration Port A
751 orb $0x02, %al # "fast A20" version
752 andb $0xFE, %al # don't accidentally reset
755 # Wait for configuration port A to take effect
761 loop a20_fast_wait_loop
763 # A20 is still not responding. Try frobbing it again.
768 movw $a20_err_msg, %si
776 .byte A20_ENABLE_LOOPS
779 .ascii "linux: fatal error: A20 gate not responding!"
782 # If we get here, all is good
785 #endif /* CONFIG_X86_VOYAGER */
786 # set up gdt and idt and 32bit start address
787 lidt idt_48 # load idt with 0,0
788 xorl %eax, %eax # Compute gdt_base
789 movw %ds, %ax # (Convert %ds:gdt to a linear ptr)
793 movl %eax, (gdt_48+2)
794 lgdt gdt_48 # load gdt with whatever is
797 # make sure any possible coprocessor is properly reset..
805 # well, that went ok, I hope. Now we mask all interrupts - the rest
806 # is done in init_IRQ().
807 movb $0xFF, %al # mask all interrupts for now
811 movb $0xFB, %al # mask all irq's but irq2 which
812 outb %al, $0x21 # is cascaded
814 # Well, that certainly wasn't fun :-(. Hopefully it works, and we don't
815 # need no steenking BIOS anyway (except for the initial loading :-).
816 # The BIOS-routine wants lots of unnecessary data, and it's less
817 # "interesting" anyway. This is how REAL programmers do it.
819 # Well, now's the time to actually move into protected mode. To make
820 # things as simple as possible, we do no register set-up or anything,
821 # we let the gnu-compiled 32-bit programs do that. We just jump to
822 # absolute address 0x1000 (or the loader supplied one),
823 # in 32-bit protected mode.
825 # Note that the short jump isn't strictly needed, although there are
826 # reasons why it might be a good idea. It won't hurt in any case.
827 movw $1, %ax # protected mode (PE) bit
828 lmsw %ax # This is it!
832 xorw %bx, %bx # Flag to indicate a boot
833 xorl %esi, %esi # Pointer to real-mode code
835 subw $DELTA_INITSEG, %si
836 shll $4, %esi # Convert to 32-bit pointer
838 # jump to startup_32 in arch/i386/boot/compressed/head.S
840 # NOTE: For high loaded big kernels we need a
841 # jmpi 0x100000,__BOOT_CS
843 # but we yet haven't reloaded the CS register, so the default size
844 # of the target offset still is 16 bit.
845 # However, using an operand prefix (0x66), the CPU will properly
846 # take our 48 bit far pointer. (INTeL 80386 Programmer's Reference
847 # Manual, Mixing 16-bit and 32-bit code, page 16-6)
849 .byte 0x66, 0xea # prefix + jmpi-opcode
850 code32: .long startup_32 # will be set to %cs+startup_32
854 movl $(__BOOT_DS), %eax
862 1: incl %eax # check that A20 really IS enabled
863 movl %eax, 0x00000000 # loop forever if it isn't
864 cmpl %eax, 0x00100000
867 # Jump to the 32bit entry point
868 jmpl *(code32_start - start + (DELTA_INITSEG << 4))(%esi)
871 # Here's a bunch of information about your current kernel..
872 kernel_version: .ascii UTS_RELEASE
874 .ascii LINUX_COMPILE_BY
876 .ascii LINUX_COMPILE_HOST
881 # This is the default real mode switch routine.
882 # to be called just before protected mode transition
884 cli # no interrupts allowed !
885 movb $0x80, %al # disable NMI for bootup
891 #ifndef CONFIG_X86_VOYAGER
892 # This routine tests whether or not A20 is enabled. If so, it
895 # The memory address used, 0x200, is the int $0x80 vector, which
898 A20_TEST_ADDR = 4*0x80
904 movw %cx, %fs # Low memory
906 movw %cx, %gs # High memory area
907 movw $A20_TEST_LOOPS, %cx
908 movw %fs:(A20_TEST_ADDR), %ax
912 movw %ax, %fs:(A20_TEST_ADDR)
913 call delay # Serialize and make delay constant
914 cmpw %gs:(A20_TEST_ADDR+0x10), %ax
917 popw %fs:(A20_TEST_ADDR)
922 #endif /* CONFIG_X86_VOYAGER */
924 # This routine checks that the keyboard command queue is empty
925 # (after emptying the output buffers)
927 # Some machines have delusions that the keyboard buffer is always full
928 # with no keyboard attached...
930 # If there is no keyboard controller, we will usually get 0xff
931 # to all the reads. With each IO taking a microsecond and
932 # a timeout of 100,000 iterations, this can take about half a
933 # second ("delay" == outb to port 0x80). That should be ok,
934 # and should also be plenty of time for a real keyboard controller
944 jz empty_8042_end_loop
948 inb $0x64, %al # 8042 status port
949 testb $1, %al # output buffer?
953 inb $0x60, %al # read it
957 testb $2, %al # is input buffer full?
958 jnz empty_8042_loop # yes - loop
963 # Read the cmos clock. Return the seconds in al
968 movb %dh, %al # %dh contains the seconds
977 # Delay is needed after doing I/O
984 # NOTE: The intel manual says gdt should be sixteen bytes aligned for
985 # efficiency reasons. However, there are machines which are known not
986 # to boot with misaligned GDTs, so alter this at your peril! If you alter
987 # GDT_ENTRY_BOOT_CS (in asm/segment.h) remember to leave at least two
988 # empty GDT entries (one for NULL and one reserved).
990 # NOTE: On some CPUs, the GDT must be 8 byte aligned. This is
991 # true for the Voyager Quad CPU card which will not boot without
992 # This directive. 16 byte aligment is recommended by intel.
996 .fill GDT_ENTRY_BOOT_CS,8,0
998 .word 0xFFFF # 4Gb - (0x100000*0x1000 = 4Gb)
999 .word 0 # base address = 0
1000 .word 0x9A00 # code read/exec
1001 .word 0x00CF # granularity = 4096, 386
1002 # (+5th nibble of limit)
1004 .word 0xFFFF # 4Gb - (0x100000*0x1000 = 4Gb)
1005 .word 0 # base address = 0
1006 .word 0x9200 # data read/write
1007 .word 0x00CF # granularity = 4096, 386
1008 # (+5th nibble of limit)
1012 .word 0 # alignment byte
1014 .word 0 # idt limit = 0
1015 .word 0, 0 # idt base = 0L
1017 .word 0 # alignment byte
1019 .word gdt_end - gdt - 1 # gdt limit
1020 .word 0, 0 # gdt base (filled in later)
1022 # Include video setup & detection code
1026 # Setup signature -- must be last
1027 setup_sig1: .word SIG1
1028 setup_sig2: .word SIG2
1030 # After this point, there is some free space which is used by the video mode
1031 # handling code to store the temporary mode table (not used by the kernel).