org.handhelds.familiar/packages/gtk+/gtk+_2.4.13.bb

   1 LICENSE = "LGPL"
   2 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   3 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   4 HOMEPAGE = "http://www.gtk.org"
   5 SECTION = "libs"
   6 PRIORITY = "optional"
   7 MAINTAINER = "Philip Blundell <pb@handhelds.org>"
   8 DEPENDS = "glib-2.0 pango atk jpeg libpng xext libxcursor"
   9 PR = "r6"
  10
  11 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.4/gtk+-${PV}.tar.bz2 \
  12            file://no-demos.patch;patch=1 \
  13            file://no-xwc.patch;patch=1;pnum=0 \
  14            file://automake-lossage.patch;patch=1 \
  15            file://gtk+-handhelds.patch;patch=1 \
  16            file://hardcoded_libtool.patch;patch=1 \
  17            file://spinbutton.patch;patch=1 \
  18            file://disable-tooltips.patch;patch=1 \
  19            file://gtklabel-resize-patch;patch=1 \
  20            file://menu-deactivate.patch;patch=1 \
  21            file://xsettings.patch;patch=1 \
  22            file://scroll-timings.patch;patch=1 \
  23            file://gtk-doc.m4 \
  24            file://small-gtkfilesel.patch;patch=1 \
  25            file://single-click.patch;patch=1"
  26
  27 inherit autotools pkgconfig flow-lossage
  28
  29 do_configure_prepend() {
  30         install -d m4
  31         install ${WORKDIR}/gtk-doc.m4 m4/
  32 }
  33
  34 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  35         ${bindir}/gtk-query-immodules-2.0 \
  36         ${libdir}/lib*.so.* \
  37         ${datadir}/themes ${sysconfdir}"
  38 FILES_${PN}-dev += "${datadir}/gtk-2.0/include ${libdir}/gtk-2.0/include ${bindir}/gdk-pixbuf-csource"
  39
  40 RRECOMMENDS_${PN} = "glibc-gconv-iso8859-1"
  41
  42 EXTRA_OECONF = "--without-libtiff --disable-xkb"
  43 # --disable-cruft
  44
  45 LIBV = "2.4.0"
  46
  47 do_stage () {
  48         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  49         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  50         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  51         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  52
  53         autotools_stage_includes
  54
  55         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  56         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  57
  58         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  59 }
  60
  61 do_install_append () {
  62         install -d ${D}${sysconfdir}/gtk-2.0
  63 }
  64
  65 python populate_packages_prepend () {
  66         import os.path
  67
  68         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  69         loaders_root = os.path.join(gtk_libdir, 'loaders')
  70         immodules_root = os.path.join(gtk_libdir, 'immodules')
  71
  72         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  73         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', 'gtk-query-immodules > /etc/gtk-2.0/gtk.immodules')
  74
  75         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  76                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  77 }