org.handhelds.familiar/packages/tcltk/tcl_8.4.11.bb

   1 DESCRIPTION = "Tool Command Language"
   2 LICENSE = "tcl"
   3 SECTION = "devel/tcltk"
   4 HOMEPAGE = "http://tcl.sourceforge.net"
   5 PR = "r2"
   6
   7 SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/tcl${PV}-src.tar.gz \
   8            file://tcl-add-soname.patch;patch=1"
   9 S = "${WORKDIR}/tcl${PV}/unix"
  10
  11 inherit autotools
  12
  13 EXTRA_OECONF = "--enable-threads"
  14
  15 do_configure() {
  16         gnu-configize
  17         oe_runconf
  18 }
  19
  20 do_compile_prepend() {
  21         echo > ../compat/fixstrtod.c
  22 }
  23
  24 do_stage() {
  25         oe_libinstall -a libtclstub8.4 ${STAGING_LIBDIR}
  26         oe_libinstall -so libtcl8.4 ${STAGING_LIBDIR}
  27         install -m 0755 tclConfig.sh ${STAGING_BINDIR}
  28         cd ..
  29         for dir in compat generic unix
  30         do
  31                 install -d ${STAGING_INCDIR}/tcl${PV}/$dir
  32                 install -m 0644 $dir/*.h ${STAGING_INCDIR}/tcl${PV}/$dir/
  33         done
  34         install -m 0644 generic/tcl.h ${STAGING_INCDIR}
  35         install -m 0644 generic/tclDecls.h ${STAGING_INCDIR}
  36         install -m 0644 generic/tclPlatDecls.h ${STAGING_INCDIR}
  37 }
  38
  39 do_install() {
  40         autotools_do_install
  41         oe_libinstall -so libtcl8.4 ${D}${libdir}
  42         ln -sf ./tclsh8.4 ${D}${bindir}/tclsh
  43 }
  44
  45 FILES_${PN} += "${libdir}/tcl8.4 ${libdir}/libtcl8.4.so"