org.handhelds.familiar/packages/dropbear/dropbear_0.45.bb

   1 DESCRIPTION = "Dropbear is a lightweight SSH and SCP Implementation"
   2 HOMEPAGE = "http://matt.ucc.asn.au/dropbear/dropbear.html"
   3 SECTION = "console/network"
   4 LICENSE = "MIT"
   5 DEPENDS = "zlib"
   6 PROVIDES = "ssh sshd"
   7 PR = "r2"
   8
   9 SRC_URI = "http://matt.ucc.asn.au/dropbear/releases/dropbear-${PV}.tar.bz2 \
  10            file://urandom-xauth-changes-to-options.h.patch;patch=1 \
  11            file://configure.patch;patch=1 \
  12            file://allow-nopw.patch \
  13            file://fix-2kb-keys.patch;patch=1 \
  14            file://chansession-security-fix.patch;patch=1 \
  15            file://init"
  16
  17 inherit autotools update-rc.d
  18
  19 INITSCRIPT_NAME = "dropbear"
  20 INITSCRIPT_PARAMS = "defaults 10"
  21
  22 CFLAGS_prepend = "-I. "
  23 LD = "${CC}"
  24
  25 SBINCOMMANDS = "dropbear dropbearkey dropbearconvert"
  26 BINCOMMANDS = "dbclient ssh scp"
  27 EXTRA_OEMAKE = 'MULTI=1 SCPPROGRESS=1 PROGRAMS="${SBINCOMMANDS} ${BINCOMMANDS}"'
  28
  29 do_configure_prepend() {
  30         if [ "${DISTRO_TYPE}" == "debug" ]; then
  31                 patch -p1 < ${WORKDIR}/allow-nopw.patch
  32         fi
  33 }
  34
  35 do_install() {
  36         install -d ${D}${sysconfdir} \
  37                    ${D}${sysconfdir}/init.d \
  38                    ${D}${sysconfdir}/default \
  39                    ${D}${sysconfdir}/dropbear \
  40                    ${D}${bindir} \
  41                    ${D}${sbindir} \
  42                    ${D}${localstatedir}
  43
  44         install -m 0755 dropbearmulti ${D}${sbindir}/
  45         for i in ${BINCOMMANDS}
  46         do
  47                 ln -s ${sbindir}/dropbearmulti ${D}${bindir}/$i
  48         done
  49         for i in ${SBINCOMMANDS}
  50         do
  51                 ln -s ./dropbearmulti ${D}${sbindir}/$i
  52         done
  53         cat ${WORKDIR}/init | sed -e 's,/etc,${sysconfdir},g' \
  54                                   -e 's,/usr/sbin,${sbindir},g' \
  55                                   -e 's,/var,${localstatedir},g' \
  56                                   -e 's,/usr/bin,${bindir},g' \
  57                                   -e 's,/usr,${prefix},g' > ${D}${sysconfdir}/init.d/dropbear
  58         chmod 755 ${D}${sysconfdir}/init.d/dropbear
  59 }
  60
  61 pkg_postrm_append () {
  62   if [ -f "${sysconfdir}/dropbear/dropbear_rsa_host_key" ]; then
  63         rm ${sysconfdir}/dropbear/dropbear_rsa_host_key
  64   fi
  65   if [ -f "${sysconfdir}/dropbear/dropbear_dss_host_key" ]; then
  66         rm ${sysconfdir}/dropbear/dropbear_dss_host_key
  67   fi
  68 }