org.handhelds.familiar/packages/db/db_4.3.27.bb

   1 # Version 4 of the Berkeley DB from Sleepycat
   2 #
   3 # At present this package only installs the DB code
   4 # itself (shared libraries, .a in the dev package),
   5 # documentation and headers.
   6 #
   7 # The headers have the same names as those as v3
   8 # of the DB, only one version can be used *for dev*
   9 # at once - DB3 and DB4 can both be installed on the
  10 # same system at the same time if really necessary.
  11 SECTION = "libs"
  12 DESCRIPTION = "Berkeley DB v4."
  13 HOMEPAGE = "http://www.sleepycat.com"
  14 LICENSE = "BSD Sleepycat"
  15 PR = "r1"
  16
  17 SRC_URI = "http://downloads.sleepycat.com/${P}.tar.gz"
  18
  19 inherit autotools
  20
  21 # At present virtual/db is only in the db4 file, but it
  22 # should probably be in the other candidates (db3, gdbm)
  23 # because it doesn't make any sense to have multiple
  24 # relational databases on an embedded machine...
  25 PROVIDES += " db4 virtual/db"
  26
  27 # bitbake isn't quite clever enough to deal with sleepycat,
  28 # the distribution sits in the expected directory, but all
  29 # the builds must occur from a sub-directory.  The following
  30 # persuades bitbake to go to the right place
  31 S = "${WORKDIR}/${P}/build_unix"
  32
  33 # The executables go in a separate package - typically there
  34 # is no need to install these unless doing real database
  35 # management on the system.
  36 PACKAGES += " ${PN}-bin"
  37
  38 # Package contents
  39 FILES_${PN} = "${libdir}/libdb-4*so*"
  40 FILES_${PN}-bin = "${bindir}"
  41 # The dev package has the .so link (as in db3) and the .a's -
  42 # it is therefore incompatible (cannot be installed at the
  43 # same time) as the db3 package
  44 FILES_${PN}-dev = "${includedir} ${libdir}"
  45
  46 #configuration - set in local.conf to override
  47 DB4_CONFIG ?= "--enable-o_direct --enable-smallbuild"
  48 # Override the MUTEX setting here, the POSIX library is
  49 # the default - "POSIX/pthreads/library".
  50 # Don't ignore the nice SWP instruction on the ARM:
  51 EXTRA_OECONF = "${DB4_CONFIG}"
  52 # These enable the ARM assembler mutex code, this won't
  53 # work with thumb compilation...
  54 ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
  55 ARM_MUTEX_thumb = ""
  56 # NOTE: only tested on nslu2, should probably be _armeb
  57 EXTRA_OECONF_nslu2 = "${DB4_CONFIG} ${ARM_MUTEX}"
  58
  59 # Cancel the site stuff - it's set for db3 and destroys the
  60 # configure.
  61 CONFIG_SITE = ""
  62 do_configure() {
  63         echo '#!/bin/sh' >${S}/configure
  64         echo 'rm ${S}/configure' >>${S}/configure
  65         echo 'exec ../dist/configure "$@"' >>${S}/configure
  66         chmod a+x ${S}/configure
  67         oe_runconf
  68 }
  69
  70 do_stage() {
  71         # The .h files get installed read-only, the autostage
  72         # function just uses cp -pPR, so do this by hand
  73         # Install, for the moment, into include/db4 to avoid
  74         # interfering with the db3 headers (which have the same
  75         # name).  -I${STAGING_INCDIR}/db4 to use db4, as opposed
  76         # to db3.
  77         rm -rf ${STAGE_TEMP}
  78         mkdir -p ${STAGE_TEMP}
  79         oe_runmake DESTDIR="${STAGE_TEMP}" install_include
  80         mkdir -p ${STAGING_INCDIR}/db4
  81         cp -pPRf ${STAGE_TEMP}/${includedir}/* ${STAGING_INCDIR}/db4
  82         rm -rf ${STAGE_TEMP}
  83         oe_libinstall -so -C .libs libdb-4.3 ${STAGING_LIBDIR}
  84 }
  85
  86 do_install_append() {
  87         # The docs end up in /usr/docs - not right.
  88         if test -d "${D}/${prefix}/docs"
  89         then
  90                 mkdir -p "${D}/${datadir}"
  91                 test ! -d "${D}/${docdir}" || rmdir "${D}/${docdir}"
  92                 mv "${D}/${prefix}/docs" "${D}/${docdir}"
  93         fi
  94 }