org.handhelds.familiar/packages/gtk+/gtk+_2.8.0.bb

   1 LICENSE = "LGPL"
   2 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   3 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   4 HOMEPAGE = "http://www.gtk.org"
   5 SECTION = "libs"
   6 PRIORITY = "optional"
   7 MAINTAINER = "Philip Blundell <pb@handhelds.org>"
   8 DEPENDS = "glib-2.0 pango atk jpeg libpng xext libxcursor gtk-doc libgcrypt cairo"
   9 PR = "r1"
  10
  11 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.8/gtk+-${PV}.tar.bz2 \
  12            file://no-xwc.patch;patch=1 \
  13            file://automake-lossage.patch;patch=1 \
  14            file://spinbutton.patch;patch=1 \
  15            file://hardcoded_libtool.patch;patch=1 \
  16            file://disable-tooltips.patch;patch=1 \
  17            file://gtklabel-resize-patch;patch=1 \
  18            file://menu-deactivate.patch;patch=1 \
  19            file://xsettings.patch;patch=1 \
  20            file://pkg-config-pangoft2.patch;patch=1 \
  21            file://scroll-timings.patch;patch=1 \
  22            file://small-gtkfilesel.patch;patch=1 \
  23            file://migration.patch;patch=1;pnum=0"
  24 #           file://no-demos.patch;patch=1
  25 #           file://gtk+-handhelds.patch;patch=1
  26 #          file://single-click.patch;patch=1
  27
  28 inherit autotools pkgconfig
  29
  30 FILES_${PN} = "${bindir}/gdk-pixbuf-query-loaders \
  31         ${bindir}/gtk-query-immodules-2.0 \
  32         ${libdir}/lib*.so.* \
  33         ${datadir}/themes ${sysconfdir} \
  34         ${libdir}/gtk-2.0/${LIBV}/engines/libpixmap.so"
  35 FILES_${PN}-dev += "${datadir}/gtk-2.0/include ${libdir}/gtk-2.0/include ${bindir}/gdk-pixbuf-csource"
  36
  37 RRECOMMENDS_${PN} = "glibc-gconv-iso8859-1"
  38
  39 EXTRA_OECONF = "--without-libtiff --disable-xkb --disable-glibtest --enable-display-migration"
  40 # --disable-cruft
  41
  42 LIBV = "2.4.0"
  43
  44 do_stage () {
  45         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  46         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  47         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  48         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  49
  50         autotools_stage_includes
  51
  52         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  53         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  54
  55         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  56 }
  57
  58 do_install_append () {
  59         install -d ${D}${sysconfdir}/gtk-2.0
  60 }
  61
  62 postinst_prologue() {
  63 if [ "x$D" != "x" ]; then
  64   exit 1
  65 fi
  66
  67 }
  68
  69 python populate_packages_prepend () {
  70         import os.path
  71
  72         prologue = bb.data.getVar("postinst_prologue", d, 1)
  73
  74         gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
  75         loaders_root = os.path.join(gtk_libdir, 'loaders')
  76         immodules_root = os.path.join(gtk_libdir, 'immodules')
  77
  78         do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
  79         do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules > /etc/gtk-2.0/gtk.immodules')
  80
  81         if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
  82                 bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
  83 }