org.handhelds.familiar/packages/libxine/libxine-fb_1.0.bb

   1 DESCRIPTION = "libxine is a multimedia library with support for many common audio and video formats \
   2 This version is configured for the usage with framebuffer based environments"
   3 SECTION = "libs"
   4 PRIORITY = "optional"
   5 LICENSE = "GPL"
   6 DEPENDS = "zlib libogg tremor libmad libmodplug"
   7 PROVIDES = "virtual/libxine"
   8 PR = "r0"
   9
  10 inherit autotools pkgconfig gettext
  11
  12 SRC_URI = "http://heanet.dl.sourceforge.net/sourceforge/xine/xine-lib-${PV}.tar.gz \
  13         file://cpu-${PV}.patch;patch=1 \
  14         file://configure-${PV}.patch;patch=1 \
  15         file://demuxogg.patch;patch=1 \
  16         file://fix-syntax.patch;patch=1 \
  17         file://libxine-cut-memusage.patch;patch=1 \
  18         file://libxine-ffmpeg-enable-arm.patch;patch=1 \
  19         file://libxine-libvorbis.patch;patch=1 \
  20         file://libxine-tremor-autoconf.patch;patch=1 \
  21         file://mpegvideo-static-inlinine.patch;patch=1 \
  22         file://libxine-arm-configure.patch;patch=1 \
  23         file://no-caca.patch;patch=1 "
  24 S = "${WORKDIR}/xine-lib-${PV}"
  25
  26 SOV = "1.0.7"
  27
  28 EXTRA_OECONF="-with-zlib-path=${STAGING_DIR}/${HOST_SYS} \
  29         --with-vorbis-prefix=${STAGING_DIR}/${HOST_SYS} \
  30         --disable-oggtest \
  31         --with-ogg-prefix=${STAGING_DIR}/${HOST_SYS} \
  32         --disable-altivec --disable-vis --disable-mlib \
  33         --enable-shared --disable-static \
  34         --disable-fb --disable-alsa --disable-vcd \
  35         --disable-asf --disable-faad --disable-iconv \
  36         --disable-aalib                            \
  37         --without-v4l --without-arts --without-sdl \
  38         --disable-dxr3 --without-xv --without-xvmc \
  39         --without-xxmc --without-Xshm --without-x "
  40
  41 do_compile() {
  42         oe_runmake LIBTOOL=${S}/${TARGET_SYS}-libtool
  43 }
  44
  45 do_install() {
  46         oe_runmake DESTDIR=${D} LIBTOOL=${S}/${TARGET_SYS}-libtool install
  47 }
  48
  49 HEADERS="src/xine-engine/xineintl.h src/xine-utils/xineutils.h            \
  50         src/xine-engine/xine_internal.h  src/xine-engine/xine_plugin.h    \
  51         src/xine-utils/xine_buffer.h     src/xine-engine/video_out.h      \
  52         src/xine-engine/buffer.h         src/xine-engine/vo_scale.h       \
  53         src/xine-engine/configfile.h     src/xine-utils/attributes.h      \
  54         src/xine-engine/info_helper.h    src/xine-engine/scratch.h        \
  55         src/xine-engine/audio_decoder.h  src/input/input_plugin.h         \
  56         src/xine-engine/spu_decoder.h    src/xine-engine/audio_out.h      \
  57         src/xine-engine/io_helper.h      src/xine-engine/video_decoder.h  \
  58         src/xine-engine/broadcaster.h    src/xine-engine/metronom.h       \
  59         src/xine-utils/xmllexer.h        src/xine-engine/osd.h            \
  60         src/xine-engine/video_overlay.h  src/xine-utils/xmlparser.h       \
  61         src/xine-utils/compat.h          src/xine-engine/plugin_catalog.h \
  62         src/xine-engine/post.h           src/demuxers/demux.h             \
  63         src/xine-engine/resample.h       lib/os_types.h                   \
  64         src/xine-engine/refcounter.h"
  65
  66 do_stage() {
  67         install -d ${STAGING_INCDIR}/xine
  68
  69         install -m 0644 ${S}/include/xine.h ${STAGING_INCDIR}
  70
  71         for file in ${HEADERS}; do
  72                 cp ${S}/$file ${STAGING_INCDIR}/xine/`basename $file`
  73         done
  74
  75         oe_libinstall -so -C src/xine-engine libxine ${STAGING_LIBDIR}
  76 }
  77
  78 python populate_packages_prepend () {
  79         plugindir = bb.data.expand('${libdir}/xine/plugins/1.0.0', d)
  80         do_split_packages(d, plugindir, '^xineplug_(.*)\.so$', 'libxine-plugin-%s', 'Xine plugin for %s', extra_depends='' )
  81
  82         postdir = bb.data.expand('${libdir}/xine/plugins/1.0.0/post', d)
  83         do_split_packages(d, postdir, '^xineplug_(.*)\.so$', 'libxine-plugin-%s', 'Xine plugin for %s', extra_depends='' )
  84
  85         fontdir = bb.data.expand('${datadir}/xine/libxine1/fonts', d)
  86         do_split_packages(d, fontdir, '^(.*).xinefont.gz$', 'libxine-font-%s', 'Xine font %s', extra_depends='' )
  87 }
  88
  89 # Omit the annoying xine-config in ${bindir}
  90 FILES_${PN}="${libdir}/*.so*"
  91
  92 # And include it in the dev package
  93 FILES_${PN}-dev += " ${bindir}"
  94