org.handhelds.familiar/packages/ntp/ntp_4.2.0.bb

   1 DESCRIPTION = "The Network Time Protocol (NTP) is used to \
   2 synchronize the time of a computer client or server to \
   3 another server or reference time source, such as a radio \
   4 or satellite receiver or modem."
   5 HOMEPAGE = "http://ntp.isc.org/bin/view/Main/WebHome"
   6 SECTION = "console/network"
   7 PRIORITY = "optional"
   8 LICENSE = "ntp"
   9 PR = "r7"
  10
  11 SRC_URI = "http://www.eecis.udel.edu/~ntp/ntp_spool/ntp4/${P}.tar.gz \
  12         file://ntpdc.Makefile.am.maybe-layout.patch;patch=1 \
  13         file://ipv6only-workaround.patch;patch=1 \
  14         file://ntpd \
  15         file://ntp.conf \
  16         file://ntpdate"
  17
  18
  19 INITSCRIPT_NAME = "ntpd"
  20 # No dependencies, so just go in at the standard level (20)
  21 INITSCRIPT_PARAMS = "defaults"
  22
  23 inherit autotools update-rc.d
  24
  25 # The ac_cv_header_readline_history is to stop ntpdc depending on either
  26 # readline or curses
  27 EXTRA_OECONF = "--without-openssl --without-crypto ac_cv_header_readline_history_h=no"
  28 CFLAGS_append = " -DPTYS_ARE_GETPT -DPTYS_ARE_SEARCHED"
  29
  30 PACKAGES = "ntpdate ntp-bin ntp ntp-tickadj"
  31 # NOTE: you don't need ntpdate, use "ntpdc -q -g -x"
  32 PROVIDES = "ntpdate-${PV} ntpdate-${PV}-${PR} ntpdate"
  33
  34 # This should use rc.update
  35 FILES_ntpdate = "${bindir}/ntpdate ${sysconfdir}/init.d/ntpdate"
  36 #This is too painful - perl is only needed for ntp-wait and ntptrace, which are
  37 #perl scripts, and installing perl is an enormous overhead for a user who only
  38 #needs ntpq
  39 #RDEPENDS_ntp-bin = perl
  40 # ntp originally includes tickadj. It's split off for inclusion in small firmware images on platforms
  41 # with wonky clocks (e.g. OpenSlug)
  42 RDEPENDS_${PN} = ${PN}-tickadj
  43 FILES_${PN}-bin = "${bindir}/ntp-wait ${bindir}/ntpdc ${bindir}/ntpq ${bindir}/ntptime ${bindir}/ntptrace"
  44 FILES_${PN} = "${bindir}/ntpd ${sysconfdir}/ntp.conf ${sysconfdir}/init.d/ntpd"
  45 FILES_${PN}-tickadj = "${bindir}/tickadj"
  46
  47 do_install_append() {
  48         install -d ${D}/${sysconfdir}/init.d
  49         install -m 644 ${WORKDIR}/ntp.conf ${D}/${sysconfdir}
  50         install -m 755 ${WORKDIR}/ntpdate ${D}/${sysconfdir}/init.d
  51         install -m 755 ${WORKDIR}/ntpd ${D}/${sysconfdir}/init.d
  52 }
  53
  54 pkg_postinst_ntpdate_nylon() {
  55 if test "x$D" != "x"; then
  56         exit 1
  57 else
  58         if ! grep -q ntpdate /etc/cron/crontabs/root; then
  59                 echo "adding crontab"
  60                 test -d /etc/cron/crontabs || mkdir -p /etc/cron/crontabs
  61                 echo "30 * * * *    /usr/bin/ntpdate -s -u pool.ntp.org" >> /etc/cron/crontabs/root
  62         fi
  63         update-rc.d -s busybox-cron defaults
  64         update-rc.d -s ntpdate defaults 30
  65 fi
  66 }