org.handhelds.familiar/packages/pango/pango_1.4.0.bb

   1 LICENSE = "LGPL"
   2 SECTION = "x11/libs"
   3 # Xt needed to keep autoconf's check for X11 happy
   4 DEPENDS = "glib-2.0 fontconfig freetype zlib x11 libxft xt"
   5 DESCRIPTION = "The goal of the Pango project is to provide an \
   6 Open Source framework for the layout and rendering of \
   7 internationalized text."
   8
   9 SRC_URI = "ftp://ftp.gtk.org/pub/gtk/v2.4/pango-${PV}.tar.bz2 \
  10            file://gtk-doc.patch;patch=1 \
  11            file://no-tests.patch;patch=1"
  12
  13 inherit autotools  pkgconfig
  14
  15 EXTRA_OECONF = "--disable-glibtest \
  16                 --enable-explicit-deps=no \
  17                 --disable-debug"
  18
  19 FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
  20
  21 LIBV = "1.4.0"
  22
  23 do_stage () {
  24         for lib in pango pangox pangoft2 pangoxft; do
  25                 oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
  26         done
  27         install -d ${STAGING_INCDIR}/pango
  28         install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
  29 }
  30
  31 python populate_packages_prepend () {
  32         modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
  33
  34         do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', 'pango-querymodules > /etc/pango/pango.modules')
  35 }