org.handhelds.familiar/packages/linux/handhelds-pxa_2.4.19-rmk6-pxa1-hh39.bb

   1 SECTION = "kernel"
   2 DESCRIPTION = "handhelds.org Linux kernel for PXA25x based devices."
   3 MAINTAINER = "Phil Blundell <pb@handhelds.org>"
   4 LICENSE = "GPL"
   5 PR = "r1"
   6
   7 KERNEL_CCSUFFIX = "-3.3.3"
   8 COMPATIBLE_HOST = "arm.*-linux"
   9
  10 SRC_URI = "${HANDHELDS_CVS};module=linux/kernel;tag=${@'K' + bb.data.getVar('PV',d,1).replace('.', '-')} \
  11            file://defconfig-${PACKAGE_ARCH} \
  12            file://ipaq-hal.init \
  13            file://linux-2.4-mmc-debugging.patch;patch=1 \
  14            file://linux-2.4-usb-gadget.patch;patch=1 \
  15            file://usb-gadget-ether-compat.patch;patch=1 \
  16            file://linux-2.4-no-short-loads.patch;patch=1 \
  17            file://linux-2.4-cpufreq.patch;patch=1"
  18
  19 S = "${WORKDIR}/kernel"
  20
  21 inherit kernel update-rc.d
  22
  23 K_MAJOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[0]}"
  24 K_MINOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[1]}"
  25 K_MICRO = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[2]}"
  26 RMKV    = "${@bb.data.getVar('PV',d,1).split('-')[1].split('rmk')[-1]}"
  27 PXAV    = "${@bb.data.getVar('PV',d,1).split('-')[2].split('pxa')[-1]}"
  28 HHV     = "${@bb.data.getVar('PV',d,1).split('-')[3].split('hh')[-1]}"
  29
  30 KERNEL_PRIORITY = "${@'%d' % (int(bb.data.getVar('K_MAJOR',d,1)) * 100000000 + int(bb.data.getVar('K_MINOR',d,1)) * 1000000 + int(bb.data.getVar('K_MICRO',d,1)) * 10000 + int(bb.data.getVar('RMKV',d,1)) * 1000 + int(bb.data.getVar('PXAV',d,1)) * 100 + float(bb.data.getVar('HHV',d,1)))}"
  31
  32 module_conf_h3900_asic = "alias ipaq_hal_3900 h3900_asic"
  33 module_conf_h5400_asic = "alias ipaq_hal_5400 h5400_asic"
  34 module_conf_pxa_ir = "alias irda0 pxa_ir"
  35 module_conf_i2c-algo-pxa = "options i2c-algo-pxa pxa_scan=0"
  36 module_conf_pcmcia_core = "options pcmcia_core ignore_cis_vcc=1"
  37 module_conf_ppp_async = "alias ppp0 ppp_async"
  38 module_conf_orinoco_cs = "options orinoco_cs ignore_cis_vcc=1"
  39 module_conf_hostap_cs = "options hostap_cs ignore_cis_vcc=1"
  40
  41 module_autoload_h3600_ts = "h3600_ts"
  42 module_autoload_apm = "apm"
  43 module_autoload_af_packet = "af_packet"
  44 module_autoload_usb-ohci-h5400 = "usb-ohci-h5400"
  45 module_autoload_ppp_async = "ppp_async"
  46 module_autoload_usb-eth = "usb-eth"
  47 module_autoload_h5400_buzzer = "h5400_buzzer"
  48 module_autoload_mmc_h5400 = "mmc_h5400"
  49 module_autoload_h5400-audio = "h5400-audio"
  50 module_autoload_h3900-uda1380 = "h3900-uda1380"
  51 module_autoload_sa1100-rtc = "sa1100-rtc"
  52 module_autoload_ak4535 = "ak4535"
  53 module_autoload_i2c-adap-pxa = "i2c-adap-pxa"
  54
  55 FILES_kernel += "/etc/init.d/ipaq-hal"
  56 INITSCRIPT_NAME = "ipaq-hal"
  57 INITSCRIPT_PARAMS = "start 21 S ."
  58
  59 # extra depends
  60 RDEPENDS_kernel-module-h5400-audio = "kernel-module-ak4535 kernel-module-i2c-adap-pxa"
  61 RDEPENDS_kernel-module-h3900-uda1380 = "kernel-module-uda1380 kernel-module-i2c-adap-pxa"
  62
  63 do_configure_prepend() {
  64         install -m 0644 ${WORKDIR}/defconfig-${PACKAGE_ARCH} ${S}/.config
  65 }
  66
  67 do_install_append() {
  68         install -d ${D}${sysconfdir}/init.d
  69         install ${WORKDIR}/ipaq-hal.init ${D}${sysconfdir}/init.d/ipaq-hal
  70 }