org.handhelds.familiar/classes/kernel.bbclass

   1 inherit module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 inherit kernel-arch
   7
   8 export OS = "${TARGET_OS}"
   9 export CROSS_COMPILE = "${TARGET_PREFIX}"
  10 KERNEL_IMAGETYPE = "zImage"
  11
  12 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  13
  14 KERNEL_CCSUFFIX ?= ""
  15 KERNEL_LDSUFFIX ?= ""
  16
  17 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX}"
  18 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX}"
  19
  20 KERNEL_OUTPUT = "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  21 KERNEL_IMAGEDEST = "boot"
  22
  23 #
  24 # configuration
  25 #
  26 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  27
  28 # parse kernel ABI version out of <linux/version.h>
  29 def get_kernelversion(p):
  30         import re
  31         try:
  32                 f = open(p, 'r')
  33         except IOError:
  34                 return None
  35         l = f.readlines()
  36         f.close()
  37         r = re.compile("#define UTS_RELEASE \"(.*)\"")
  38         for s in l:
  39                 m = r.match(s)
  40                 if m:
  41                         return m.group(1)
  42         return None
  43
  44 def get_kernelmajorversion(p):
  45         import re
  46         r = re.compile("([0-9]+\.[0-9]+).*")
  47         m = r.match(p);
  48         if m:
  49                 return m.group(1)
  50         return None
  51
  52 KERNEL_VERSION = "${@get_kernelversion('${S}/include/linux/version.h')}"
  53 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  54
  55 KERNEL_LOCALVERSION ?= ""
  56
  57 # kernels are generally machine specific
  58 PACKAGE_ARCH = "${MACHINE_ARCH}"
  59
  60 kernel_do_compile() {
  61         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  62         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  63         oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  64         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  65         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  66                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  67         else
  68                 oenote "no modules to compile"
  69         fi
  70 }
  71
  72 kernel_do_stage() {
  73         ASMDIR=`readlink include/asm`
  74
  75         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  76         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
  77         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
  78
  79         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
  80         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
  81
  82         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
  83         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
  84
  85         mkdir -p ${STAGING_KERNEL_DIR}/include/net
  86         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
  87
  88         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
  89         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
  90
  91         if [ -d drivers/sound ]; then
  92                 # 2.4 alsa needs some headers from this directory
  93                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
  94                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
  95         fi
  96
  97         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${PV}${KERNEL_LOCALVERSION}
  98         ln -sf config-${PV}${KERNEL_LOCALVERSION} ${STAGING_KERNEL_DIR}/.config
  99         ln -sf config-${PV}${KERNEL_LOCALVERSION} ${STAGING_KERNEL_DIR}/kernel-config
 100         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 101         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 102         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 103         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 104         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 105         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 106
 107         # Check if arch/${ARCH}/Makefile exists and install it
 108         if [ -e arch/${ARCH}/Makefile ]; then
 109                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 110                 install -m 0644 arch/${ARCH}/Makefile ${STAGING_KERNEL_DIR}/arch/${ARCH}
 111         fi
 112         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 113         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 114         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${PV}${KERNEL_LOCALVERSION}
 115         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 116
 117         cp -fR scripts ${STAGING_KERNEL_DIR}/
 118 }
 119
 120 kernel_do_install() {
 121         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
 122         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 123                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 124         else
 125                 oenote "no modules to install"
 126         fi
 127
 128         install -d ${D}/${KERNEL_IMAGEDEST}
 129         install -d ${D}/boot
 130         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${PV}${KERNEL_LOCALVERSION}
 131         install -m 0644 System.map ${D}/boot/System.map-${PV}${KERNEL_LOCALVERSION}
 132         install -m 0644 .config ${D}/boot/config-${PV}${KERNEL_LOCALVERSION}
 133         install -d ${D}/etc/modutils
 134
 135         # Check if scripts/genksyms exists and if so, build it
 136         if [ -e scripts/genksyms/ ]; then
 137                 oe_runmake SUBDIRS="scripts/genksyms"
 138         fi
 139
 140         cp -fR scripts ${STAGING_KERNEL_DIR}/
 141 }
 142
 143 kernel_do_configure() {
 144         yes '' | oe_runmake oldconfig
 145 }
 146
 147 pkg_postinst_kernel () {
 148         update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${PV}${KERNEL_LOCALVERSION} ${KERNEL_PRIORITY} || true
 149 }
 150
 151 pkg_postrm_kernel () {
 152         update-alternatives --remove ${KERNEL_IMAGETYPE} /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${PV}${KERNEL_LOCALVERSION} || true
 153 }
 154
 155 inherit cml1
 156
 157 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 158
 159 PACKAGES = "kernel kernel-image kernel-dev"
 160 FILES = ""
 161 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 162 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 163 RDEPENDS_kernel = "kernel-image-${KERNEL_VERSION}"
 164 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 165 ALLOW_EMPTY_kernel = "1"
 166 ALLOW_EMPTY_kernel-image = "1"
 167
 168 pkg_postinst_modules () {
 169 if [ -n "$D" ]; then
 170         ${HOST_PREFIX}depmod -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${PV}${KERNEL_LOCALVERSION} ${KERNEL_VERSION}
 171 else
 172         depmod -A
 173         update-modules || true
 174 fi
 175 }
 176
 177 pkg_postrm_modules () {
 178 update-modules || true
 179 }
 180
 181 autoload_postinst_fragment() {
 182 if [ x"$D" = "x" ]; then
 183         modprobe %s || true
 184 fi
 185 }
 186
 187 # autoload defaults (alphabetically sorted)
 188 module_autoload_evdev = "evdev"
 189 module_autoload_hidp = "hidp"
 190 module_autoload_ipv6 = "ipv6"
 191 module_autoload_ipsec = "ipsec"
 192 module_autoload_ircomm-tty = "ircomm-tty"
 193 module_autoload_rfcomm = "rfcomm"
 194 module_autoload_sa1100-rtc = "sa1100-rtc"
 195
 196 # alias defaults (alphabetically sorted)
 197 module_conf_af_packet = "alias net-pf-17 af_packet"
 198 module_conf_bluez = "alias net-pf-31 bluez"
 199 module_conf_bnep = "alias bt-proto-4 bnep"
 200 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 201 module_conf_l2cap = "alias bt-proto-0 l2cap"
 202 module_conf_sco = "alias bt-proto-2 sco"
 203 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 204
 205 python populate_packages_prepend () {
 206         def extract_modinfo(file):
 207                 import os, re
 208                 tmpfile = os.tmpnam()
 209                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 210                 os.system(cmd)
 211                 f = open(tmpfile)
 212                 l = f.read().split("\000")
 213                 f.close()
 214                 os.unlink(tmpfile)
 215                 exp = re.compile("([^=]+)=(.*)")
 216                 vals = {}
 217                 for i in l:
 218                         m = exp.match(i)
 219                         if not m:
 220                                 continue
 221                         vals[m.group(1)] = m.group(2)
 222                 return vals
 223
 224         def parse_depmod():
 225                 import os, re
 226
 227                 dvar = bb.data.getVar('D', d, 1)
 228                 if not dvar:
 229                         bb.error("D not defined")
 230                         return
 231
 232                 kernelver = bb.data.getVar('PV', d, 1) + bb.data.getVar('KERNEL_LOCALVERSION', d, 1)
 233                 kernelver_stripped = kernelver
 234                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 235                 if m and not bb.data.getVar('KERNEL_PRESERVE_HH_MINOR_VER', d, 1):
 236                         kernelver_stripped = m.group(1)
 237                 path = bb.data.getVar("PATH", d, 1)
 238                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 239
 240                 cmd = "PATH=\"%s\" %sdepmod -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, dvar, dvar, kernelver, kernelver_stripped)
 241                 bb.debug (1, cmd)
 242                 f = os.popen(cmd, 'r')
 243
 244                 deps = {}
 245                 pattern0 = "^(.*\.k?o):..*$"
 246                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 247                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 248                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 249                 pattern4 = "^\t(.*\.k?o)\s*$"
 250
 251                 line = f.readline()
 252                 while line:
 253                         if not re.match(pattern0, line):
 254                                 line = f.readline()
 255                                 continue
 256                         m1 = re.match(pattern1, line)
 257                         if m1:
 258                                 deps[m1.group(1)] = m1.group(2).split()
 259                         else:
 260                                 m2 = re.match(pattern2, line)
 261                                 if m2:
 262                                         deps[m2.group(1)] = m2.group(2).split()
 263                                         line = f.readline()
 264                                         m3 = re.match(pattern3, line)
 265                                         while m3:
 266                                                 deps[m2.group(1)].extend(m3.group(1).split())
 267                                                 line = f.readline()
 268                                                 m3 = re.match(pattern3, line)
 269                                         m4 = re.match(pattern4, line)
 270                                         deps[m2.group(1)].extend(m4.group(1).split())
 271                         line = f.readline()
 272                 if f.close() or not deps:
 273                         # depmod returned an error or no deps found (very unlikely)
 274                         raise bb.build.FuncFailed("Failed to extract module dependencies.")
 275                 return deps
 276
 277         def get_dependencies(file, pattern, format):
 278                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 279
 280                 if module_deps.has_key(file):
 281                         import os.path, re
 282                         dependencies = []
 283                         for i in module_deps[file]:
 284                                 m = re.match(pattern, os.path.basename(i))
 285                                 if not m:
 286                                         continue
 287                                 on = legitimize_package_name(m.group(1))
 288                                 dependency_pkg = format % on
 289                                 v = bb.data.getVar("PARALLEL_INSTALL_MODULES", d, 1) or "0"
 290                                 if v == "1":
 291                                         kv = bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1)
 292                                         dependency_pkg = "%s-%s" % (dependency_pkg, kv)
 293                                 dependencies.append(dependency_pkg)
 294                         return dependencies
 295                 return []
 296
 297         def frob_metadata(file, pkg, pattern, format, basename):
 298                 import re
 299                 vals = extract_modinfo(file)
 300
 301                 dvar = bb.data.getVar('D', d, 1)
 302
 303                 # If autoloading is requested, output /etc/modutils/<name> and append
 304                 # appropriate modprobe commands to the postinst
 305                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 306                 if autoload:
 307                         name = '%s/etc/modutils/%s' % (dvar, basename)
 308                         f = open(name, 'w')
 309                         for m in autoload.split():
 310                                 f.write('%s\n' % m)
 311                         f.close()
 312                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 313                         if not postinst:
 314                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 315                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 316                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 317
 318                 # Write out any modconf fragment
 319                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 320                 if modconf:
 321                         name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 322                         f = open(name, 'w')
 323                         f.write("%s\n" % modconf)
 324                         f.close()
 325
 326                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 327                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf" % (files, basename, basename)
 328                 bb.data.setVar('FILES_%s' % pkg, files, d)
 329
 330                 if vals.has_key("description"):
 331                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 332                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 333
 334                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 335                 if rdepends_str:
 336                         rdepends = rdepends_str.split()
 337                 else:
 338                         rdepends = []
 339                 rdepends.extend(get_dependencies(file, pattern, format))
 340                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 341
 342         module_deps = parse_depmod()
 343         module_regex = '^(.*)\.k?o$'
 344         module_pattern = 'kernel-module-%s'
 345
 346         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 347         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 348         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-image-%s' % bb.data.getVar("KERNEL_VERSION", d, 1))
 349
 350         import re, os
 351         metapkg = "kernel-modules"
 352         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 353         bb.data.setVar('FILES_' + metapkg, "", d)
 354         blacklist = [ 'kernel-dev', 'kernel-image' ]
 355         for l in module_deps.values():
 356                 for i in l:
 357                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 358                         blacklist.append(pkg)
 359         metapkg_rdepends = []
 360         packages = bb.data.getVar('PACKAGES', d, 1).split()
 361         for pkg in packages[1:]:
 362                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 363                         metapkg_rdepends.append(pkg)
 364         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 365         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 366         packages.append(metapkg)
 367         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 368
 369         v = bb.data.getVar("PARALLEL_INSTALL_MODULES", d, 1) or "0"
 370         if v == "1":
 371                 kv = bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1)
 372                 packages = bb.data.getVar("PACKAGES", d, 1)
 373                 module_re = re.compile("^kernel-module-")
 374                 for p in packages.split():
 375                         if not module_re.match(p):
 376                                 continue
 377                         pkg = bb.data.getVar("PKG_%s" % p, d, 1) or p
 378                         newpkg = "%s-%s" % (pkg, kv)
 379                         bb.data.setVar("PKG_%s" % p, newpkg, d)
 380                         rprovides = bb.data.getVar("RPROVIDES_%s" % p, d, 1)
 381                         if rprovides:
 382                                 rprovides = "%s %s" % (rprovides, pkg)
 383                         else:
 384                                 rprovides = pkg
 385                         bb.data.setVar("RPROVIDES_%s" % p, rprovides, d)
 386 }