org.handhelds.familiar/packages/ncurses/ncurses.inc

   1 DESCRIPTION = "Ncurses library"
   2 HOMEPAGE = "http://www.gnu.org/software/ncurses/ncurses.html"
   3 LICENSE = "MIT"
   4 SECTION = "libs"
   5 DEPENDS = "ncurses-native"
   6 PACKAGES_prepend = "ncurses-tools "
   7 PACKAGES_append = " ncurses-terminfo"
   8 FILES_ncurses_append = " ${datadir}/tabset"
   9 RSUGGESTS_${PN} = "ncurses-terminfo"
  10
  11 inherit autotools
  12
  13 # This keeps only tput/tset in ncurses
  14 # clear/reset are in already busybox
  15 FILES_ncurses-tools = "${bindir}/tic ${bindir}/toe ${bindir}/infotocap ${bindir}/captoinfo ${bindir}/infocmp ${bindir}/clear.${PN} ${bindir}/reset.${PN} ${bindir}/tack "
  16 FILES_ncurses-terminfo = "${datadir}/terminfo"
  17 FILES_${PN} = "${bindir}/tput ${bindir}/tset ${libdir}/lib*.so.* usr/share/tabset etc/terminfo"
  18
  19 PARALLEL_MAKE=""
  20
  21 EXTRA_OECONF = "--with-shared \
  22                 --without-profile \
  23                 --without-debug \
  24                 --disable-rpath \
  25                 --enable-echo \
  26                 --enable-const \
  27                 --without-ada \
  28                 --enable-termcap \
  29                 --without-cxx-binding \
  30                 --with-terminfo-dirs=${sysconfdir}/terminfo:${datadir}/terminfo \
  31                 --enable-overwrite"
  32 export BUILD_CCFLAGS = "-I${S}/ncurses -I${S}/include ${BUILD_CFLAGS}"
  33 export BUILD_LDFLAGS = ""
  34 export EXTRA_OEMAKE = '"BUILD_LDFLAGS=" "BUILD_CCFLAGS=${BUILD_CCFLAGS}"'
  35
  36 do_stage () {
  37         for i in libncurses libpanel libform libmenu; do
  38                 oe_libinstall -so -a -C lib $i ${STAGING_LIBDIR}
  39         done
  40         for h in ncurses_*.h curses.h eti.h form.h menu.h panel.h \
  41                 termcap.h term.h unctrl.h; do
  42                        install -m 0644 include/$h ${STAGING_INCDIR}/
  43         done
  44         ln -sf curses.h ${STAGING_INCDIR}/ncurses.h
  45         ln -sf libncurses.so ${STAGING_LIBDIR}/libtermcap.so
  46         ln -sf libncurses.a ${STAGING_LIBDIR}/libtermcap.a
  47 }
  48
  49 do_install() {
  50         autotools_do_install
  51
  52         # our ncurses has termcap support
  53         ln -sf libncurses.so ${D}${libdir}/libtermcap.so
  54         ln -sf libncurses.a ${D}${libdir}/libtermcap.a
  55
  56         # include some basic terminfo files
  57         # stolen ;) from gentoo and modified a bit
  58         for x in ansi console dumb linux rxvt screen sun vt{52,100,102,200,220} xterm-color xterm-xfree86
  59         do
  60                 local termfile="$(find "${D}${datadir}/terminfo/" -name "${x}" 2>/dev/null)"
  61                 local basedir="$(basename $(dirname "${termfile}"))"
  62
  63                 if [ -n "${termfile}" ]
  64                 then
  65                         install -d ${D}${sysconfdir}/terminfo/${basedir}
  66                         mv ${termfile} ${D}${sysconfdir}/terminfo/${basedir}/
  67                         ln -s /etc/terminfo/${basedir}/${x} \
  68                                 ${D}${datadir}/terminfo/${basedir}/${x}
  69                 fi
  70         done
  71         # i think we can use xterm-color as default xterm
  72         if [ -e ${D}${sysconfdir}/terminfo/x/xterm-color ]
  73         then
  74                 ln -sf xterm-color ${D}${sysconfdir}/terminfo/x/xterm
  75         fi
  76
  77         mv ${D}${bindir}/clear ${D}${bindir}/clear.${PN}
  78         mv ${D}${bindir}/reset ${D}${bindir}/reset.${PN}
  79 }
  80
  81
  82 pkg_postinst_ncurses-tools () {
  83         update-alternatives --install ${bindir}/clear clear clear.${PN} 100
  84         update-alternatives --install ${bindir}/reset reset reset.${PN} 100
  85 }
  86
  87
  88 pkg_prerm_ncurses-tools () {
  89         update-alternatives --remove clear clear.${PN}
  90         update-alternatives --remove reset reset.${PN}
  91 }