org.handhelds.familiar/packages/binutils/binutils_csl-arm-20050416.bb

   1 SECTION = "devel"
   2 inherit autotools gettext
   3
   4 DESCRIPTION = "A GNU collection of binary utilities"
   5 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   6 LICENSE = "GPL"
   7 MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
   8 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/binutils-cvs"
   9 PV = "2.15.99+csl-arm+cvs20050416"
  10 PR = "r0"
  11 OVERRIDES_append = ":${TARGET_ARCH}-${TARGET_OS}"
  12 DEFAULT_PREFERENCE = "-1"
  13 DEFAULT_PREFERENCE_arm-linux = "1"
  14 DEFAULT_PREFERENCE_arm-linuxeabi = "1"
  15
  16 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  17
  18 FILES_${PN} = " \
  19         ${bindir}/${TARGET_PREFIX}* \
  20         ${libdir}/lib*-*.so \
  21         ${prefix}/${TARGET_SYS}/bin/*"
  22
  23 FILES_${PN}-dev = " \
  24         ${includedir} \
  25         ${libdir}/*.a \
  26         ${libdir}/*.la \
  27         ${libdir}/libbfd.so \
  28         ${libdir}/libopcodes.so"
  29
  30 FILES_${PN}-symlinks = " \
  31         ${bindir}/addr2line \
  32         ${bindir}/ar \
  33         ${bindir}/as \
  34         ${bindir}/c++filt \
  35         ${bindir}/gprof \
  36         ${bindir}/ld \
  37         ${bindir}/nm \
  38         ${bindir}/objcopy \
  39         ${bindir}/objdump \
  40         ${bindir}/ranlib \
  41         ${bindir}/readelf \
  42         ${bindir}/size \
  43         ${bindir}/strings \
  44         ${bindir}/strip"
  45
  46 SRC_URI = "cvs://anoncvs:anoncvs@sources.redhat.com/cvs/src;module=binutils;method=pserver;localdir=src;tag=binutils-csl-arm-2005q1-branch;date=20050416 \
  47      file://ld_makefile.patch;patch=1 \
  48      file://better_file_error.patch;patch=1 \
  49      file://signed_char_fix.patch;patch=1"
  50
  51 S = "${WORKDIR}/src"
  52 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  53
  54 EXTRA_OECONF = "--with-sysroot=${prefix} \
  55                 --program-prefix=${TARGET_PREFIX} \
  56                 --enable-shared"
  57
  58 # This is necessary due to a bug in the binutils Makefiles
  59 EXTRA_OEMAKE = "configure-build-libiberty all"
  60
  61 export AR = "${HOST_PREFIX}ar"
  62 export AS = "${HOST_PREFIX}as"
  63 export LD = "${HOST_PREFIX}ld"
  64 export NM = "${HOST_PREFIX}nm"
  65 export RANLIB = "${HOST_PREFIX}ranlib"
  66 export OBJCOPY = "${HOST_PREFIX}objcopy"
  67 export OBJDUMP = "${HOST_PREFIX}objdump"
  68
  69 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  70 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  71 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  72 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  73 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  74
  75 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  76 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  77
  78 export CC_FOR_BUILD = "${BUILD_CC}"
  79
  80 export CC = "${CCACHE} ${HOST_PREFIX}gcc"
  81
  82 do_configure () {
  83         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  84         oe_runconf
  85 }
  86
  87 do_stage () {
  88         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  89         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  90         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  91         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  92         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  93         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  94         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  95         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
  96         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
  97 }
  98
  99 do_install () {
 100         autotools_do_install
 101
 102         # We don't really need these, so we'll remove them...
 103         rm -rf ${D}${libdir}/ldscripts
 104
 105         # Fix the /usr/${TARGET_SYS}/bin/* links
 106         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
 107                 rm -f $l
 108                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 109                         | tr -s / \
 110                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 111         done
 112
 113         # Install the libiberty header
 114         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 115         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 116
 117         cd ${D}${bindir}
 118
 119         # Symlinks for ease of running these on the native target
 120         for p in ${TARGET_SYS}-* ; do
 121                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 122         done
 123 }