org.handhelds.familiar/packages/linux/opensimpad_2.4.25-vrs2-pxa1-jpm1.bb

   1 DESCRIPTION = "Linux kernel for the SIEMENS SIMpad family of devices."
   2 MAINTAINER = "Frederic Devernay <frederic.devernay@m4x.org>"
   3 SECTION = "kernel"
   4 LICENSE = "GPL"
   5 KV = "${@bb.data.getVar('PV',d,True).split('-')[0]}"
   6 VRSV = "${@bb.data.getVar('PV',d,True).split('-')[1]}"
   7 PXAV = "${@bb.data.getVar('PV',d,True).split('-')[2]}"
   8 JPMV = "${@bb.data.getVar('PV',d,True).split('-')[3]}"
   9 PR = "r22"
  10
  11 FILESPATH = "${FILE_DIRNAME}/opensimpad-${PV}:${FILE_DIRNAME}/opensimpad:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
  12
  13 SRC_URI = "ftp://ftp.kernel.org/pub/linux/kernel/v2.4/linux-${KV}.tar.bz2 \
  14            file://${KV}-${VRSV}.patch;patch=1 \
  15            file://${KV}-${VRSV}-${PXAV}.patch;patch=1 \
  16            file://${KV}-${VRSV}-${PXAV}-${JPMV}.patch;patch=1 \
  17            file://sound-volume-reversed.patch;patch=1 \
  18            file://disable-pcmcia-probe.patch;patch=1 \
  19            file://mkdep.patch;patch=1 \
  20            file://defconfig-${MACHINE} \
  21            http://www.openswan.org/download/old/openswan-2.2.0-kernel-2.4-klips.patch.gz;patch=1 \
  22            file://mipv6-1.1-v2.4.25.patch;patch=1 \
  23            file://simpad-backlight-if.patch;patch=1 \
  24            file://simpad-switches-input.patch;patch=1 \
  25            file://simpad-switches-input2.patch;patch=1 \
  26            file://simpad-apm.diff;patch=1;pnum=0 \
  27            file://simpad-ts-noninput.patch;patch=1 \
  28            file://simpad-pm-updates.patch;patch=1;pnum=0 \
  29            file://support-128mb-ram.patch;patch=1 \
  30            file://mmc-spi.patch;patch=1 \
  31            file://iw249_we17-13.diff;patch=1 \
  32            file://iw240_we18-5.diff;patch=1 \
  33 "
  34
  35 # apply this when we have a patch that allows building with gcc 3.x:
  36 # SRC_URI_append = file://gcc-3.3.patch;patch=1
  37 # SRC_URI_append = file://machtune-args.patch;patch=1
  38
  39 S = "${WORKDIR}/linux-${KV}"
  40
  41 inherit kernel
  42
  43 KERNEL_CCSUFFIX = "-3.3.4"
  44 COMPATIBLE_HOST = "arm.*-linux"
  45
  46 SIMPAD_MEM     = ${@bb.data.getVar("SIMPAD_MEMORY_SIZE",d,1)  or "32"}
  47 SIMPAD_RD      = ${@bb.data.getVar("SIMPAD_RAMDISK_SIZE",d,1) or "32"}
  48 export CMDLINE = ${@bb.data.getVar("SIMPAD_CMDLINE",d,1) or  "mtdparts=sa1100:512k(boot),1m(kernel),14848k(root),-(home) console=ttySA root=1f02 noinitrd jffs2_orphaned_inodes=delete rootfstype=jffs2 "}
  49 EXTRA_OEMAKE = ""
  50
  51 module_conf_sa1100_ir = "alias irda0 sa1100_ir"
  52
  53 do_configure() {
  54         install -m 0644 ${WORKDIR}/defconfig-${MACHINE} ${S}/.config || die "No default configuration for ${MACHINE} available."
  55
  56         mem=${SIMPAD_MEM}
  57         rd=${SIMPAD_RD}
  58         mempos=`echo "obase=16; $mem * 1024 * 1024" | bc`
  59         rdsize=`echo "$rd * 1024" | bc`
  60         total=`expr $mem + $rd`
  61         addr=`echo "obase=16; ibase=16; C0000000 + $mempos" | bc`
  62
  63         if [ "$rd" == "0" ]
  64         then
  65                 echo "# CONFIG_MTD_MTDRAM is not set" >> ${S}/.config
  66         else
  67                 echo "CONFIG_MTD_MTDRAM=y"           >> ${S}/.config
  68                 echo "CONFIG_MTDRAM_TOTAL_SIZE=$rdsize"     >> ${S}/.config
  69                 echo "CONFIG_MTDRAM_ERASE_SIZE=1"           >> ${S}/.config
  70                 echo "CONFIG_MTDRAM_ABS_POS=$addr"          >> ${S}/.config
  71         fi
  72         if [ "$total" == "128" ]
  73         then
  74                 echo "CCONFIG_SA1100_SIMPAD_128M=y"           >> ${S}/.config
  75         else
  76                 echo "# CONFIG_SA1100_SIMPAD_128M is not set" >> ${S}/.config
  77         fi
  78         if [ "$total" == "32" ]
  79         then
  80                 echo "CONFIG_SA1100_SIMPAD_SINUSPAD=y"            >> ${S}/.config
  81         else
  82                 echo "# CONFIG_SA1100_SIMPAD_SINUSPAD is not set" >> ${S}/.config
  83         fi
  84         echo "CONFIG_CMDLINE=\"${CMDLINE} mem=${mem}M\"" >> ${S}/.config
  85         oe_runmake oldconfig
  86 }