org.handhelds.familiar/packages/gaim/gaim.inc

   1 SECTION = "x11/network"
   2 DESCRIPTION = "multi-protocol instant messaging client"
   3 MAINTAINER = "Mads Chr. Olesen <gaim@shiyee.dk>"
   4 LICENSE = "GPL"
   5
   6 DEPENDS = "gtk+ gnutls virtual/libintl"
   7 RRECOMMENDS_${PN} = "gaim-protocol-irc gaim-protocol-jabber"
   8
   9 PREMIRRORS_prepend () {
  10         ${SOURCEFORGE_MIRROR}   http://unc.dl.sourceforge.net/sourceforge
  11 }
  12 EXTRA_OECONF = "--disable-audio --disable-perl --disable-tcl --disable-deprecated"
  13
  14 FILES_${PN} = "${bindir} ${sbindir} ${libexecdir} ${libdir}/lib*.so.* \
  15             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
  16             /bin /sbin /lib/*.so* ${datadir}/${PN} ${libdir}/${PN}/*.so \
  17             ${datadir}/pixmaps ${datadir}/applications \
  18             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
  19             ${libdir}/bonobo/servers"
  20 FILES_${PN}-dev += "${libdir}/gaim/*.la"
  21
  22 inherit autotools gettext
  23
  24 python populate_packages_prepend () {
  25         root = bb.data.expand('${libdir}/gaim', d)
  26
  27         do_split_packages(d, root, '^lib(.*)\.so$',
  28                            output_pattern='gaim-protocol-%s',
  29                            description='GAIM protocol plugin for %s',
  30                            prepend=True,
  31                            aux_files_pattern=['${datadir}/pixmaps/gaim/status/default/%s.png', '${datadir}/pixmaps/gaim/smileys/default/%s_*'])
  32 }