org.handhelds.familiar/packages/gnome/files/gtk-doc.m4

   1 dnl -*- mode: autoconf -*-
   2
   3 # serial 1
   4
   5 dnl Usage:
   6 dnl   GTK_DOC_CHECK([minimum-gtk-doc-version])
   7 AC_DEFUN([GTK_DOC_CHECK],
   8 [
   9   AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
  10   AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
  11   dnl for overriding the documentation installation directory
  12   AC_ARG_WITH(html-dir,
  13     AC_HELP_STRING([--with-html-dir=PATH], [path to installed docs]),,
  14     [with_html_dir='${datadir}/gtk-doc/html'])
  15   HTML_DIR="$with_html_dir"
  16   AC_SUBST(HTML_DIR)
  17
  18   dnl enable/disable documentation building
  19   AC_ARG_ENABLE(gtk-doc,
  20     AC_HELP_STRING([--enable-gtk-doc],
  21                    [use gtk-doc to build documentation [default=no]]),,
  22     enable_gtk_doc=no)
  23
  24   have_gtk_doc=no
  25   if test -z "$PKG_CONFIG"; then
  26     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  27   fi
  28   if test "$PKG_CONFIG" != "no" && $PKG_CONFIG --exists gtk-doc; then
  29     have_gtk_doc=yes
  30   fi
  31
  32   dnl do we want to do a version check?
  33 ifelse([$1],[],,
  34   [gtk_doc_min_version=$1
  35   if test "$have_gtk_doc" = yes; then
  36     AC_MSG_CHECKING([gtk-doc version >= $gtk_doc_min_version])
  37     if $PKG_CONFIG --atleast-version $gtk_doc_min_version gtk-doc; then
  38       AC_MSG_RESULT(yes)
  39     else
  40       AC_MSG_RESULT(no)
  41       have_gtk_doc=no
  42     fi
  43   fi
  44 ])
  45   if test x$enable_gtk_doc = xyes; then
  46     if test "$have_gtk_doc" != yes; then
  47       enable_gtk_doc=no
  48     fi
  49   fi
  50
  51   AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
  52   AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL, test -n "$LIBTOOL")
  53 ])