org.handhelds.familiar/packages/pcmcia-cs/pcmcia-cs_3.2.8.bb

   1 DESCRIPTION = "Utilities and system configuration files for the Linux PCMCIA card services"
   2 SECTION = "base"
   3 PRIORITY = "required"
   4 LICENSE = "GPL"
   5 DEPENDS = "virtual/kernel"
   6 PR = "r22"
   7
   8 SRC_URI = "${SOURCEFORGE_MIRROR}/pcmcia-cs/pcmcia-cs-${PV}.tar.gz \
   9            file://busybox.patch;patch=1 \
  10            file://network.patch;patch=1 \
  11            file://pcic-extra.patch;patch=1 \
  12            file://automount.patch;patch=1 \
  13            file://ratoc-cfu1u.patch;patch=1 \
  14            file://no-hostap-cards.patch;patch=1 \
  15            file://pcmcia \
  16            file://ide.opts \
  17            file://wireless.opts \
  18            file://network.conf \
  19            file://wnv.conf"
  20
  21 SRC_URI_append_spitz = " file://nocleanup.patch;patch=1"
  22 S = "${WORKDIR}/pcmcia-cs-${PV}"
  23
  24 INITSCRIPT_NAME = "pcmcia"
  25 INITSCRIPT_PARAMS = "defaults"
  26
  27 inherit update-rc.d module-base
  28
  29 export KERNEL_SOURCE = ${@base_read_file('${STAGING_KERNEL_DIR}/kernel-source')}
  30
  31 sbindir = "/sbin"
  32
  33 do_configure() {
  34         touch .prereq.ok
  35         touch config.out
  36         cat >config.mk <<EOF
  37 UCC=${CC}
  38 UFLAGS=${CFLAGS} -I${S}/include
  39 HAS_WORDEXP=y
  40 SYSV_INIT=y
  41 RC_DIR=/etc
  42 CONFIG_PNP_BIOS=n
  43 ARCH=${ARCH}
  44 CONFIG_CARDBUS=n
  45 CONFIG_PCMCIA=y
  46 CONFIG_INET=y
  47 CONFIG_SCSI=y
  48 DO_IDE=y
  49 EOF
  50         cat >include/pcmcia/autoconf.h <<EOF
  51 #define HAS_WORDEXP 1
  52 EOF
  53 }
  54
  55 do_compile() {
  56         oe_runmake all HAS_XPM= FLIBS="" XMANDIR=""
  57 }
  58
  59 INSTALL_ETC = "ftl ide ieee1394 memory network parport scsi serial wireless"
  60 INSTALL_ETC_DATA =     "config config.opts ftl.opts ieee1394.opts memory.opts network.opts parport.opts scsi.opts serial.opts shared"
  61 INSTALL_ETC_DATA_arm = "config             ftl.opts ieee1394.opts memory.opts network.opts parport.opts scsi.opts serial.opts shared"
  62
  63 do_install() {
  64         install -d ${D}${sbindir}
  65         for f in cardmgr/cardctl cardmgr/cardmgr cardmgr/ide_info cardmgr/ifport cardmgr/ifuser cardmgr/pcinitrd flash/ftl_check flash/ftl_format
  66         do
  67                 install -m 0755 $f ${D}${sbindir}/
  68         done
  69         install -d ${D}${sysconfdir}/init.d \
  70                    ${D}${sysconfdir}/pcmcia \
  71                    ${D}${sysconfdir}/pcmcia/cis
  72
  73         install -m 0644 ${WORKDIR}/network.conf ${D}${sysconfdir}/pcmcia/
  74         install -m 0644 ${WORKDIR}/wnv.conf ${D}${sysconfdir}/pcmcia/
  75
  76         for i in ${INSTALL_ETC}; do
  77                 install -m 0755 etc/${i} ${D}${sysconfdir}/pcmcia/
  78         done
  79         for i in ${INSTALL_ETC_DATA}; do
  80                 install -m 0644 etc/${i} ${D}${sysconfdir}/pcmcia/
  81         done
  82
  83         # ensure that config.opts always exists, albeit empty
  84         echo >> ${D}${sysconfdir}/pcmcia/config.opts
  85
  86         install -m 0644 ${WORKDIR}/ide.opts ${D}${sysconfdir}/pcmcia/
  87         install -m 0644 ${WORKDIR}/wireless.opts ${D}${sysconfdir}/pcmcia/
  88         for i in etc/cis/*; do
  89                 install -m 0644 $i ${D}${sysconfdir}/pcmcia/cis/
  90         done
  91         install -m 0755 etc/rc.pcmcia ${D}${sysconfdir}/init.d/pcmcia
  92         install -d ${D}${sysconfdir}/sysconfig
  93         install -m 0755 ${WORKDIR}/pcmcia ${D}${sysconfdir}/sysconfig/pcmcia
  94 }
  95
  96 PACKAGES =+ "${PN}-ftl ${PN}-pcinitrd"
  97
  98 FILES_${PN} = "${sbindir} ${sysconfdir}"
  99 FILES_${PN}-ftl = "/sbin/ftl_format /sbin/ftl_check /etc/pcmcia/ftl*"
 100 FILES_${PN}-pcinitrd = "/sbin/pcinitrd"
 101