org.handhelds.familiar/packages/gtk+/gtk+_2.6.1.bb

   1 LICENSE = "LGPL"
   2 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   3 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   4 HOMEPAGE = "http://www.gtk.org"
   5 SECTION = "libs"
   6 PRIORITY = "optional"
   7 MAINTAINER = "Philip Blundell <pb@handhelds.org>"
   8 DEPENDS = "glib-2.0 pango atk jpeg libpng xext libxcursor gtk-doc"
   9 PR = "r2"
  10
  11 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.6/gtk+-${PV}.tar.bz2 \
  12            file://no-demos.patch;patch=1 \
  13            file://no-xwc.patch;patch=1 \
  14            file://automake-lossage.patch;patch=1 \
  15            file://gtk+-handhelds.patch;patch=1 \
  16            file://spinbutton.patch;patch=1 \
  17            file://hardcoded_libtool.patch;patch=1 \
  18            file://disable-tooltips.patch;patch=1 \
  19            file://gtklabel-resize-patch;patch=1 \
  20            file://menu-deactivate.patch;patch=1 \
  21            file://xsettings.patch;patch=1 \
  22            file://scroll-timings.patch;patch=1 \
  23            file://small-gtkfilesel.patch;patch=1 \
  24            file://single-click.patch;patch=1 \
  25            file://ltr.patch;patch=1"
  26
  27 inherit autotools pkgconfig flow-lossage
  28
  29 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  30         ${bindir}/gtk-query-immodules-2.0 \
  31         ${libdir}/lib*.so.* \
  32         ${datadir}/themes ${sysconfdir}"
  33 FILES_${PN}-dev += "${datadir}/gtk-2.0/include ${libdir}/gtk-2.0/include ${bindir}/gdk-pixbuf-csource"
  34
  35 RRECOMMENDS_${PN} = "glibc-gconv-iso8859-1"
  36
  37 EXTRA_OECONF = "--without-libtiff --disable-xkb"
  38 # --disable-cruft
  39
  40 LIBV = "2.4.0"
  41
  42 do_stage () {
  43         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  44         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  45         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  46         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  47
  48         autotools_stage_includes
  49
  50         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  51         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  52
  53         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  54 }
  55
  56 do_install_append () {
  57         install -d ${D}${sysconfdir}/gtk-2.0
  58 }
  59
  60 python populate_packages_prepend () {
  61         import os.path
  62
  63         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  64         loaders_root = os.path.join(gtk_libdir, 'loaders')
  65         immodules_root = os.path.join(gtk_libdir, 'immodules')
  66
  67         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  68         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', 'gtk-query-immodules > /etc/gtk-2.0/gtk.immodules')
  69
  70         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  71                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  72 }