arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54
  55         .code64
  56
  57 #ifndef CONFIG_PREEMPT
  58 #define retint_kernel retint_restore_args
  59 #endif
  60
  61 #ifdef CONFIG_PARAVIRT
  62 ENTRY(native_irq_enable_syscall_ret)
  63         movq    %gs:pda_oldrsp,%rsp
  64         swapgs
  65         sysretq
  66 #endif /* CONFIG_PARAVIRT */
  67
  68
  69 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  70 #ifdef CONFIG_TRACE_IRQFLAGS
  71         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  72         jnc  1f
  73         TRACE_IRQS_ON
  74 1:
  75 #endif
  76 .endm
  77
  78 /*
  79  * C code is not supposed to know about undefined top of stack. Every time
  80  * a C function with an pt_regs argument is called from the SYSCALL based
  81  * fast path FIXUP_TOP_OF_STACK is needed.
  82  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
  83  * manipulation.
  84  */
  85
  86         /* %rsp:at FRAMEEND */
  87         .macro FIXUP_TOP_OF_STACK tmp
  88         movq    %gs:pda_oldrsp,\tmp
  89         movq    \tmp,RSP(%rsp)
  90         movq    $__USER_DS,SS(%rsp)
  91         movq    $__USER_CS,CS(%rsp)
  92         movq    $-1,RCX(%rsp)
  93         movq    R11(%rsp),\tmp  /* get eflags */
  94         movq    \tmp,EFLAGS(%rsp)
  95         .endm
  96
  97         .macro RESTORE_TOP_OF_STACK tmp,offset=0
  98         movq   RSP-\offset(%rsp),\tmp
  99         movq   \tmp,%gs:pda_oldrsp
 100         movq   EFLAGS-\offset(%rsp),\tmp
 101         movq   \tmp,R11-\offset(%rsp)
 102         .endm
 103
 104         .macro FAKE_STACK_FRAME child_rip
 105         /* push in order ss, rsp, eflags, cs, rip */
 106         xorl %eax, %eax
 107         pushq %rax /* ss */
 108         CFI_ADJUST_CFA_OFFSET   8
 109         /*CFI_REL_OFFSET        ss,0*/
 110         pushq %rax /* rsp */
 111         CFI_ADJUST_CFA_OFFSET   8
 112         CFI_REL_OFFSET  rsp,0
 113         pushq $(1<<9) /* eflags - interrupts on */
 114         CFI_ADJUST_CFA_OFFSET   8
 115         /*CFI_REL_OFFSET        rflags,0*/
 116         pushq $__KERNEL_CS /* cs */
 117         CFI_ADJUST_CFA_OFFSET   8
 118         /*CFI_REL_OFFSET        cs,0*/
 119         pushq \child_rip /* rip */
 120         CFI_ADJUST_CFA_OFFSET   8
 121         CFI_REL_OFFSET  rip,0
 122         pushq   %rax /* orig rax */
 123         CFI_ADJUST_CFA_OFFSET   8
 124         .endm
 125
 126         .macro UNFAKE_STACK_FRAME
 127         addq $8*6, %rsp
 128         CFI_ADJUST_CFA_OFFSET   -(6*8)
 129         .endm
 130
 131         .macro  CFI_DEFAULT_STACK start=1
 132         .if \start
 133         CFI_STARTPROC   simple
 134         CFI_SIGNAL_FRAME
 135         CFI_DEF_CFA     rsp,SS+8
 136         .else
 137         CFI_DEF_CFA_OFFSET SS+8
 138         .endif
 139         CFI_REL_OFFSET  r15,R15
 140         CFI_REL_OFFSET  r14,R14
 141         CFI_REL_OFFSET  r13,R13
 142         CFI_REL_OFFSET  r12,R12
 143         CFI_REL_OFFSET  rbp,RBP
 144         CFI_REL_OFFSET  rbx,RBX
 145         CFI_REL_OFFSET  r11,R11
 146         CFI_REL_OFFSET  r10,R10
 147         CFI_REL_OFFSET  r9,R9
 148         CFI_REL_OFFSET  r8,R8
 149         CFI_REL_OFFSET  rax,RAX
 150         CFI_REL_OFFSET  rcx,RCX
 151         CFI_REL_OFFSET  rdx,RDX
 152         CFI_REL_OFFSET  rsi,RSI
 153         CFI_REL_OFFSET  rdi,RDI
 154         CFI_REL_OFFSET  rip,RIP
 155         /*CFI_REL_OFFSET        cs,CS*/
 156         /*CFI_REL_OFFSET        rflags,EFLAGS*/
 157         CFI_REL_OFFSET  rsp,RSP
 158         /*CFI_REL_OFFSET        ss,SS*/
 159         .endm
 160 /*
 161  * A newly forked process directly context switches into this.
 162  */
 163 /* rdi: prev */
 164 ENTRY(ret_from_fork)
 165         CFI_DEFAULT_STACK
 166         push kernel_eflags(%rip)
 167         CFI_ADJUST_CFA_OFFSET 4
 168         popf                            # reset kernel eflags
 169         CFI_ADJUST_CFA_OFFSET -4
 170         call schedule_tail
 171         GET_THREAD_INFO(%rcx)
 172         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT),threadinfo_flags(%rcx)
 173         jnz rff_trace
 174 rff_action:
 175         RESTORE_REST
 176         testl $3,CS-ARGOFFSET(%rsp)     # from kernel_thread?
 177         je   int_ret_from_sys_call
 178         testl $_TIF_IA32,threadinfo_flags(%rcx)
 179         jnz  int_ret_from_sys_call
 180         RESTORE_TOP_OF_STACK %rdi,ARGOFFSET
 181         jmp ret_from_sys_call
 182 rff_trace:
 183         movq %rsp,%rdi
 184         call syscall_trace_leave
 185         GET_THREAD_INFO(%rcx)
 186         jmp rff_action
 187         CFI_ENDPROC
 188 END(ret_from_fork)
 189
 190 /*
 191  * System call entry. Upto 6 arguments in registers are supported.
 192  *
 193  * SYSCALL does not save anything on the stack and does not change the
 194  * stack pointer.
 195  */
 196
 197 /*
 198  * Register setup:
 199  * rax  system call number
 200  * rdi  arg0
 201  * rcx  return address for syscall/sysret, C arg3
 202  * rsi  arg1
 203  * rdx  arg2
 204  * r10  arg3    (--> moved to rcx for C)
 205  * r8   arg4
 206  * r9   arg5
 207  * r11  eflags for syscall/sysret, temporary for C
 208  * r12-r15,rbp,rbx saved by C code, not touched.
 209  *
 210  * Interrupts are off on entry.
 211  * Only called from user space.
 212  *
 213  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 214  *      and report it properly in ps. Unfortunately we haven't.
 215  *
 216  * When user can change the frames always force IRET. That is because
 217  * it deals with uncanonical addresses better. SYSRET has trouble
 218  * with them due to bugs in both AMD and Intel CPUs.
 219  */
 220
 221 ENTRY(system_call)
 222         CFI_STARTPROC   simple
 223         CFI_SIGNAL_FRAME
 224         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 225         CFI_REGISTER    rip,rcx
 226         /*CFI_REGISTER  rflags,r11*/
 227         SWAPGS_UNSAFE_STACK
 228         /*
 229          * A hypervisor implementation might want to use a label
 230          * after the swapgs, so that it can do the swapgs
 231          * for the guest and jump here on syscall.
 232          */
 233 ENTRY(system_call_after_swapgs)
 234
 235         movq    %rsp,%gs:pda_oldrsp
 236         movq    %gs:pda_kernelstack,%rsp
 237         /*
 238          * No need to follow this irqs off/on section - it's straight
 239          * and short:
 240          */
 241         ENABLE_INTERRUPTS(CLBR_NONE)
 242         SAVE_ARGS 8,1
 243         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 244         movq  %rcx,RIP-ARGOFFSET(%rsp)
 245         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 246         GET_THREAD_INFO(%rcx)
 247         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%rcx)
 248         jnz tracesys
 249         cmpq $__NR_syscall_max,%rax
 250         ja badsys
 251         movq %r10,%rcx
 252         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 253         movq %rax,RAX-ARGOFFSET(%rsp)
 254 /*
 255  * Syscall return path ending with SYSRET (fast path)
 256  * Has incomplete stack frame and undefined top of stack.
 257  */
 258 ret_from_sys_call:
 259         movl $_TIF_ALLWORK_MASK,%edi
 260         /* edi: flagmask */
 261 sysret_check:
 262         LOCKDEP_SYS_EXIT
 263         GET_THREAD_INFO(%rcx)
 264         DISABLE_INTERRUPTS(CLBR_NONE)
 265         TRACE_IRQS_OFF
 266         movl threadinfo_flags(%rcx),%edx
 267         andl %edi,%edx
 268         jnz  sysret_careful
 269         CFI_REMEMBER_STATE
 270         /*
 271          * sysretq will re-enable interrupts:
 272          */
 273         TRACE_IRQS_ON
 274         movq RIP-ARGOFFSET(%rsp),%rcx
 275         CFI_REGISTER    rip,rcx
 276         RESTORE_ARGS 0,-ARG_SKIP,1
 277         /*CFI_REGISTER  rflags,r11*/
 278         ENABLE_INTERRUPTS_SYSCALL_RET
 279
 280         CFI_RESTORE_STATE
 281         /* Handle reschedules */
 282         /* edx: work, edi: workmask */
 283 sysret_careful:
 284         bt $TIF_NEED_RESCHED,%edx
 285         jnc sysret_signal
 286         TRACE_IRQS_ON
 287         ENABLE_INTERRUPTS(CLBR_NONE)
 288         pushq %rdi
 289         CFI_ADJUST_CFA_OFFSET 8
 290         call schedule
 291         popq  %rdi
 292         CFI_ADJUST_CFA_OFFSET -8
 293         jmp sysret_check
 294
 295         /* Handle a signal */
 296 sysret_signal:
 297         TRACE_IRQS_ON
 298         ENABLE_INTERRUPTS(CLBR_NONE)
 299         testl $_TIF_DO_NOTIFY_MASK,%edx
 300         jz    1f
 301
 302         /* Really a signal */
 303         /* edx: work flags (arg3) */
 304         leaq do_notify_resume(%rip),%rax
 305         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 306         xorl %esi,%esi # oldset -> arg2
 307         call ptregscall_common
 308 1:      movl $_TIF_NEED_RESCHED,%edi
 309         /* Use IRET because user could have changed frame. This
 310            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 311         DISABLE_INTERRUPTS(CLBR_NONE)
 312         TRACE_IRQS_OFF
 313         jmp int_with_check
 314
 315 badsys:
 316         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 317         jmp ret_from_sys_call
 318
 319         /* Do syscall tracing */
 320 tracesys:
 321         SAVE_REST
 322         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 323         FIXUP_TOP_OF_STACK %rdi
 324         movq %rsp,%rdi
 325         call syscall_trace_enter
 326         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 327         RESTORE_REST
 328         cmpq $__NR_syscall_max,%rax
 329         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 330         movq %r10,%rcx  /* fixup for C */
 331         call *sys_call_table(,%rax,8)
 332         movq %rax,RAX-ARGOFFSET(%rsp)
 333         /* Use IRET because user could have changed frame */
 334
 335 /*
 336  * Syscall return path ending with IRET.
 337  * Has correct top of stack, but partial stack frame.
 338  */
 339         .globl int_ret_from_sys_call
 340 int_ret_from_sys_call:
 341         DISABLE_INTERRUPTS(CLBR_NONE)
 342         TRACE_IRQS_OFF
 343         testl $3,CS-ARGOFFSET(%rsp)
 344         je retint_restore_args
 345         movl $_TIF_ALLWORK_MASK,%edi
 346         /* edi: mask to check */
 347 int_with_check:
 348         LOCKDEP_SYS_EXIT_IRQ
 349         GET_THREAD_INFO(%rcx)
 350         movl threadinfo_flags(%rcx),%edx
 351         andl %edi,%edx
 352         jnz   int_careful
 353         andl    $~TS_COMPAT,threadinfo_status(%rcx)
 354         jmp   retint_swapgs
 355
 356         /* Either reschedule or signal or syscall exit tracking needed. */
 357         /* First do a reschedule test. */
 358         /* edx: work, edi: workmask */
 359 int_careful:
 360         bt $TIF_NEED_RESCHED,%edx
 361         jnc  int_very_careful
 362         TRACE_IRQS_ON
 363         ENABLE_INTERRUPTS(CLBR_NONE)
 364         pushq %rdi
 365         CFI_ADJUST_CFA_OFFSET 8
 366         call schedule
 367         popq %rdi
 368         CFI_ADJUST_CFA_OFFSET -8
 369         DISABLE_INTERRUPTS(CLBR_NONE)
 370         TRACE_IRQS_OFF
 371         jmp int_with_check
 372
 373         /* handle signals and tracing -- both require a full stack frame */
 374 int_very_careful:
 375         TRACE_IRQS_ON
 376         ENABLE_INTERRUPTS(CLBR_NONE)
 377         SAVE_REST
 378         /* Check for syscall exit trace */
 379         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP),%edx
 380         jz int_signal
 381         pushq %rdi
 382         CFI_ADJUST_CFA_OFFSET 8
 383         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 384         call syscall_trace_leave
 385         popq %rdi
 386         CFI_ADJUST_CFA_OFFSET -8
 387         andl $~(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP),%edi
 388         jmp int_restore_rest
 389
 390 int_signal:
 391         testl $_TIF_DO_NOTIFY_MASK,%edx
 392         jz 1f
 393         movq %rsp,%rdi          # &ptregs -> arg1
 394         xorl %esi,%esi          # oldset -> arg2
 395         call do_notify_resume
 396 1:      movl $_TIF_NEED_RESCHED,%edi
 397 int_restore_rest:
 398         RESTORE_REST
 399         DISABLE_INTERRUPTS(CLBR_NONE)
 400         TRACE_IRQS_OFF
 401         jmp int_with_check
 402         CFI_ENDPROC
 403 END(system_call)
 404
 405 /*
 406  * Certain special system calls that need to save a complete full stack frame.
 407  */
 408
 409         .macro PTREGSCALL label,func,arg
 410         .globl \label
 411 \label:
 412         leaq    \func(%rip),%rax
 413         leaq    -ARGOFFSET+8(%rsp),\arg /* 8 for return address */
 414         jmp     ptregscall_common
 415 END(\label)
 416         .endm
 417
 418         CFI_STARTPROC
 419
 420         PTREGSCALL stub_clone, sys_clone, %r8
 421         PTREGSCALL stub_fork, sys_fork, %rdi
 422         PTREGSCALL stub_vfork, sys_vfork, %rdi
 423         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 424         PTREGSCALL stub_iopl, sys_iopl, %rsi
 425
 426 ENTRY(ptregscall_common)
 427         popq %r11
 428         CFI_ADJUST_CFA_OFFSET -8
 429         CFI_REGISTER rip, r11
 430         SAVE_REST
 431         movq %r11, %r15
 432         CFI_REGISTER rip, r15
 433         FIXUP_TOP_OF_STACK %r11
 434         call *%rax
 435         RESTORE_TOP_OF_STACK %r11
 436         movq %r15, %r11
 437         CFI_REGISTER rip, r11
 438         RESTORE_REST
 439         pushq %r11
 440         CFI_ADJUST_CFA_OFFSET 8
 441         CFI_REL_OFFSET rip, 0
 442         ret
 443         CFI_ENDPROC
 444 END(ptregscall_common)
 445
 446 ENTRY(stub_execve)
 447         CFI_STARTPROC
 448         popq %r11
 449         CFI_ADJUST_CFA_OFFSET -8
 450         CFI_REGISTER rip, r11
 451         SAVE_REST
 452         FIXUP_TOP_OF_STACK %r11
 453         movq %rsp, %rcx
 454         call sys_execve
 455         RESTORE_TOP_OF_STACK %r11
 456         movq %rax,RAX(%rsp)
 457         RESTORE_REST
 458         jmp int_ret_from_sys_call
 459         CFI_ENDPROC
 460 END(stub_execve)
 461
 462 /*
 463  * sigreturn is special because it needs to restore all registers on return.
 464  * This cannot be done with SYSRET, so use the IRET return path instead.
 465  */
 466 ENTRY(stub_rt_sigreturn)
 467         CFI_STARTPROC
 468         addq $8, %rsp
 469         CFI_ADJUST_CFA_OFFSET   -8
 470         SAVE_REST
 471         movq %rsp,%rdi
 472         FIXUP_TOP_OF_STACK %r11
 473         call sys_rt_sigreturn
 474         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 475         RESTORE_REST
 476         jmp int_ret_from_sys_call
 477         CFI_ENDPROC
 478 END(stub_rt_sigreturn)
 479
 480 /*
 481  * initial frame state for interrupts and exceptions
 482  */
 483         .macro _frame ref
 484         CFI_STARTPROC simple
 485         CFI_SIGNAL_FRAME
 486         CFI_DEF_CFA rsp,SS+8-\ref
 487         /*CFI_REL_OFFSET ss,SS-\ref*/
 488         CFI_REL_OFFSET rsp,RSP-\ref
 489         /*CFI_REL_OFFSET rflags,EFLAGS-\ref*/
 490         /*CFI_REL_OFFSET cs,CS-\ref*/
 491         CFI_REL_OFFSET rip,RIP-\ref
 492         .endm
 493
 494 /* initial frame state for interrupts (and exceptions without error code) */
 495 #define INTR_FRAME _frame RIP
 496 /* initial frame state for exceptions with error code (and interrupts with
 497    vector already pushed) */
 498 #define XCPT_FRAME _frame ORIG_RAX
 499
 500 /*
 501  * Interrupt entry/exit.
 502  *
 503  * Interrupt entry points save only callee clobbered registers in fast path.
 504  *
 505  * Entry runs with interrupts off.
 506  */
 507
 508 /* 0(%rsp): interrupt number */
 509         .macro interrupt func
 510         cld
 511         SAVE_ARGS
 512         leaq -ARGOFFSET(%rsp),%rdi      # arg1 for handler
 513         pushq %rbp
 514         CFI_ADJUST_CFA_OFFSET   8
 515         CFI_REL_OFFSET          rbp, 0
 516         movq %rsp,%rbp
 517         CFI_DEF_CFA_REGISTER    rbp
 518         testl $3,CS(%rdi)
 519         je 1f
 520         SWAPGS
 521         /* irqcount is used to check if a CPU is already on an interrupt
 522            stack or not. While this is essentially redundant with preempt_count
 523            it is a little cheaper to use a separate counter in the PDA
 524            (short of moving irq_enter into assembly, which would be too
 525             much work) */
 526 1:      incl    %gs:pda_irqcount
 527         cmoveq %gs:pda_irqstackptr,%rsp
 528         push    %rbp                    # backlink for old unwinder
 529         /*
 530          * We entered an interrupt context - irqs are off:
 531          */
 532         TRACE_IRQS_OFF
 533         call \func
 534         .endm
 535
 536 ENTRY(common_interrupt)
 537         XCPT_FRAME
 538         interrupt do_IRQ
 539         /* 0(%rsp): oldrsp-ARGOFFSET */
 540 ret_from_intr:
 541         DISABLE_INTERRUPTS(CLBR_NONE)
 542         TRACE_IRQS_OFF
 543         decl %gs:pda_irqcount
 544         leaveq
 545         CFI_DEF_CFA_REGISTER    rsp
 546         CFI_ADJUST_CFA_OFFSET   -8
 547 exit_intr:
 548         GET_THREAD_INFO(%rcx)
 549         testl $3,CS-ARGOFFSET(%rsp)
 550         je retint_kernel
 551
 552         /* Interrupt came from user space */
 553         /*
 554          * Has a correct top of stack, but a partial stack frame
 555          * %rcx: thread info. Interrupts off.
 556          */
 557 retint_with_reschedule:
 558         movl $_TIF_WORK_MASK,%edi
 559 retint_check:
 560         LOCKDEP_SYS_EXIT_IRQ
 561         movl threadinfo_flags(%rcx),%edx
 562         andl %edi,%edx
 563         CFI_REMEMBER_STATE
 564         jnz  retint_careful
 565
 566 retint_swapgs:          /* return to user-space */
 567         /*
 568          * The iretq could re-enable interrupts:
 569          */
 570         DISABLE_INTERRUPTS(CLBR_ANY)
 571         TRACE_IRQS_IRETQ
 572         SWAPGS
 573         jmp restore_args
 574
 575 retint_restore_args:    /* return to kernel space */
 576         DISABLE_INTERRUPTS(CLBR_ANY)
 577         /*
 578          * The iretq could re-enable interrupts:
 579          */
 580         TRACE_IRQS_IRETQ
 581 restore_args:
 582         RESTORE_ARGS 0,8,0
 583
 584 irq_return:
 585         INTERRUPT_RETURN
 586
 587         .section __ex_table, "a"
 588         .quad irq_return, bad_iret
 589         .previous
 590
 591 #ifdef CONFIG_PARAVIRT
 592 ENTRY(native_iret)
 593         iretq
 594
 595         .section __ex_table,"a"
 596         .quad native_iret, bad_iret
 597         .previous
 598 #endif
 599
 600         .section .fixup,"ax"
 601 bad_iret:
 602         /*
 603          * The iret traps when the %cs or %ss being restored is bogus.
 604          * We've lost the original trap vector and error code.
 605          * #GPF is the most likely one to get for an invalid selector.
 606          * So pretend we completed the iret and took the #GPF in user mode.
 607          *
 608          * We are now running with the kernel GS after exception recovery.
 609          * But error_entry expects us to have user GS to match the user %cs,
 610          * so swap back.
 611          */
 612         pushq $0
 613
 614         SWAPGS
 615         jmp general_protection
 616
 617         .previous
 618
 619         /* edi: workmask, edx: work */
 620 retint_careful:
 621         CFI_RESTORE_STATE
 622         bt    $TIF_NEED_RESCHED,%edx
 623         jnc   retint_signal
 624         TRACE_IRQS_ON
 625         ENABLE_INTERRUPTS(CLBR_NONE)
 626         pushq %rdi
 627         CFI_ADJUST_CFA_OFFSET   8
 628         call  schedule
 629         popq %rdi
 630         CFI_ADJUST_CFA_OFFSET   -8
 631         GET_THREAD_INFO(%rcx)
 632         DISABLE_INTERRUPTS(CLBR_NONE)
 633         TRACE_IRQS_OFF
 634         jmp retint_check
 635
 636 retint_signal:
 637         testl $_TIF_DO_NOTIFY_MASK,%edx
 638         jz    retint_swapgs
 639         TRACE_IRQS_ON
 640         ENABLE_INTERRUPTS(CLBR_NONE)
 641         SAVE_REST
 642         movq $-1,ORIG_RAX(%rsp)
 643         xorl %esi,%esi          # oldset
 644         movq %rsp,%rdi          # &pt_regs
 645         call do_notify_resume
 646         RESTORE_REST
 647         DISABLE_INTERRUPTS(CLBR_NONE)
 648         TRACE_IRQS_OFF
 649         movl $_TIF_NEED_RESCHED,%edi
 650         GET_THREAD_INFO(%rcx)
 651         jmp retint_check
 652
 653 #ifdef CONFIG_PREEMPT
 654         /* Returning to kernel space. Check if we need preemption */
 655         /* rcx:  threadinfo. interrupts off. */
 656 ENTRY(retint_kernel)
 657         cmpl $0,threadinfo_preempt_count(%rcx)
 658         jnz  retint_restore_args
 659         bt  $TIF_NEED_RESCHED,threadinfo_flags(%rcx)
 660         jnc  retint_restore_args
 661         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 662         jnc  retint_restore_args
 663         call preempt_schedule_irq
 664         jmp exit_intr
 665 #endif
 666
 667         CFI_ENDPROC
 668 END(common_interrupt)
 669
 670 /*
 671  * APIC interrupts.
 672  */
 673         .macro apicinterrupt num,func
 674         INTR_FRAME
 675         pushq $~(\num)
 676         CFI_ADJUST_CFA_OFFSET 8
 677         interrupt \func
 678         jmp ret_from_intr
 679         CFI_ENDPROC
 680         .endm
 681
 682 ENTRY(thermal_interrupt)
 683         apicinterrupt THERMAL_APIC_VECTOR,smp_thermal_interrupt
 684 END(thermal_interrupt)
 685
 686 ENTRY(threshold_interrupt)
 687         apicinterrupt THRESHOLD_APIC_VECTOR,mce_threshold_interrupt
 688 END(threshold_interrupt)
 689
 690 #ifdef CONFIG_SMP
 691 ENTRY(reschedule_interrupt)
 692         apicinterrupt RESCHEDULE_VECTOR,smp_reschedule_interrupt
 693 END(reschedule_interrupt)
 694
 695         .macro INVALIDATE_ENTRY num
 696 ENTRY(invalidate_interrupt\num)
 697         apicinterrupt INVALIDATE_TLB_VECTOR_START+\num,smp_invalidate_interrupt
 698 END(invalidate_interrupt\num)
 699         .endm
 700
 701         INVALIDATE_ENTRY 0
 702         INVALIDATE_ENTRY 1
 703         INVALIDATE_ENTRY 2
 704         INVALIDATE_ENTRY 3
 705         INVALIDATE_ENTRY 4
 706         INVALIDATE_ENTRY 5
 707         INVALIDATE_ENTRY 6
 708         INVALIDATE_ENTRY 7
 709
 710 ENTRY(call_function_interrupt)
 711         apicinterrupt CALL_FUNCTION_VECTOR,smp_call_function_interrupt
 712 END(call_function_interrupt)
 713 ENTRY(irq_move_cleanup_interrupt)
 714         apicinterrupt IRQ_MOVE_CLEANUP_VECTOR,smp_irq_move_cleanup_interrupt
 715 END(irq_move_cleanup_interrupt)
 716 #endif
 717
 718 ENTRY(apic_timer_interrupt)
 719         apicinterrupt LOCAL_TIMER_VECTOR,smp_apic_timer_interrupt
 720 END(apic_timer_interrupt)
 721
 722 ENTRY(error_interrupt)
 723         apicinterrupt ERROR_APIC_VECTOR,smp_error_interrupt
 724 END(error_interrupt)
 725
 726 ENTRY(spurious_interrupt)
 727         apicinterrupt SPURIOUS_APIC_VECTOR,smp_spurious_interrupt
 728 END(spurious_interrupt)
 729
 730 /*
 731  * Exception entry points.
 732  */
 733         .macro zeroentry sym
 734         INTR_FRAME
 735         pushq $0        /* push error code/oldrax */
 736         CFI_ADJUST_CFA_OFFSET 8
 737         pushq %rax      /* push real oldrax to the rdi slot */
 738         CFI_ADJUST_CFA_OFFSET 8
 739         CFI_REL_OFFSET rax,0
 740         leaq  \sym(%rip),%rax
 741         jmp error_entry
 742         CFI_ENDPROC
 743         .endm
 744
 745         .macro errorentry sym
 746         XCPT_FRAME
 747         pushq %rax
 748         CFI_ADJUST_CFA_OFFSET 8
 749         CFI_REL_OFFSET rax,0
 750         leaq  \sym(%rip),%rax
 751         jmp error_entry
 752         CFI_ENDPROC
 753         .endm
 754
 755         /* error code is on the stack already */
 756         /* handle NMI like exceptions that can happen everywhere */
 757         .macro paranoidentry sym, ist=0, irqtrace=1
 758         SAVE_ALL
 759         cld
 760         movl $1,%ebx
 761         movl  $MSR_GS_BASE,%ecx
 762         rdmsr
 763         testl %edx,%edx
 764         js    1f
 765         SWAPGS
 766         xorl  %ebx,%ebx
 767 1:
 768         .if \ist
 769         movq    %gs:pda_data_offset, %rbp
 770         .endif
 771         movq %rsp,%rdi
 772         movq ORIG_RAX(%rsp),%rsi
 773         movq $-1,ORIG_RAX(%rsp)
 774         .if \ist
 775         subq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 776         .endif
 777         call \sym
 778         .if \ist
 779         addq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 780         .endif
 781         DISABLE_INTERRUPTS(CLBR_NONE)
 782         .if \irqtrace
 783         TRACE_IRQS_OFF
 784         .endif
 785         .endm
 786
 787         /*
 788          * "Paranoid" exit path from exception stack.
 789          * Paranoid because this is used by NMIs and cannot take
 790          * any kernel state for granted.
 791          * We don't do kernel preemption checks here, because only
 792          * NMI should be common and it does not enable IRQs and
 793          * cannot get reschedule ticks.
 794          *
 795          * "trace" is 0 for the NMI handler only, because irq-tracing
 796          * is fundamentally NMI-unsafe. (we cannot change the soft and
 797          * hard flags at once, atomically)
 798          */
 799         .macro paranoidexit trace=1
 800         /* ebx: no swapgs flag */
 801 paranoid_exit\trace:
 802         testl %ebx,%ebx                         /* swapgs needed? */
 803         jnz paranoid_restore\trace
 804         testl $3,CS(%rsp)
 805         jnz   paranoid_userspace\trace
 806 paranoid_swapgs\trace:
 807         .if \trace
 808         TRACE_IRQS_IRETQ 0
 809         .endif
 810         SWAPGS_UNSAFE_STACK
 811 paranoid_restore\trace:
 812         RESTORE_ALL 8
 813         jmp irq_return
 814 paranoid_userspace\trace:
 815         GET_THREAD_INFO(%rcx)
 816         movl threadinfo_flags(%rcx),%ebx
 817         andl $_TIF_WORK_MASK,%ebx
 818         jz paranoid_swapgs\trace
 819         movq %rsp,%rdi                  /* &pt_regs */
 820         call sync_regs
 821         movq %rax,%rsp                  /* switch stack for scheduling */
 822         testl $_TIF_NEED_RESCHED,%ebx
 823         jnz paranoid_schedule\trace
 824         movl %ebx,%edx                  /* arg3: thread flags */
 825         .if \trace
 826         TRACE_IRQS_ON
 827         .endif
 828         ENABLE_INTERRUPTS(CLBR_NONE)
 829         xorl %esi,%esi                  /* arg2: oldset */
 830         movq %rsp,%rdi                  /* arg1: &pt_regs */
 831         call do_notify_resume
 832         DISABLE_INTERRUPTS(CLBR_NONE)
 833         .if \trace
 834         TRACE_IRQS_OFF
 835         .endif
 836         jmp paranoid_userspace\trace
 837 paranoid_schedule\trace:
 838         .if \trace
 839         TRACE_IRQS_ON
 840         .endif
 841         ENABLE_INTERRUPTS(CLBR_ANY)
 842         call schedule
 843         DISABLE_INTERRUPTS(CLBR_ANY)
 844         .if \trace
 845         TRACE_IRQS_OFF
 846         .endif
 847         jmp paranoid_userspace\trace
 848         CFI_ENDPROC
 849         .endm
 850
 851 /*
 852  * Exception entry point. This expects an error code/orig_rax on the stack
 853  * and the exception handler in %rax.
 854  */
 855 KPROBE_ENTRY(error_entry)
 856         _frame RDI
 857         CFI_REL_OFFSET rax,0
 858         /* rdi slot contains rax, oldrax contains error code */
 859         cld
 860         subq  $14*8,%rsp
 861         CFI_ADJUST_CFA_OFFSET   (14*8)
 862         movq %rsi,13*8(%rsp)
 863         CFI_REL_OFFSET  rsi,RSI
 864         movq 14*8(%rsp),%rsi    /* load rax from rdi slot */
 865         CFI_REGISTER    rax,rsi
 866         movq %rdx,12*8(%rsp)
 867         CFI_REL_OFFSET  rdx,RDX
 868         movq %rcx,11*8(%rsp)
 869         CFI_REL_OFFSET  rcx,RCX
 870         movq %rsi,10*8(%rsp)    /* store rax */
 871         CFI_REL_OFFSET  rax,RAX
 872         movq %r8, 9*8(%rsp)
 873         CFI_REL_OFFSET  r8,R8
 874         movq %r9, 8*8(%rsp)
 875         CFI_REL_OFFSET  r9,R9
 876         movq %r10,7*8(%rsp)
 877         CFI_REL_OFFSET  r10,R10
 878         movq %r11,6*8(%rsp)
 879         CFI_REL_OFFSET  r11,R11
 880         movq %rbx,5*8(%rsp)
 881         CFI_REL_OFFSET  rbx,RBX
 882         movq %rbp,4*8(%rsp)
 883         CFI_REL_OFFSET  rbp,RBP
 884         movq %r12,3*8(%rsp)
 885         CFI_REL_OFFSET  r12,R12
 886         movq %r13,2*8(%rsp)
 887         CFI_REL_OFFSET  r13,R13
 888         movq %r14,1*8(%rsp)
 889         CFI_REL_OFFSET  r14,R14
 890         movq %r15,(%rsp)
 891         CFI_REL_OFFSET  r15,R15
 892         xorl %ebx,%ebx
 893         testl $3,CS(%rsp)
 894         je  error_kernelspace
 895 error_swapgs:
 896         SWAPGS
 897 error_sti:
 898         movq %rdi,RDI(%rsp)
 899         CFI_REL_OFFSET  rdi,RDI
 900         movq %rsp,%rdi
 901         movq ORIG_RAX(%rsp),%rsi        /* get error code */
 902         movq $-1,ORIG_RAX(%rsp)
 903         call *%rax
 904         /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
 905 error_exit:
 906         movl %ebx,%eax
 907         RESTORE_REST
 908         DISABLE_INTERRUPTS(CLBR_NONE)
 909         TRACE_IRQS_OFF
 910         GET_THREAD_INFO(%rcx)
 911         testl %eax,%eax
 912         jne  retint_kernel
 913         LOCKDEP_SYS_EXIT_IRQ
 914         movl  threadinfo_flags(%rcx),%edx
 915         movl  $_TIF_WORK_MASK,%edi
 916         andl  %edi,%edx
 917         jnz  retint_careful
 918         jmp retint_swapgs
 919         CFI_ENDPROC
 920
 921 error_kernelspace:
 922         incl %ebx
 923        /* There are two places in the kernel that can potentially fault with
 924           usergs. Handle them here. The exception handlers after
 925            iret run with kernel gs again, so don't set the user space flag.
 926            B stepping K8s sometimes report an truncated RIP for IRET
 927            exceptions returning to compat mode. Check for these here too. */
 928         leaq irq_return(%rip),%rcx
 929         cmpq %rcx,RIP(%rsp)
 930         je   error_swapgs
 931         movl %ecx,%ecx  /* zero extend */
 932         cmpq %rcx,RIP(%rsp)
 933         je   error_swapgs
 934         cmpq $gs_change,RIP(%rsp)
 935         je   error_swapgs
 936         jmp  error_sti
 937 KPROBE_END(error_entry)
 938
 939        /* Reload gs selector with exception handling */
 940        /* edi:  new selector */
 941 ENTRY(load_gs_index)
 942         CFI_STARTPROC
 943         pushf
 944         CFI_ADJUST_CFA_OFFSET 8
 945         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
 946         SWAPGS
 947 gs_change:
 948         movl %edi,%gs
 949 2:      mfence          /* workaround */
 950         SWAPGS
 951         popf
 952         CFI_ADJUST_CFA_OFFSET -8
 953         ret
 954         CFI_ENDPROC
 955 ENDPROC(load_gs_index)
 956
 957         .section __ex_table,"a"
 958         .align 8
 959         .quad gs_change,bad_gs
 960         .previous
 961         .section .fixup,"ax"
 962         /* running with kernelgs */
 963 bad_gs:
 964         SWAPGS                  /* switch back to user gs */
 965         xorl %eax,%eax
 966         movl %eax,%gs
 967         jmp  2b
 968         .previous
 969
 970 /*
 971  * Create a kernel thread.
 972  *
 973  * C extern interface:
 974  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
 975  *
 976  * asm input arguments:
 977  *      rdi: fn, rsi: arg, rdx: flags
 978  */
 979 ENTRY(kernel_thread)
 980         CFI_STARTPROC
 981         FAKE_STACK_FRAME $child_rip
 982         SAVE_ALL
 983
 984         # rdi: flags, rsi: usp, rdx: will be &pt_regs
 985         movq %rdx,%rdi
 986         orq  kernel_thread_flags(%rip),%rdi
 987         movq $-1, %rsi
 988         movq %rsp, %rdx
 989
 990         xorl %r8d,%r8d
 991         xorl %r9d,%r9d
 992
 993         # clone now
 994         call do_fork
 995         movq %rax,RAX(%rsp)
 996         xorl %edi,%edi
 997
 998         /*
 999          * It isn't worth to check for reschedule here,
1000          * so internally to the x86_64 port you can rely on kernel_thread()
1001          * not to reschedule the child before returning, this avoids the need
1002          * of hacks for example to fork off the per-CPU idle tasks.
1003          * [Hopefully no generic code relies on the reschedule -AK]
1004          */
1005         RESTORE_ALL
1006         UNFAKE_STACK_FRAME
1007         ret
1008         CFI_ENDPROC
1009 ENDPROC(kernel_thread)
1010
1011 child_rip:
1012         pushq $0                # fake return address
1013         CFI_STARTPROC
1014         /*
1015          * Here we are in the child and the registers are set as they were
1016          * at kernel_thread() invocation in the parent.
1017          */
1018         movq %rdi, %rax
1019         movq %rsi, %rdi
1020         call *%rax
1021         # exit
1022         mov %eax, %edi
1023         call do_exit
1024         CFI_ENDPROC
1025 ENDPROC(child_rip)
1026
1027 /*
1028  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1029  *
1030  * C extern interface:
1031  *       extern long execve(char *name, char **argv, char **envp)
1032  *
1033  * asm input arguments:
1034  *      rdi: name, rsi: argv, rdx: envp
1035  *
1036  * We want to fallback into:
1037  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1038  *
1039  * do_sys_execve asm fallback arguments:
1040  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1041  */
1042 ENTRY(kernel_execve)
1043         CFI_STARTPROC
1044         FAKE_STACK_FRAME $0
1045         SAVE_ALL
1046         movq %rsp,%rcx
1047         call sys_execve
1048         movq %rax, RAX(%rsp)
1049         RESTORE_REST
1050         testq %rax,%rax
1051         je int_ret_from_sys_call
1052         RESTORE_ARGS
1053         UNFAKE_STACK_FRAME
1054         ret
1055         CFI_ENDPROC
1056 ENDPROC(kernel_execve)
1057
1058 KPROBE_ENTRY(page_fault)
1059         errorentry do_page_fault
1060 KPROBE_END(page_fault)
1061
1062 ENTRY(coprocessor_error)
1063         zeroentry do_coprocessor_error
1064 END(coprocessor_error)
1065
1066 ENTRY(simd_coprocessor_error)
1067         zeroentry do_simd_coprocessor_error
1068 END(simd_coprocessor_error)
1069
1070 ENTRY(device_not_available)
1071         zeroentry math_state_restore
1072 END(device_not_available)
1073
1074         /* runs on exception stack */
1075 KPROBE_ENTRY(debug)
1076         INTR_FRAME
1077         pushq $0
1078         CFI_ADJUST_CFA_OFFSET 8
1079         paranoidentry do_debug, DEBUG_STACK
1080         paranoidexit
1081 KPROBE_END(debug)
1082
1083         /* runs on exception stack */
1084 KPROBE_ENTRY(nmi)
1085         INTR_FRAME
1086         pushq $-1
1087         CFI_ADJUST_CFA_OFFSET 8
1088         paranoidentry do_nmi, 0, 0
1089 #ifdef CONFIG_TRACE_IRQFLAGS
1090         paranoidexit 0
1091 #else
1092         jmp paranoid_exit1
1093         CFI_ENDPROC
1094 #endif
1095 KPROBE_END(nmi)
1096
1097 KPROBE_ENTRY(int3)
1098         INTR_FRAME
1099         pushq $0
1100         CFI_ADJUST_CFA_OFFSET 8
1101         paranoidentry do_int3, DEBUG_STACK
1102         jmp paranoid_exit1
1103         CFI_ENDPROC
1104 KPROBE_END(int3)
1105
1106 ENTRY(overflow)
1107         zeroentry do_overflow
1108 END(overflow)
1109
1110 ENTRY(bounds)
1111         zeroentry do_bounds
1112 END(bounds)
1113
1114 ENTRY(invalid_op)
1115         zeroentry do_invalid_op
1116 END(invalid_op)
1117
1118 ENTRY(coprocessor_segment_overrun)
1119         zeroentry do_coprocessor_segment_overrun
1120 END(coprocessor_segment_overrun)
1121
1122         /* runs on exception stack */
1123 ENTRY(double_fault)
1124         XCPT_FRAME
1125         paranoidentry do_double_fault
1126         jmp paranoid_exit1
1127         CFI_ENDPROC
1128 END(double_fault)
1129
1130 ENTRY(invalid_TSS)
1131         errorentry do_invalid_TSS
1132 END(invalid_TSS)
1133
1134 ENTRY(segment_not_present)
1135         errorentry do_segment_not_present
1136 END(segment_not_present)
1137
1138         /* runs on exception stack */
1139 ENTRY(stack_segment)
1140         XCPT_FRAME
1141         paranoidentry do_stack_segment
1142         jmp paranoid_exit1
1143         CFI_ENDPROC
1144 END(stack_segment)
1145
1146 KPROBE_ENTRY(general_protection)
1147         errorentry do_general_protection
1148 KPROBE_END(general_protection)
1149
1150 ENTRY(alignment_check)
1151         errorentry do_alignment_check
1152 END(alignment_check)
1153
1154 ENTRY(divide_error)
1155         zeroentry do_divide_error
1156 END(divide_error)
1157
1158 ENTRY(spurious_interrupt_bug)
1159         zeroentry do_spurious_interrupt_bug
1160 END(spurious_interrupt_bug)
1161
1162 #ifdef CONFIG_X86_MCE
1163         /* runs on exception stack */
1164 ENTRY(machine_check)
1165         INTR_FRAME
1166         pushq $0
1167         CFI_ADJUST_CFA_OFFSET 8
1168         paranoidentry do_machine_check
1169         jmp paranoid_exit1
1170         CFI_ENDPROC
1171 END(machine_check)
1172 #endif
1173
1174 /* Call softirq on interrupt stack. Interrupts are off. */
1175 ENTRY(call_softirq)
1176         CFI_STARTPROC
1177         push %rbp
1178         CFI_ADJUST_CFA_OFFSET   8
1179         CFI_REL_OFFSET rbp,0
1180         mov  %rsp,%rbp
1181         CFI_DEF_CFA_REGISTER rbp
1182         incl %gs:pda_irqcount
1183         cmove %gs:pda_irqstackptr,%rsp
1184         push  %rbp                      # backlink for old unwinder
1185         call __do_softirq
1186         leaveq
1187         CFI_DEF_CFA_REGISTER    rsp
1188         CFI_ADJUST_CFA_OFFSET   -8
1189         decl %gs:pda_irqcount
1190         ret
1191         CFI_ENDPROC
1192 ENDPROC(call_softirq)
1193
1194 KPROBE_ENTRY(ignore_sysret)
1195         CFI_STARTPROC
1196         mov $-ENOSYS,%eax
1197         sysret
1198         CFI_ENDPROC
1199 ENDPROC(ignore_sysret)