org.handhelds.familiar/packages/cyrus-sasl/cyrus-sasl_2.1.19.bb

   1 SECTION = "console/network"
   2 DEPENDS = "db3 openssl"
   3 DESCRIPTION = "Generic client/server library for SASL authentication."
   4 LICENSE = "BSD"
   5 PR = "r6"
   6
   7 SRC_URI = "ftp://ftp.andrew.cmu.edu/pub/cyrus-mail/cyrus-sasl-${PV}.tar.gz \
   8            file://berkdb.m4.patch;patch=1"
   9
  10 inherit autotools
  11
  12 acpaths = "-I ${S}/cmulocal -I ${S}/config -I ."
  13 CFLAGS_append = " -I${S}/include -I${S}/saslauthd/include"
  14 EXTRA_OECONF = "--enable-shared --enable-static --with-dblib=berkeley \
  15                 --with-bdb-libdir=${STAGING_LIBDIR} \
  16                 --with-bdb-incdir=${STAGING_INCDIR}/db4 \
  17                 --without-pam \
  18                 --without-opie --without-des"
  19
  20 FILES_${PN} += "${prefix}/lib/sasl2/*.so*"
  21 FILES_${PN}-dev += "${libdir}/sasl2/*.la ${libdir}/sasl2/*.a"
  22
  23 do_configure_prepend () {
  24         rm -f acinclude.m4 config/libtool.m4
  25 }
  26
  27 do_compile_prepend () {
  28         cd include
  29         ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} makemd5.c -o makemd5
  30         touch makemd5.o makemd5.lo makemd5
  31         cd ..
  32 }
  33
  34 do_stage () {
  35         oe_libinstall -so -a -C lib libsasl2 ${STAGING_LIBDIR}
  36         install -d ${STAGING_LIBDIR}/sasl2
  37         install -d ${STAGING_INCDIR}/sasl
  38         install -m 0644 ${S}/include/hmac-md5.h ${STAGING_INCDIR}/sasl/
  39         install -m 0644 ${S}/include/md5.h ${STAGING_INCDIR}/sasl/
  40         install -m 0644 ${S}/include/md5global.h ${STAGING_INCDIR}/sasl/
  41         install -m 0644 ${S}/include/sasl.h ${STAGING_INCDIR}/sasl/
  42         install -m 0644 ${S}/include/saslplug.h ${STAGING_INCDIR}/sasl/
  43         install -m 0644 ${S}/include/saslutil.h ${STAGING_INCDIR}/sasl/
  44         install -m 0644 ${S}/include/prop.h ${STAGING_INCDIR}/sasl/
  45 }
  46
  47 pkg_postinst () {
  48         grep cyrus /etc/passwd || adduser --disabled-password --home=/var/spool/mail --ingroup mail -g "Cyrus sasl" cyrus
  49         echo "cyrus" | saslpasswd2 -p -c cyrus
  50         chgrp mail /etc/sasldb2
  51 }