org.handhelds.familiar/packages/glibc/glibc_2.3.2+cvs20040726.bb

   1 DESCRIPTION = "GNU C Library"
   2 HOMEPAGE = "http://www.gnu.org/software/libc/libc.html"
   3 LICENSE = "LGPL"
   4 SECTION = "libs"
   5 PRIORITY = "required"
   6 MAINTAINER = "Phil Blundell <pb@handhelds.org>"
   7
   8 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/glibc-cvs"
   9 PR = "r17"
  10
  11 GLIBC_ADDONS ?= "linuxthreads"
  12 GLIBC_EXTRA_OECONF ?= ""
  13
  14 # nptl needs unwind support in gcc, which can't be built without glibc.
  15 PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
  16 PROVIDES += "virtual/libintl virtual/libiconv"
  17 DEPENDS = "${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
  18 INHIBIT_DEFAULT_DEPS = "1"
  19
  20 #          file://noinfo.patch;patch=1
  21 #          file://ldconfig.patch;patch=1;pnum=0
  22 SRC_URI = "cvs://anoncvs@sources.redhat.com/cvs/glibc;module=libc;date=${@bb.data.getVar('PV', d, 1)[9:]} \
  23            file://arm-ioperm.patch;patch=1;pnum=0 \
  24            file://makeconfig.patch;patch=1;pnum=0 \
  25            file://ldd.patch;patch=1;pnum=0 \
  26            file://fhs-linux-paths.patch;patch=1 \
  27            file://arm-no-hwcap.patch;patch=1;pnum=0 \
  28            file://arm-memcpy.patch;patch=1;pnum=0 \
  29            file://arm-longlong.patch;patch=1;pnum=0 \
  30            file://arm-machine-gmon.patch;patch=1;pnum=0 \
  31            file://glibc-fp-byteorder.patch;patch=1 \
  32            \
  33            file://etc/ld.so.conf \
  34            file://generate-supported.mk"
  35
  36 # seems to fail on tls platforms
  37 SRC_URI_append_arm = " file://dyn-ldconfig.patch;patch=1;pnum=0"
  38
  39 SRC_URI_append_openmn = " file://ldsocache-varrun.patch;patch=1"
  40
  41 S = "${WORKDIR}/libc"
  42 B = "${WORKDIR}/build-${TARGET_SYS}"
  43
  44 inherit autotools
  45
  46 EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
  47                 --without-cvs --disable-profile --disable-debug --without-gd \
  48                 --enable-clocale=gnu \
  49                 --enable-add-ons=${GLIBC_ADDONS} \
  50                 --with-headers=${CROSS_DIR}/${TARGET_SYS}/include \
  51                 ${GLIBC_EXTRA_OECONF}"
  52
  53 do_configure () {
  54 # override this function to avoid the autoconf/automake/aclocal/autoheader
  55 # calls for now
  56 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
  57 # version check and doesn't really help with anything
  58         if [ -z "`which rpcgen`" ]; then
  59                 echo "rpcgen not found.  Install glibc-devel."
  60                 exit 1
  61         fi
  62         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
  63         CPPFLAGS="" oe_runconf
  64 }
  65
  66 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
  67           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
  68           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
  69
  70 do_compile () {
  71         # this really is arm specific
  72         touch ${S}/sysdeps/arm/framestate.c
  73         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
  74         unset LDFLAGS
  75         base_do_compile
  76         (
  77                 cd ${S}/sunrpc/rpcsvc
  78                 for r in ${rpcsvc}; do
  79                         h=`echo $r|sed -e's,\.x$,.h,'`
  80                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
  81                 done
  82         )
  83 }
  84
  85 do_stage() {
  86         rm -f ${STAGING_LIBDIR}/libc.so.6
  87         oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
  88                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
  89                    '${STAGING_LIBDIR}/libc.so.6' \
  90                    install-headers install-lib
  91
  92         install -d ${STAGING_INCDIR}/gnu \
  93                    ${STAGING_INCDIR}/bits \
  94                    ${STAGING_INCDIR}/rpcsvc
  95         install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
  96         install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
  97         install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
  98         for r in ${rpcsvc}; do
  99                 h=`echo $r|sed -e's,\.x$,.h,'`
 100                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
 101         done
 102         for i in libc.a libc_pic.a libc_nonshared.a; do
 103                 install -m 0644 ${B}/$i ${STAGING_LIBDIR}/ || die "failed to install $i"
 104         done
 105         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
 106         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so
 107
 108         rm -f ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6
 109         oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
 110                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 111                    '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
 112                    install-headers install-lib
 113
 114         install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
 115                    ${CROSS_DIR}/${TARGET_SYS}/include/bits \
 116                    ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
 117         install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
 118         install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
 119         install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
 120         for r in ${rpcsvc}; do
 121                 h=`echo $r|sed -e's,\.x$,.h,'`
 122                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
 123         done
 124
 125         for i in libc.a libc_pic.a libc_nonshared.a; do
 126                 install -m 0644 ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/ || die "failed to install $i"
 127         done
 128         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
 129         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
 130 }
 131
 132 include glibc-package.bbclass