org.handhelds.familiar/packages/base-files/base-files_3.0.14.bb

   1 DESCRIPTION = "Miscellaneous files for the base system."
   2 SECTION = "base"
   3 PRIORITY = "required"
   4 PR = "r46"
   5 LICENSE = "GPL"
   6
   7 PACKAGE_ARCH = "${MACHINE_ARCH}"
   8
   9 SRC_URI = " \
  10            file://nsswitch.conf \
  11            file://motd \
  12            file://inputrc \
  13            file://host.conf \
  14            file://profile \
  15            file://fstab \
  16            file://filesystems \
  17            file://issue.net \
  18            file://issue \
  19            file://usbd \
  20            file://share/dot.bashrc \
  21            file://share/dot.profile \
  22            file://licenses/BSD \
  23            file://licenses/GPL-2 \
  24            file://licenses/LGPL-2 \
  25            file://licenses/LGPL-2.1 \
  26            file://licenses/Artistic "
  27 S = "${WORKDIR}"
  28
  29 docdir_append = "/${P}"
  30 dirs1777 = "/tmp ${localstatedir}/lock ${localstatedir}/tmp"
  31 dirs2775 = "/home ${prefix}/src ${localstatedir}/local"
  32 dirs755 = "/bin /boot /dev ${sysconfdir} ${sysconfdir}/default \
  33            ${sysconfdir}/skel /lib /mnt /proc /home/root /sbin \
  34            ${prefix} ${bindir} ${docdir} /usr/games ${includedir} \
  35            ${libdir} ${sbindir} ${datadir} \
  36            ${datadir}/common-licenses ${datadir}/dict ${infodir} \
  37            ${mandir} ${datadir}/misc ${localstatedir} \
  38            ${localstatedir}/backups ${localstatedir}/cache \
  39            ${localstatedir}/lib /sys ${localstatedir}/lib/misc \
  40            ${localstatedir}/lock/subsys ${localstatedir}/log \
  41            ${localstatedir}/run ${localstatedir}/spool \
  42            /mnt /media /media/card /media/cf /media/net /media/ram \
  43            /media/union /media/realroot /media/hdd \
  44            /media/mmc1"
  45 conffiles = "${sysconfdir}/debian_version ${sysconfdir}/host.conf \
  46              ${sysconfdir}/inputrc ${sysconfdir}/issue /${sysconfdir}/issue.net \
  47              ${sysconfdir}/nsswitch.conf ${sysconfdir}/profile \
  48              ${sysconfdir}/default"
  49
  50 hostname = "openembedded"
  51 hostname_openslug = "openslug"
  52 hostname_mnci = "MNCI"
  53 PACKAGE_ARCH_mnci = "mnci"
  54 hostname_rt3000 = "MNRT"
  55 PACKAGE_ARCH_rt3000 = "rt3000"
  56
  57 do_install () {
  58         for d in ${dirs755}; do
  59                 install -m 0755 -d ${D}$d
  60         done
  61         for d in ${dirs1777}; do
  62                 install -m 1777 -d ${D}$d
  63         done
  64         for d in ${dirs2775}; do
  65                 install -m 2755 -d ${D}$d
  66         done
  67         for d in card cf net ram; do
  68                 ln -sf /media/$d ${D}/mnt/$d
  69         done
  70
  71         if [ -n "${MACHINE}" -a "${hostname}" = "openembedded" ]; then
  72                 echo ${MACHINE} > ${D}${sysconfdir}/hostname
  73         else
  74                 echo ${hostname} > ${D}${sysconfdir}/hostname
  75         fi
  76
  77         if [ -n "${DISTRO_NAME}" ]; then
  78                 echo -n "${DISTRO_NAME} " > ${D}${sysconfdir}/issue
  79                 echo -n "${DISTRO_NAME} " > ${D}${sysconfdir}/issue.net
  80                 if [ -n "${DISTRO_VERSION}" ]; then
  81                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue
  82                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue.net
  83                 fi
  84                 echo "\n \l" >> ${D}${sysconfdir}/issue
  85                 echo >> ${D}${sysconfdir}/issue
  86                 echo "%h"    >> ${D}${sysconfdir}/issue.net
  87                 echo >> ${D}${sysconfdir}/issue.net
  88         else
  89                install -m 0644 ${WORKDIR}/issue ${D}${sysconfdir}/issue
  90                install -m 0644 ${WORKDIR}/issue.net ${D}${sysconfdir}/issue.net
  91         fi
  92
  93         install -m 0644 ${WORKDIR}/fstab ${D}${sysconfdir}/fstab
  94         install -m 0644 ${WORKDIR}/filesystems ${D}${sysconfdir}/filesystems
  95         install -m 0644 ${WORKDIR}/usbd ${D}${sysconfdir}/default/usbd
  96         install -m 0644 ${WORKDIR}/profile ${D}${sysconfdir}/profile
  97         install -m 0755 ${WORKDIR}/share/dot.profile ${D}${sysconfdir}/skel/.profile
  98         install -m 0755 ${WORKDIR}/share/dot.bashrc ${D}${sysconfdir}/skel/.bashrc
  99         install -m 0644 ${WORKDIR}/inputrc ${D}${sysconfdir}/inputrc
 100         install -m 0644 ${WORKDIR}/nsswitch.conf ${D}${sysconfdir}/nsswitch.conf
 101         install -m 0644 ${WORKDIR}/host.conf ${D}${sysconfdir}/host.conf
 102         install -m 0644 ${WORKDIR}/motd ${D}${sysconfdir}/motd
 103
 104         for license in BSD GPL-2 LGPL-2 LGPL-2.1 Artistic; do
 105                 install -m 0644 ${WORKDIR}/licenses/$license ${D}${datadir}/common-licenses/
 106         done
 107
 108         ln -sf /proc/mounts ${D}${sysconfdir}/mtab
 109 }
 110
 111
 112 do_install_append_mnci () {
 113         rmdir ${D}/tmp
 114         mkdir -p ${D}${localstatedir}/tmp
 115         ln -s var/tmp ${D}/tmp
 116 }
 117
 118 do_install_append_nylon() {
 119         printf "" "" >${D}${sysconfdir}/resolv.conf
 120         rm -r ${D}/mnt/*
 121         rm -r ${D}/media
 122         rm -rf ${D}/tmp
 123         ln -sf /var/tmp ${D}/tmp
 124 }
 125
 126 do_install_append_openslug() {
 127         printf "" "" >${D}${sysconfdir}/resolv.conf
 128         rm -r ${D}/mnt/*
 129         rmdir ${D}/home/root
 130         install -m 0755 -d ${D}/root
 131         ln -s ../root ${D}/home/root
 132 }
 133
 134
 135 #some familiar stuff below
 136 do_install_append_familiar() {
 137         mkdir -p ${D}/${sysconfdir}/default/volatiles
 138         echo "l root root 644 /etc/resolv.conf /var/run/resolv.conf" > ${D}/${sysconfdir}/default/volatiles/01_resolv.conf
 139 }
 140
 141 do_install_append_openzaurus() {
 142         mkdir -p ${D}/${sysconfdir}/default/volatiles
 143         echo "l root root 644 /etc/resolv.conf /var/run/resolv.conf" > ${D}/${sysconfdir}/default/volatiles/01_resolv.conf
 144 }
 145
 146 pkg_postinst_familiar() {
 147 #!/bin/sh
 148 /etc/init.d/populate-volatile.sh
 149 }
 150
 151 pkg_postinst_openzaurus() {
 152 #!/bin/sh
 153 /etc/init.d/populate-volatile.sh
 154 }
 155
 156 DEPENDS_append_familiar = " initscripts"
 157 RDEPENDS_append_familiar = " initscripts (>= 1.0-r60)"
 158 DEPENDS_append_openzaurus = " initscripts"
 159 RDEPENDS_append_openzaurus = " initscripts (>= 1.0-r60)"
 160
 161
 162 PACKAGES = "${PN}-doc ${PN}"
 163 FILES_${PN} = "/"
 164 FILES_${PN}-doc = "${docdir} ${datadir}/common-licenses"
 165
 166
 167 # Unslung distribution specific packages follow ...
 168
 169 PACKAGES_unslung = "${PN}-unslung"
 170 PACKAGE_ARCH_${PN}-unslung = "nslu2"
 171 MAINTAINER_${PN}-unslung = "NSLU2 Linux <www.nslu2-linux.org>"
 172 RDEPENDS_${PN}-unslung = "nslu2-linksys-ramdisk"
 173 RPROVIDES_${PN}-unslung = "${PN}"
 174
 175 FILES_${PN}-unslung = ""
 176
 177 CONFFILES_${PN} = "${sysconfdir}/fstab ${sysconfdir}/hostname"
 178 CONFFILES_${PN}_nylon = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 179 CONFFILES_${PN}_openslug = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 180