org.handhelds.familiar/packages/xinetd/xinetd_2.3.13.bb

   1 DEPENDS = ""
   2 DESCRIPTION = "Highly configurable, modular and secure inetd"
   3 MAINTAINER = "NSLU2 Linux <nslu2-linux@yahoogroups.com>"
   4 PR="r2"
   5
   6 SRC_URI = "http://www.xinetd.org/xinetd-${PV}.tar.gz \
   7           file://xinetd.init \
   8           file://xinetd.conf \
   9           "
  10
  11 EXTRA_OECONF="--disable-nls"
  12
  13 inherit autotools update-rc.d
  14
  15 INITSCRIPT_NAME = "xinetd"
  16 INITSCRIPT_PARAMS = "defaults"
  17
  18 do_configure() {
  19         # Looks like configure.in is broken, so we are skipping
  20         # rebuilding configure and are just using the shipped one
  21         oe_runconf
  22 }
  23
  24 do_install() {
  25         # Same here, the Makefile does some really stupid things,
  26         # but since we only want two files why not override
  27         # do_install from autotools and doing it ourselfs?
  28         install -d "${D}/usr/sbin"
  29         install -d "${D}/etc/init.d"
  30         install -d "${D}/etc/xinetd.d"
  31         install -m 644 "${WORKDIR}/xinetd.conf" "${D}/etc"
  32         install -m 755 "${WORKDIR}/xinetd.init" "${D}/etc/init.d/xinetd"
  33         install -m 755 "${S}/xinetd/xinetd" "${D}/usr/sbin"
  34         install -m 755 "${S}/xinetd/itox" "${D}/usr/sbin"
  35
  36 }
  37
  38 CONFFILES_${PN} = "${sysconfdir}/xinetd.conf"