org.handhelds.familiar/packages/opie-networksettings/opie-networksettings.inc

   1 DESCRIPTION = "Opie Network Settings"
   2 SECTION = "opie/settings"
   3 PRIORITY = "optional"
   4 MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
   5 LICENSE = "GPL"
   6 PROVIDES = "opie-networksettings-pppplugin opie-networksettings-wlanplugin"
   7 APPNAME = "networksettings"
   8
   9 S = "${WORKDIR}/${APPNAME}"
  10
  11 inherit opie
  12
  13 PARALLEL_MAKE = ""
  14
  15 EXTRA_QMAKEVARS_POST += "LIBS+=-L${S}"
  16
  17 do_stage() {
  18         oe_libinstall -so libinterfaces ${STAGING_LIBDIR}
  19         install -d ${STAGING_INCDIR}/interfaces/
  20         install -m 0644 interfaces/*.h ${STAGING_INCDIR}/interfaces/
  21 }
  22
  23 do_install() {
  24         # Create dir for changedns and the opie-kppp peer
  25         install -d ${D}${bindir}/
  26         install -d ${D}${sysconfdir}/
  27         install -d ${D}${sysconfdir}/ppp/
  28         install -d ${D}${sysconfdir}/ppp/peers/
  29
  30         install -d ${D}${palmtopdir}/pics/${APPNAME}/
  31         install -d ${D}${palmtopdir}/pics/Network/
  32         install -m 0644 ${WORKDIR}/pics/${APPNAME}/*.* ${D}${palmtopdir}/pics/${APPNAME}/
  33         install -m 0644 ${WORKDIR}/pics/Network/*.* ${D}${palmtopdir}/pics/Network/
  34         install -d ${D}${palmtopdir}/lib/
  35         oe_libinstall -so libinterfaces ${D}${palmtopdir}/lib
  36         install -d ${D}${palmtopdir}/plugins/networksettings/
  37         for plugin in kppp wlan
  38         do
  39                 install lib$plugin.so ${D}${palmtopdir}/plugins/networksettings/
  40         done
  41
  42         # install changedns script
  43         install -m 0755 ${WORKDIR}/root${bindir}/changedns ${D}${bindir}/
  44         install -m 0644 ${WORKDIR}/root/etc/ppp/peers/opie-kppp ${D}${sysconfdir}/ppp/peers
  45 }
  46
  47 PACKAGES =+ "opie-networksettings-pppplugin opie-networksettings-wlanplugin"
  48 FILES_${PN} += " ${bindir}/changedns "
  49 FILES_opie-networksettings-pppplugin = "${palmtopdir}/plugins/networksettings/libkppp.so ${sysconfdir}/ppp/peers/opie-kppp"
  50 FILES_opie-networksettings-wlanplugin = "${palmtopdir}/plugins/networksettings/libwlan.so"
  51