org.handhelds.familiar/packages/dbus/dbus_0.23.bb

   1 SECTION = "base"
   2 PR = "r2"
   3 HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
   4 DESCRIPTION = "message bus system for applications to talk to one another"
   5 LICENSE = "GPL"
   6 DEPENDS = "expat glib-2.0 virtual/libintl"
   7
   8 SRC_URI = "http://freedesktop.org/software/dbus/releases/dbus-${PV}.tar.gz \
   9            file://cross.patch;patch=1 \
  10            file://tmpdir.patch;patch=1 \
  11            file://gettext.patch;patch=1 \
  12            file://dbus-1.init"
  13
  14 inherit autotools pkgconfig update-rc.d gettext
  15
  16 INITSCRIPT_NAME = "dbus-1"
  17 INITSCRIPT_PARAMS = "defaults"
  18
  19 CONFFILES_${PN} = "${sysconfdir}/dbus-1/system.conf ${sysconfdir}/dbus-1/session.conf"
  20
  21 FILES_${PN} = "${bindir}/dbus-daemon-1 ${bindir}/dbus-launch ${bindir}/dbus-cleanup-sockets ${bindir}/dbus-send ${bindir}/dbus-monitor ${sysconfdir} ${datadir}/dbus-1/services ${libdir}/lib*.so.*"
  22 FILES_${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-glib-tool"
  23
  24 pkg_postinst_dbus() {
  25 #!/bin/sh
  26
  27 # can't do adduser stuff offline
  28 if [ "x$D" != "x" ]; then
  29   exit 1
  30 fi
  31
  32 MESSAGEUSER=messagebus
  33 MESSAGEHOME=/var/run/dbus
  34
  35 mkdir -p $MESSAGEHOME || true
  36 chgrp "$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || addgroup "$MESSAGEUSER"
  37 chown "$MESSAGEUSER"."$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || adduser --system --home "$MESSAGEHOME" --no-create-home --disabled-password --ingroup "$MESSAGEUSER" "$MESSAGEUSER"
  38 }
  39
  40 EXTRA_OECONF = "--disable-qt --disable-gtk --disable-tests \
  41                 --disable-checks --disable-xml-docs --disable-doxygen-docs \
  42                 --with-xml=expat --without-x"
  43
  44 do_stage () {
  45         oe_libinstall -so -C dbus libdbus-1 ${STAGING_LIBDIR}
  46         oe_libinstall -so -C glib libdbus-glib-1 ${STAGING_LIBDIR}
  47
  48         autotools_stage_includes
  49
  50         mkdir -p ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
  51         install -m 0644 dbus/dbus-arch-deps.h ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
  52 }
  53
  54 do_install_append () {
  55         install -d ${D}${sysconfdir}/init.d
  56         install -m 0755 ${WORKDIR}/dbus-1.init ${D}${sysconfdir}/init.d/dbus-1
  57 }
  58
  59 python populate_packages_prepend () {
  60         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  61                 bb.data.setVar('PKG_dbus', 'dbus-1', d)
  62 }