org.handhelds.familiar/packages/wireless-tools/wireless-tools_27.bb

   1 DESCRIPTION = "Tools for the Linux Standard Wireless Extension Subsystem"
   2 HOMEPAGE = "http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/Tools.html"
   3 SECTION = "base"
   4 PRIORITY = "optional"
   5 #DEPENDS = "virtual/kernel"
   6 MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
   7 LICENSE = "GPL"
   8 PR = "r1"
   9
  10 SRC_URI = "http://pcmcia-cs.sourceforge.net/ftp/contrib/wireless_tools.${PV}.tar.gz \
  11            file://man.patch;patch=1 \
  12            file://fixheaders.patch;patch=1 \
  13            file://wireless-tools.if-pre-up"
  14 S = "${WORKDIR}/wireless_tools.${PV}"
  15
  16 CFLAGS =+ "-I${S}"
  17 EXTRA_OEMAKE = "-e 'BUILD_SHARED=y' \
  18                 'INSTALL_DIR=${D}${base_sbindir}' \
  19                 'INSTALL_LIB=${D}${libdir}' \
  20                 'INSTALL_INC=${D}${includedir}' \
  21                 'INSTALL_MAN=${D}${mandir}'"
  22
  23 do_compile() {
  24         oe_runmake all libiw.a
  25 }
  26
  27 do_stage () {
  28         install -m 0644 wireless.h ${STAGING_INCDIR}/
  29         install -m 0644 iwlib.h ${STAGING_INCDIR}/
  30         oe_libinstall -a -so libiw ${STAGING_LIBDIR}/
  31 }
  32
  33 do_install() {
  34         oe_runmake PREFIX=${D} install install-static
  35         install -d ${D}${sysconfdir}/network/if-pre-up.d
  36         install ${WORKDIR}/wireless-tools.if-pre-up ${D}${sysconfdir}/network/if-pre-up.d/wireless-tools
  37 }
  38
  39 PACKAGES = "libiw libiw-dev libiw-doc ${PN} ${PN}-doc"
  40 FILES_libiw = "${libdir}/*.so.*"
  41 FILES_libiw-dev = "${libdir}/*.a ${libdir}/*.so ${includedir}"
  42 FILES_libiw-doc = "${mandir}/man7"
  43 FILES_${PN} = "${bindir} ${sbindir} ${base_sbindir} ${base_bindir} ${sysconfdir}/network"
  44 FILES_${PN}-doc = "${mandir}/man8"