org.handhelds.familiar/packages/pango/pango_1.10.0.bb

   1 LICENSE = "LGPL"
   2 SECTION = "x11/libs"
   3 # Xt needed to keep autoconf's check for X11 happy
   4 DEPENDS = "glib-2.0 fontconfig freetype zlib x11 libxft xt gtk-doc cairo"
   5 DESCRIPTION = "The goal of the Pango project is to provide an \
   6 Open Source framework for the layout and rendering of \
   7 internationalized text."
   8 PR = "r0"
   9
  10 # seems to go wrong with default cflags
  11 FULL_OPTIMIZATION_arm = "-O2"
  12
  13 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.8/pango-${PV}.tar.bz2 \
  14            file://no-tests.patch;patch=1"
  15
  16 inherit autotools pkgconfig
  17
  18 EXTRA_OECONF = "--disable-glibtest \
  19                 --enable-explicit-deps=no \
  20                 --disable-debug"
  21
  22 FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
  23
  24 LIBV = "1.4.0"
  25
  26 do_stage () {
  27         for lib in pango pangox pangoft2 pangoxft pangocairo; do
  28                 oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
  29         done
  30         install -d ${STAGING_INCDIR}/pango
  31         install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
  32 }
  33
  34 postinst_prologue() {
  35 if [ "x$D" != "x" ]; then
  36   exit 1
  37 fi
  38
  39 }
  40
  41 python populate_packages_prepend () {
  42         prologue = bb.data.getVar("postinst_prologue", d, 1)
  43
  44         modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
  45
  46         do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
  47 }