org.handhelds.familiar/packages/glibc/glibc_2.3.3.bb

   1 PR = "r3"
   2 DESCRIPTION = "GNU C Library"
   3 HOMEPAGE = "http://www.gnu.org/software/libc/libc.html"
   4 LICENSE = "LGPL"
   5 SECTION = "libs"
   6 PRIORITY = "required"
   7
   8 DEFAULT_PREFERENCE = "-1"
   9 DEFAULT_PREFERENCE_mipsel = "0"
  10
  11 GLIBC_ADDONS ?= "linuxthreads"
  12 GLIBC_EXTRA_OECONF ?= ""
  13
  14 #
  15 # For now, we will skip building of a gcc package if it is a uclibc one
  16 # and our build is not a uclibc one, and we skip a glibc one if our build
  17 # is a uclibc build.
  18 #
  19 # See the note in gcc/gcc_3.4.0.oe
  20 #
  21
  22 python __anonymous () {
  23     import bb, re
  24     uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
  25     if uc_os:
  26         raise bb.parse.SkipPackage("incompatible with target %s" %
  27                                    bb.data.getVar('TARGET_OS', d, 1))
  28 }
  29
  30 PACKAGES = "glibc catchsegv sln nscd ldd localedef glibc-utils glibc-dev glibc-doc glibc-locale libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
  31
  32 # nptl needs unwind support in gcc, which can't be built without glibc.
  33 PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
  34 PROVIDES += "virtual/libintl virtual/libiconv"
  35 DEPENDS = "${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
  36 INHIBIT_DEFAULT_DEPS = "1"
  37
  38 libc_baselibs = "/lib/libc* /lib/libm* /lib/ld* /lib/libpthread* /lib/libresolv* /lib/librt* /lib/libutil* /lib/libnsl* /lib/libnss_files* /lib/libnss_compat* /lib/libnss_dns* /lib/libdl* /lib/libanl* /lib/libBrokenLocale*"
  39
  40 FILES_${PN} = "${sysconfdir} ${libc_baselibs} /sbin/ldconfig ${libexecdir} ${datadir}/zoneinfo"
  41 FILES_ldd = "${bindir}/ldd"
  42 FILES_libsegfault = "/lib/libSegFault*"
  43 FILES_glibc-extra-nss = "/lib/libnss*"
  44 FILES_sln = "/sbin/sln"
  45 FILES_glibc-dev_append = " ${libdir}/*.o ${bindir}/rpcgen"
  46 FILES_nscd = "${sbindir}/nscd*"
  47 FILES_glibc-utils = "${bindir} ${sbindir}"
  48 FILES_glibc-gconv = "${libdir}/gconv"
  49 FILES_catchsegv = "${bindir}/catchsegv"
  50 DEPENDS_catchsegv = "libsegfault"
  51 FILES_glibc-pcprofile = "/lib/libpcprofile.so"
  52 FILES_glibc-thread-db = "/lib/libthread_db*"
  53 FILES_localedef = "${bindir}/localedef"
  54 RPROVIDES_glibc-dev += "libc-dev"
  55
  56 SRC_URI = "ftp://ftp.gnu.org/gnu/glibc/glibc-${PV}.tar.gz \
  57            ftp://ftp.gnu.org/pub/gnu/glibc/glibc-linuxthreads-${PV}.tar.gz \
  58            file://etc/ld.so.conf \
  59            file://generate-supported.mk"
  60
  61 S = "${WORKDIR}/glibc-${PV}"
  62 B = "${WORKDIR}/build-${TARGET_SYS}"
  63
  64 inherit autotools
  65
  66 EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
  67                 --without-cvs --disable-profile --disable-debug --without-gd \
  68                 --enable-clocale=gnu \
  69                 --enable-add-ons=${GLIBC_ADDONS} \
  70                 --with-headers=${CROSS_DIR}/${TARGET_SYS}/include \
  71                 ${GLIBC_EXTRA_OECONF}"
  72
  73 EXTRA_OECONF += "${@get_glibc_fpu_setting(bb, d)}"
  74
  75 def get_glibc_fpu_setting(bb, d):
  76         if bb.data.getVar('TARGET_FPU', d, 1) in [ 'soft' ]:
  77                 return "--without-fp"
  78         return ""
  79
  80 glibc_do_unpack () {
  81         mv "${WORKDIR}/linuxthreads" "${WORKDIR}/linuxthreads_db" "${S}/"
  82 }
  83
  84 python do_unpack () {
  85         bb.build.exec_func('base_do_unpack', d)
  86         bb.build.exec_func('glibc_do_unpack', d)
  87 }
  88
  89 do_configure () {
  90 # override this function to avoid the autoconf/automake/aclocal/autoheader
  91 # calls for now
  92 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
  93 # version check and doesn't really help with anything
  94         if [ -z "`which rpcgen`" ]; then
  95                 echo "rpcgen not found.  Install glibc-devel."
  96                 exit 1
  97         fi
  98         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
  99         CPPFLAGS="" oe_runconf
 100 }
 101
 102 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
 103           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
 104           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
 105
 106 do_compile () {
 107         # this really is arm specific
 108         touch ${S}/sysdeps/arm/framestate.c
 109         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 110         unset LDFLAGS
 111         base_do_compile
 112         (
 113                 cd ${S}/sunrpc/rpcsvc
 114                 for r in ${rpcsvc}; do
 115                         h=`echo $r|sed -e's,\.x$,.h,'`
 116                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 117                 done
 118         )
 119 }
 120
 121 do_stage() {
 122         rm -f ${STAGING_LIBDIR}/libc.so.6
 123         oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
 124                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 125                    '${STAGING_LIBDIR}/libc.so.6' \
 126                    install-headers install-lib
 127
 128         install -d ${STAGING_INCDIR}/gnu \
 129                    ${STAGING_INCDIR}/bits \
 130                    ${STAGING_INCDIR}/rpcsvc
 131         install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
 132         install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
 133         install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
 134         for r in ${rpcsvc}; do
 135                 h=`echo $r|sed -e's,\.x$,.h,'`
 136                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
 137         done
 138         for i in libc.a libc_pic.a libc_nonshared.a; do
 139                 install -m 0644 ${B}/$i ${STAGING_LIBDIR}/ || die "failed to install $i"
 140         done
 141         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
 142         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so
 143
 144         rm -f ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6
 145         oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
 146                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 147                    '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
 148                    install-headers install-lib
 149
 150         install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
 151                    ${CROSS_DIR}/${TARGET_SYS}/include/bits \
 152                    ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
 153         install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
 154         install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
 155         install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
 156         for r in ${rpcsvc}; do
 157                 h=`echo $r|sed -e's,\.x$,.h,'`
 158                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
 159         done
 160
 161         for i in libc.a libc_pic.a libc_nonshared.a; do
 162                 install -m 0644 ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/ || die "failed to install $i"
 163         done
 164         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
 165         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
 166 }
 167
 168 include glibc-package.bbclass