arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <asm/thread_info.h>
   6 #include <asm/cache.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 #ifdef CONFIG_CPU_LITTLE_ENDIAN
  10 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  11 #else
  12 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  13 #endif
  14 OUTPUT_ARCH(sh)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18   . = CONFIG_PAGE_OFFSET + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  19   _text = .;                    /* Text and read-only data */
  20   text = .;                     /* Text and read-only data */
  21   .empty_zero_page : {
  22         *(.empty_zero_page)
  23         } = 0
  24   .text : {
  25         *(.text.head)
  26         TEXT_TEXT
  27         SCHED_TEXT
  28         LOCK_TEXT
  29         *(.fixup)
  30         *(.gnu.warning)
  31         } = 0x0009
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   _etext = .;                   /* End of text section */
  39
  40   RODATA
  41
  42   BUG_TABLE
  43
  44   .data : {                     /* Data */
  45         DATA_DATA
  46         CONSTRUCTORS
  47         }
  48
  49   . = ALIGN(PAGE_SIZE);
  50   .data.page_aligned : { *(.data.page_aligned) }
  51   __nosave_begin = .;
  52   .data_nosave : { *(.data.nosave) }
  53   . = ALIGN(PAGE_SIZE);
  54   __nosave_end = .;
  55
  56   PERCPU(PAGE_SIZE)
  57
  58   . = ALIGN(L1_CACHE_BYTES);
  59   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  60
  61   _edata = .;                   /* End of data section */
  62
  63   . = ALIGN(THREAD_SIZE);               /* init_task */
  64   .data.init_task : { *(.data.init_task) }
  65
  66   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  67   __init_begin = .;
  68   _sinittext = .;
  69   .init.text : { *(.init.text) }
  70   _einittext = .;
  71   .init.data : { *(.init.data) }
  72   . = ALIGN(16);
  73   __setup_start = .;
  74   .init.setup : { *(.init.setup) }
  75   __setup_end = .;
  76   __initcall_start = .;
  77   .initcall.init : {
  78         INITCALLS
  79   }
  80   __initcall_end = .;
  81   __con_initcall_start = .;
  82   .con_initcall.init : { *(.con_initcall.init) }
  83   __con_initcall_end = .;
  84   SECURITY_INIT
  85
  86   /* .exit.text is discarded at runtime, not link time, to deal with
  87      references from .rodata */
  88   .exit.text : { *(.exit.text) }
  89   .exit.data : { *(.exit.data) }
  90
  91 #ifdef CONFIG_BLK_DEV_INITRD
  92   . = ALIGN(PAGE_SIZE);
  93
  94   __initramfs_start = .;
  95   .init.ramfs : { *(.init.ramfs) }
  96   __initramfs_end = .;
  97 #endif
  98
  99  . = ALIGN(4);
 100   __machvec_start = .;
 101   .machvec.init : { *(.machvec.init) }
 102   __machvec_end = .;
 103
 104   . = ALIGN(PAGE_SIZE);
 105   .bss : {
 106         __init_end = .;
 107         __bss_start = .;                /* BSS */
 108         *(.bss.page_aligned)
 109         *(.bss)
 110         . = ALIGN(4);
 111         _ebss = .;                      /* uClinux MTD sucks */
 112         _end = . ;
 113   }
 114
 115   /* When something in the kernel is NOT compiled as a module, the
 116    * module cleanup code and data are put into these segments.  Both
 117    * can then be thrown away, as cleanup code is never called unless
 118    * it's a module.
 119    */
 120   /DISCARD/ : {
 121         *(.exitcall.exit)
 122         }
 123
 124   STABS_DEBUG
 125
 126   DWARF_DEBUG
 127 }