org.handhelds.familiar/packages/linux-hotplug/linux-hotplug_20040920.bb

   1 DESCRIPTION = "This package contains the scripts necessary \
   2 for hotplug Linux support, and lets you plug in new devices \
   3 and use them immediately."
   4 HOMEPAGE = "http://linux-hotplug.sourceforge.net/"
   5 LICENSE = "GPL"
   6 RPROVIDES_${PN} = "hotplug"
   7 RCONFLICTS_${PN} = "hotplug"
   8 RREPLACES_${PN} = "hotplug"
   9 SECTION = "base"
  10 RSUGGESTS = "usbutils ${PN}-pci"
  11 RSUGGESTS_${PN}-pci = "pciutils"
  12 PR = "r9"
  13
  14 SRC_URI = "ftp://ftp.kernel.org/pub/linux/utils/kernel/hotplug/hotplug-2004_09_20.tar.gz \
  15         file://userspecified_hcd.patch;patch=1 \
  16         file://hotplug-net-agent-usb.patch;patch=1 \
  17         file://usbrc-busybox.patch;patch=1 \
  18         file://fix-net.agent \
  19         file://update-usb.usermap \
  20         file://logcheck-ignore \
  21         file://sleeve.agent \
  22         file://sleeve.rc \
  23         file://mmc.agent \
  24         file://usbd.agent \
  25         file://usbd \
  26         file://sysconfig-hotplug \
  27         file://sysconfig-usb \
  28         file://isapnp-exit.diff;patch=1 \
  29         file://usb-storage \
  30         file://soc.agent"
  31
  32 SRC_URI_append_openzaurus = " file://quiet-pci.patch;patch=1"
  33
  34 S = "${WORKDIR}/hotplug-2004_09_20"
  35
  36 INITSCRIPT_NAME = "hotplug"
  37 INITSCRIPT_PARAMS = "start 40 S . stop 89 0 6 ."
  38
  39 inherit update-rc.d
  40
  41 do_compile () {
  42         :
  43 }
  44
  45 PACKAGES =+ "${PN}-pci"
  46 FILES_${PN}-pci = "${sysconfdir}/hotplug/pci*"
  47
  48 oldmandir := "${mandir}"
  49 oldsbindir := "${sbindir}"
  50 prefix = ""
  51 exec_prefix = ""
  52 FILES_${PN} += "${oldsbindir}"
  53 FILES_${PN}-doc += "${oldmandir}"
  54
  55 export DEBFIX = "sed -e 's:sysconfig/usb:default/hotplug.usb:'"
  56 do_install () {
  57         install -d ${D}${sysconfdir}/logcheck/ignore.d
  58         install -d ${D}${oldmandir}
  59         install -d ${D}${oldsbindir}
  60         #install -d ${D}${sysconfdir}/default
  61         oe_runmake prefix=${D}${prefix} exec_prefix=${D}${exec_prefix} \
  62                    etcdir=${D}${sysconfdir} sbindir=${D}${sbindir} \
  63                    mandir=${D}${oldmandir} INSTALL=install install
  64         sh ${WORKDIR}/fix-net.agent ${D} || :
  65         install -m 0755 ${WORKDIR}/update-usb.usermap ${D}${oldsbindir}/
  66         install -m 0644 ${WORKDIR}/logcheck-ignore ${D}${sysconfdir}/logcheck/ignore.d/hotplug
  67         install -m 0755 ${WORKDIR}/sleeve.agent ${D}${sysconfdir}/hotplug/
  68         install -m 0755 ${WORKDIR}/sleeve.rc ${D}${sysconfdir}/hotplug/
  69         install -m 0755 ${WORKDIR}/mmc.agent ${D}${sysconfdir}/hotplug/
  70         install -m 0755 ${WORKDIR}/usbd.agent ${D}${sysconfdir}/hotplug/
  71         install -m 0755 ${WORKDIR}/soc.agent ${D}${sysconfdir}/hotplug/
  72         #install -m 0755 ${WORKDIR}/usbd ${D}${sysconfdir}/default/usbd
  73         install -d ${D}${sysconfdir}/sysconfig
  74         install -m 0644 ${WORKDIR}/sysconfig-hotplug ${D}${sysconfdir}/sysconfig/hotplug
  75         install -m 0644 ${WORKDIR}/sysconfig-usb ${D}${sysconfdir}/sysconfig/usb
  76         install -m 0755 ${WORKDIR}/usb-storage ${D}${sysconfdir}/hotplug/usb
  77 }