org.handhelds.familiar/packages/wireless-tools/wireless-tools_28-pre13.bb

   1 DESCRIPTION = "Tools for the Linux Standard Wireless Extension Subsystem"
   2 HOMEPAGE = "http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/Tools.html"
   3 SECTION = "base"
   4 PRIORITY = "optional"
   5 MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
   6 LICENSE = "GPL"
   7 PR = "r0"
   8
   9 SRC_URI = "http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/wireless_tools.28.pre13.tar.gz \
  10            file://man.patch;patch=1 \
  11            file://wireless-tools.if-pre-up"
  12 S = "${WORKDIR}/wireless_tools.28"
  13
  14 CFLAGS =+ "-I${S}"
  15 EXTRA_OEMAKE = "-e 'BUILD_SHARED=y' \
  16                 'INSTALL_DIR=${D}${base_sbindir}' \
  17                 'INSTALL_LIB=${D}${libdir}' \
  18                 'INSTALL_INC=${D}${includedir}' \
  19                 'INSTALL_MAN=${D}${mandir}'"
  20
  21 do_compile() {
  22         oe_runmake all libiw.a
  23 }
  24
  25 do_stage() {
  26         install -m 0644 wireless.h ${STAGING_INCDIR}/
  27         install -m 0644 iwlib.h ${STAGING_INCDIR}/
  28         oe_libinstall -a -so libiw ${STAGING_LIBDIR}/
  29 }
  30
  31 do_install() {
  32         oe_runmake PREFIX=${D} install-iwmulticall install-dynamic
  33         install -d ${D}${sysconfdir}/network/if-pre-up.d
  34         install ${WORKDIR}/wireless-tools.if-pre-up ${D}${sysconfdir}/network/if-pre-up.d/wireless-tools
  35 }
  36
  37 PACKAGES = "libiw libiw-dev libiw-doc ${PN} ${PN}-doc"
  38 FILES_libiw = "${libdir}/*.so.*"
  39 FILES_libiw-dev = "${libdir}/*.a ${libdir}/*.so ${includedir}"
  40 FILES_libiw-doc = "${mandir}/man7"
  41 FILES_${PN} = "${bindir} ${sbindir} ${base_sbindir} ${base_bindir} ${sysconfdir}/network"
  42 FILES_${PN}-doc = "${mandir}/man8"