arch/sh/kernel/vmlinux_64.lds.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * arch/sh5/vmlinux.lds.S
   7  *
   8  * ld script to make ST50 Linux kernel
   9  *
  10  * Copyright (C) 2000, 2001  Paolo Alberelli
  11  *
  12  * benedict.gaster@superh.com:   2nd May 2002
  13  *    Add definition of empty_zero_page to be the first page of kernel image.
  14  *
  15  * benedict.gaster@superh.com:   3rd May 2002
  16  *    Added support for ramdisk, removing statically linked romfs at the same time.
  17  *
  18  * lethal@linux-sh.org:          9th May 2003
  19  *    Kill off GLOBAL_NAME() usage and other CDC-isms.
  20  *
  21  * lethal@linux-sh.org:         19th May 2003
  22  *    Remove support for ancient toolchains.
  23  */
  24
  25 #include <asm/page.h>
  26 #include <asm/cache.h>
  27 #include <asm/thread_info.h>
  28
  29 #define LOAD_OFFSET     CONFIG_CACHED_MEMORY_OFFSET
  30 #include <asm-generic/vmlinux.lds.h>
  31
  32 OUTPUT_ARCH(sh:sh5)
  33
  34 #define C_PHYS(x) AT (ADDR(x) - LOAD_OFFSET)
  35
  36 ENTRY(__start)
  37 SECTIONS
  38 {
  39   . = CONFIG_CACHED_MEMORY_OFFSET + CONFIG_MEMORY_START + PAGE_SIZE;
  40   _text = .;                    /* Text and read-only data */
  41   text = .;                     /* Text and read-only data */
  42
  43   .empty_zero_page : C_PHYS(.empty_zero_page) {
  44         *(.empty_zero_page)
  45         } = 0
  46
  47   .text : C_PHYS(.text) {
  48         *(.text.head)
  49         TEXT_TEXT
  50         *(.text64)
  51         *(.text..SHmedia32)
  52         SCHED_TEXT
  53         LOCK_TEXT
  54         *(.fixup)
  55         *(.gnu.warning)
  56 #ifdef CONFIG_LITTLE_ENDIAN
  57         } = 0x6ff0fff0
  58 #else
  59         } = 0xf0fff06f
  60 #endif
  61
  62   /* We likely want __ex_table to be Cache Line aligned */
  63   . = ALIGN(L1_CACHE_BYTES);            /* Exception table */
  64   __start___ex_table = .;
  65   __ex_table : C_PHYS(__ex_table) { *(__ex_table) }
  66   __stop___ex_table = .;
  67
  68   _etext = .;                   /* End of text section */
  69
  70   NOTES
  71
  72   RODATA
  73
  74   .data : C_PHYS(.data) {                       /* Data */
  75         DATA_DATA
  76         CONSTRUCTORS
  77         }
  78
  79   . = ALIGN(PAGE_SIZE);
  80   .data.page_aligned : C_PHYS(.data.page_aligned) { *(.data.page_aligned) }
  81
  82   PERCPU(PAGE_SIZE)
  83
  84   . = ALIGN(L1_CACHE_BYTES);
  85   .data.cacheline_aligned : C_PHYS(.data.cacheline_aligned) { *(.data.cacheline_aligned) }
  86
  87   _edata = .;                   /* End of data section */
  88
  89   . = ALIGN(THREAD_SIZE);       /* init_task: structure size aligned */
  90   .data.init_task : C_PHYS(.data.init_task) { *(.data.init_task) }
  91
  92   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  93   __init_begin = .;
  94   _sinittext = .;
  95   .init.text : C_PHYS(.init.text) { *(.init.text) }
  96   _einittext = .;
  97   .init.data : C_PHYS(.init.data) { *(.init.data) }
  98   . = ALIGN(L1_CACHE_BYTES);    /* Better if Cache Line aligned */
  99   __setup_start = .;
 100   .init.setup : C_PHYS(.init.setup) { *(.init.setup) }
 101   __setup_end = .;
 102   __initcall_start = .;
 103   .initcall.init : C_PHYS(.initcall.init) {
 104         INITCALLS
 105   }
 106   __initcall_end = .;
 107   __con_initcall_start = .;
 108   .con_initcall.init : C_PHYS(.con_initcall.init) { *(.con_initcall.init) }
 109   __con_initcall_end = .;
 110   SECURITY_INIT
 111
 112 #ifdef CONFIG_BLK_DEV_INITRD
 113   __initramfs_start = .;
 114   .init.ramfs : C_PHYS(.init.ramfs) { *(.init.ramfs) }
 115   __initramfs_end = .;
 116 #endif
 117
 118   . = ALIGN(PAGE_SIZE);
 119   __init_end = .;
 120
 121   /* Align to the biggest single data representation, head and tail */
 122   . = ALIGN(8);
 123   __bss_start = .;              /* BSS */
 124   .bss : C_PHYS(.bss) {
 125         *(.bss)
 126         }
 127   . = ALIGN(8);
 128   _end = . ;
 129
 130   /* Sections to be discarded */
 131   /DISCARD/ : {
 132         *(.exit.text)
 133         *(.exit.data)
 134         *(.exitcall.exit)
 135         }
 136
 137   STABS_DEBUG
 138   DWARF_DEBUG
 139 }