org.handhelds.familiar/packages/linux-libc-headers/linux-libc-headers_2.6.11.1.bb

   1 SECTION = "devel"
   2 DESCRIPTION = "Sanitized set of 2.6 kernel headers for the C library's use."
   3 HOMEPAGE = "http://ep09.pld-linux.org/~mmazur/linux-libc-headers/"
   4 # license note from the package:
   5 #   Linux-libc-headers are derived from linux kernel headers. For license of a
   6 #   particular header, check it's content, and if copyright notice isn't present,
   7 #   standard linux kernel license applies.
   8 # since we assume GPL for linux i think we can also assume it here
   9 LICENSE = "GPL"
  10 MAINTAINER = "Chris Larson <kergoth@handhelds.org>"
  11 INHIBIT_DEFAULT_DEPS = "1"
  12 PR = "r1"
  13
  14 SRC_URI = "http://ep09.pld-linux.org/~mmazur/linux-libc-headers/linux-libc-headers-${PV}.tar.bz2 \
  15         file://keyboard.patch;patch=1"
  16
  17 S = "${WORKDIR}/linux-libc-headers-${PV}"
  18
  19 do_configure () {
  20         case ${TARGET_ARCH} in
  21                 alpha*)   ARCH=alpha ;;
  22                 arm*)     ARCH=arm ;;
  23                 cris*)    ARCH=cris ;;
  24                 hppa*)    ARCH=parisc ;;
  25                 i*86*)    ARCH=i386 ;;
  26                 ia64*)    ARCH=ia64 ;;
  27                 mips*)    ARCH=mips ;;
  28                 m68k*)    ARCH=m68k ;;
  29                 powerpc*) ARCH=ppc ;;
  30                 s390*)    ARCH=s390 ;;
  31                 sh*)      ARCH=sh ;;
  32                 sparc64*) ARCH=sparc64 ;;
  33                 sparc*)   ARCH=sparc ;;
  34                 x86_64*)  ARCH=x86_64 ;;
  35         esac
  36         if test !  -e include/asm-$ARCH; then
  37                 oefatal unable to create asm symlink in kernel headers
  38         fi
  39         cp -pPR "include/asm-$ARCH" "include/asm"
  40         if test "$ARCH" = "arm"; then
  41                 cp -pPR include/asm/arch-ebsa285 include/asm/arch
  42         elif test "$ARCH" = "sh"; then
  43                 cp -pPR include/asm/cpu-${TARGET_ARCH} include/asm/cpu || die "unable to create include/asm/cpu"
  44         fi
  45 }
  46
  47 do_stage () {
  48         install -d ${STAGING_INCDIR}
  49         rm -rf ${STAGING_INCDIR}/linux ${STAGING_INCDIR}/asm
  50         cp -pfLR include/linux ${STAGING_INCDIR}/
  51         cp -pfLR include/asm ${STAGING_INCDIR}/
  52         rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/linux
  53         rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/asm
  54         install -d ${CROSS_DIR}/${TARGET_SYS}/include
  55         cp -pfLR include/linux ${CROSS_DIR}/${TARGET_SYS}/include/
  56         cp -pfLR include/asm ${CROSS_DIR}/${TARGET_SYS}/include/
  57 }
  58
  59 do_install() {
  60         install -d ${D}${includedir}
  61         cp -pfLR include/linux ${D}${includedir}/
  62         cp -pfLR include/asm ${D}${includedir}/
  63 }
  64