org.handhelds.familiar/packages/busybox/slingbox_1.00.bb

   1 DESCRIPTION = "SlingBox is a minimal version of BusyBox with just enough functionality \
   2 to enable ipkg to run on an Unslung NSLU2 device."
   3 HOMEPAGE = "http://www.busybox.net"
   4 LICENSE = "GPL"
   5 SECTION = "base"
   6 PRIORITY = "required"
   7 PR = "r6"
   8
   9 SRC_URI = "http://www.busybox.net/downloads/busybox-${PV}.tar.gz \
  10            file://defconfig \
  11            file://slingbox.patch;patch=1"
  12
  13 S = "${WORKDIR}/busybox-${PV}"
  14
  15 python () {
  16         # Don't build slingbox unless we're targeting an nslu2
  17         if bb.data.getVar("MACHINE", d, 1) != "nslu2":
  18                 raise bb.parse.SkipPackage("switchbox only builds for the Linksys NSLU2")
  19 }
  20
  21 export EXTRA_CFLAGS = "${CFLAGS}"
  22 EXTRA_OEMAKE_append = " CROSS=${HOST_PREFIX}"
  23
  24 PACKAGES = "${PN}"
  25 FILES_${PN} = "/"
  26 FILES_${PN}-doc = ""
  27 FILES_${PN}-dev = ""
  28 FILES_${PN}-locale = ""
  29
  30 inherit cml1
  31
  32 do_configure () {
  33         install -m 0644 ${WORKDIR}/defconfig ${S}/.config
  34         cml1_do_configure
  35 }
  36
  37 do_compile () {
  38         unset CFLAGS
  39         base_do_compile
  40 }
  41
  42 do_install () {
  43         oe_runmake 'PREFIX=${D}' install
  44 }