org.handhelds.familiar/packages/gcc/gcc-cross_3.3.3.bb

   1 SECTION = "devel"
   2 include gcc_${PV}.bb
   3 inherit cross
   4 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/gcc-${PV}"
   5
   6 DEPENDS = "virtual/${TARGET_PREFIX}binutils virtual/${TARGET_PREFIX}libc-for-gcc"
   7 PROVIDES = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
   8
   9 # Files for these are defined in the main gcc.oe
  10 PACKAGES = "libgcc libstdc++ libg2c"
  11 INHIBIT_PACKAGE_STRIP = "1"
  12
  13 EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
  14                 --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
  15
  16 export CPPFLAGS = ""
  17 export CXXFLAGS = ""
  18 export CFLAGS = ""
  19 export LDFLAGS = ""
  20
  21 do_configure () {
  22         export CC="${BUILD_CC}"
  23         export AR="${TARGET_SYS}-ar"
  24         export RANLIB="${TARGET_SYS}-ranlib"
  25         export LD="${TARGET_SYS}-ld"
  26         export NM="${TARGET_SYS}-nm"
  27         rm -f ${CROSS_DIR}/lib/gcc-lib/${TARGET_SYS}/${PV}/libgcc_eh.a
  28         (cd ${S} && gnu-configize) || die "failure running gnu-configize"
  29         oe_runconf
  30 }
  31
  32 do_compile_prepend () {
  33         export CC="${BUILD_CC}"
  34         export AR_FOR_TARGET="${TARGET_SYS}-ar"
  35         export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
  36         export LD_FOR_TARGET="${TARGET_SYS}-ld"
  37         export NM_FOR_TARGET="${TARGET_SYS}-nm"
  38         export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
  39 }
  40
  41 do_stage_append () {
  42         for d in info man share/doc share/locale ; do
  43                 rm -rf ${CROSS_DIR}/$d
  44         done
  45
  46         # These aren't useful on the cross toolchain
  47         rm -f ${CROSS_DIR}/bin/*gcov
  48         rm -f ${CROSS_DIR}/bin/*gccbug
  49
  50         # Fix a few include links so cross builds are happier
  51         if [ ! -e ${STAGING_INCDIR}/c++ ]; then
  52                 mkdir -p ${STAGING_INCDIR}
  53                 rm -f ${STAGING_INCDIR}/c++
  54                 ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
  55                         ${STAGING_INCDIR}/
  56         fi
  57
  58         # We use libiberty from binutils
  59         rm -f ${CROSS_DIR}/lib/libiberty.a
  60
  61         # We probably don't need these
  62         rmdir ${CROSS_DIR}/include || :
  63
  64         # We don't really need to keep this around
  65         rm -rf ${CROSS_DIR}/share
  66 }
  67
  68 python do_package() {
  69         if bb.data.getVar('DEBIAN_NAMES', d, 1):
  70                 bb.data.setVar('PKG_libgcc', 'libgcc1', d)
  71         bb.build.exec_func('package_do_package', d)
  72 }
  73
  74 do_install () {
  75         oe_runmake 'DESTDIR=${D}' install
  76
  77         # Move libgcc_s into /lib
  78         mkdir -p ${D}${base_libdir}
  79         if [ "${BUILD_SYS}" == "${TARGET_SYS}" ]; then
  80                 # native builds drop one pathname component
  81                 mv -f ${D}${prefix}/lib/libgcc_s.so.* ${D}${base_libdir}
  82         else
  83                 mv -f ${D}${prefix}/*/lib/libgcc_s.so.* ${D}${base_libdir}
  84         fi
  85
  86         # Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
  87         TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
  88         mkdir -p ${D}${TGT_LIBDIR}
  89         mv -f ${D}${prefix}/*/lib/libstdc++.so.* ${D}${TGT_LIBDIR}
  90         mv -f ${D}${prefix}/*/lib/libg2c.so.* ${D}${TGT_LIBDIR}
  91
  92         # Manually run the target stripper since we won't get it run by
  93         # the packaging.
  94         ${TARGET_PREFIX}strip ${D}${TGT_LIBDIR}/libstdc++.so.*
  95         ${TARGET_PREFIX}strip ${D}${TGT_LIBDIR}/libg2c.so.*
  96         ${TARGET_PREFIX}strip ${D}${base_libdir}/libgcc_s.so.*
  97 }