org.handhelds.familiar/packages/lsof/lsof_4.74.bb

   1 SECTION = "console/utils"
   2 DESCRIPTION = "Lsof is a Unix-specific diagnostic \
   3 tool. Its name stands for LiSt Open Files, and it \
   4 does just that."
   5 LICENSE = "BSD"
   6
   7 SRC_URI = "ftp://lsof.itap.purdue.edu/pub/tools/unix/lsof/OLD/lsof_${PV}.tar.bz2"
   8 LOCALSRC = "file://${WORKDIR}/lsof_${PV}/lsof_${PV}_src.tar"
   9 S = "${WORKDIR}/lsof_${PV}_src"
  10
  11 python do_unpack () {
  12         bb.build.exec_func('base_do_unpack', d)
  13         src_uri = bb.data.getVar('SRC_URI', d)
  14         bb.data.setVar('SRC_URI', '${LOCALSRC}', d)
  15         bb.build.exec_func('base_do_unpack', d)
  16         bb.data.setVar('SRC_URI', src_uri, d)
  17 }
  18
  19 LSOF_OS = "${TARGET_OS}"
  20 LSOF_OS_linux-uclibc = "linux"
  21
  22 do_configure () {
  23         ./Configure ${LSOF_OS}
  24 }
  25
  26 export I = "${STAGING_INCDIR}"
  27 export L = "${STAGING_INCDIR}"
  28 export EXTRA_OEMAKE = ""
  29
  30 do_compile () {
  31         oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS}'
  32 }
  33
  34 do_install () {
  35         install -d ${D}${sbindir} ${D}${mandir}/man8
  36         install -m 4755 lsof ${D}${sbindir}/lsof
  37         install -m 0644 lsof.8 ${D}${mandir}/man8/lsof.8
  38 }