arch/mips/kernel/entry.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1994 - 2000, 2001, 2003 Ralf Baechle
   7  * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
   8  * Copyright (C) 2001 MIPS Technologies, Inc.
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/asm.h>
  13 #include <asm/asmmacro.h>
  14 #include <asm/regdef.h>
  15 #include <asm/mipsregs.h>
  16 #include <asm/stackframe.h>
  17 #include <asm/isadep.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/war.h>
  20
  21 #ifdef CONFIG_PREEMPT
  22         .macro  preempt_stop
  23         .endm
  24 #else
  25         .macro  preempt_stop
  26         local_irq_disable
  27         .endm
  28 #define resume_kernel   restore_all
  29 #endif
  30
  31         .text
  32         .align  5
  33 FEXPORT(ret_from_exception)
  34         preempt_stop
  35 FEXPORT(ret_from_irq)
  36         LONG_L  t0, PT_STATUS(sp)               # returning to kernel mode?
  37         andi    t0, t0, KU_USER
  38         beqz    t0, resume_kernel
  39
  40 resume_userspace:
  41         local_irq_disable               # make sure we dont miss an
  42                                         # interrupt setting need_resched
  43                                         # between sampling and return
  44         LONG_L  a2, TI_FLAGS($28)       # current->work
  45         andi    t0, a2, _TIF_WORK_MASK  # (ignoring syscall_trace)
  46         bnez    t0, work_pending
  47         j       restore_all
  48
  49 #ifdef CONFIG_PREEMPT
  50 resume_kernel:
  51         lw      t0, TI_PRE_COUNT($28)
  52         bnez    t0, restore_all
  53 need_resched:
  54         LONG_L  t0, TI_FLAGS($28)
  55         andi    t1, t0, _TIF_NEED_RESCHED
  56         beqz    t1, restore_all
  57         LONG_L  t0, PT_STATUS(sp)               # Interrupts off?
  58         andi    t0, 1
  59         beqz    t0, restore_all
  60         li      t0, PREEMPT_ACTIVE
  61         sw      t0, TI_PRE_COUNT($28)
  62         local_irq_enable
  63         jal     schedule
  64         sw      zero, TI_PRE_COUNT($28)
  65         local_irq_disable
  66         b       need_resched
  67 #endif
  68
  69 FEXPORT(ret_from_fork)
  70         jal     schedule_tail           # a0 = task_t *prev
  71
  72 FEXPORT(syscall_exit)
  73         local_irq_disable               # make sure need_resched and
  74                                         # signals dont change between
  75                                         # sampling and return
  76         LONG_L  a2, TI_FLAGS($28)       # current->work
  77         li      t0, _TIF_ALLWORK_MASK
  78         and     t0, a2, t0
  79         bnez    t0, syscall_exit_work
  80
  81 FEXPORT(restore_all)                    # restore full frame
  82         .set    noat
  83         RESTORE_TEMP
  84         RESTORE_AT
  85         RESTORE_STATIC
  86 FEXPORT(restore_partial)                # restore partial frame
  87         RESTORE_SOME
  88         RESTORE_SP_AND_RET
  89         .set    at
  90
  91 work_pending:
  92         andi    t0, a2, _TIF_NEED_RESCHED # a2 is preloaded with TI_FLAGS
  93         beqz    t0, work_notifysig
  94 work_resched:
  95         jal     schedule
  96
  97         local_irq_disable               # make sure need_resched and
  98                                         # signals dont change between
  99                                         # sampling and return
 100         LONG_L  a2, TI_FLAGS($28)
 101         andi    t0, a2, _TIF_WORK_MASK  # is there any work to be done
 102                                         # other than syscall tracing?
 103         beqz    t0, restore_all
 104         andi    t0, a2, _TIF_NEED_RESCHED
 105         bnez    t0, work_resched
 106
 107 work_notifysig:                         # deal with pending signals and
 108                                         # notify-resume requests
 109         move    a0, sp
 110         li      a1, 0
 111         jal     do_notify_resume        # a2 already loaded
 112         j       restore_all
 113
 114 FEXPORT(syscall_exit_work_partial)
 115         SAVE_STATIC
 116 syscall_exit_work:
 117         li      t0, _TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT
 118         and     t0, a2                  # a2 is preloaded with TI_FLAGS
 119         beqz    t0, work_pending        # trace bit set?
 120         local_irq_enable                # could let do_syscall_trace()
 121                                         # call schedule() instead
 122         move    a0, sp
 123         li      a1, 1
 124         jal     do_syscall_trace
 125         b       resume_userspace
 126
 127 /*
 128  * Common spurious interrupt handler.
 129  */
 130 LEAF(spurious_interrupt)
 131         /*
 132          * Someone tried to fool us by sending an interrupt but we
 133          * couldn't find a cause for it.
 134          */
 135         PTR_LA  t1, irq_err_count
 136 #ifdef CONFIG_SMP
 137 1:      ll      t0, (t1)
 138         addiu   t0, 1
 139         sc      t0, (t1)
 140 #if R10000_LLSC_WAR
 141         beqzl   t0, 1b
 142 #else
 143         beqz    t0, 1b
 144 #endif
 145 #else
 146         lw      t0, (t1)
 147         addiu   t0, 1
 148         sw      t0, (t1)
 149 #endif
 150         j       ret_from_irq
 151         END(spurious_interrupt)