arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10
  11 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  12 OUTPUT_ARCH(i386)
  13 ENTRY(phys_startup_32)
  14 jiffies = jiffies_64;
  15 SECTIONS
  16 {
  17   . = __KERNEL_START;
  18   phys_startup_32 = startup_32 - LOAD_OFFSET;
  19   /* read-only */
  20   _text = .;                    /* Text and read-only data */
  21   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  22         *(.text)
  23         SCHED_TEXT
  24         LOCK_TEXT
  25         KPROBES_TEXT
  26         *(.fixup)
  27         *(.gnu.warning)
  28         } = 0x9090
  29
  30   _etext = .;                   /* End of text section */
  31
  32   . = ALIGN(16);                /* Exception table */
  33   __start___ex_table = .;
  34   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  35   __stop___ex_table = .;
  36
  37   RODATA
  38
  39   /* writeable */
  40   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  41         *(.data)
  42         CONSTRUCTORS
  43         }
  44
  45   . = ALIGN(4096);
  46   __nosave_begin = .;
  47   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  48   . = ALIGN(4096);
  49   __nosave_end = .;
  50
  51   . = ALIGN(4096);
  52   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  53         *(.data.idt)
  54   }
  55
  56   . = ALIGN(32);
  57   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  58         *(.data.cacheline_aligned)
  59   }
  60
  61   /* rarely changed data like cpu maps */
  62   . = ALIGN(32);
  63   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  64   _edata = .;                   /* End of data section */
  65
  66   . = ALIGN(THREAD_SIZE);       /* init_task */
  67   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  68         *(.data.init_task)
  69   }
  70
  71   /* might get freed after init */
  72   . = ALIGN(4096);
  73   __smp_alt_begin = .;
  74   __smp_alt_instructions = .;
  75   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
  76         *(.smp_altinstructions)
  77   }
  78   __smp_alt_instructions_end = .;
  79   . = ALIGN(4);
  80   __smp_locks = .;
  81   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
  82         *(.smp_locks)
  83   }
  84   __smp_locks_end = .;
  85   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
  86         *(.smp_altinstr_replacement)
  87   }
  88   . = ALIGN(4096);
  89   __smp_alt_end = .;
  90
  91   /* will be freed after init */
  92   . = ALIGN(4096);              /* Init code and data */
  93   __init_begin = .;
  94   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  95         _sinittext = .;
  96         *(.init.text)
  97         _einittext = .;
  98   }
  99   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 100   . = ALIGN(16);
 101   __setup_start = .;
 102   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 103   __setup_end = .;
 104   __initcall_start = .;
 105   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 106         *(.initcall1.init)
 107         *(.initcall2.init)
 108         *(.initcall3.init)
 109         *(.initcall4.init)
 110         *(.initcall5.init)
 111         *(.initcall6.init)
 112         *(.initcall7.init)
 113   }
 114   __initcall_end = .;
 115   __con_initcall_start = .;
 116   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 117         *(.con_initcall.init)
 118   }
 119   __con_initcall_end = .;
 120   SECURITY_INIT
 121   . = ALIGN(4);
 122   __alt_instructions = .;
 123   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 124         *(.altinstructions)
 125   }
 126   __alt_instructions_end = .;
 127   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 128         *(.altinstr_replacement)
 129   }
 130   /* .exit.text is discard at runtime, not link time, to deal with references
 131      from .altinstructions and .eh_frame */
 132   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 133   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 134   . = ALIGN(4096);
 135   __initramfs_start = .;
 136   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 137   __initramfs_end = .;
 138   . = ALIGN(32);
 139   __per_cpu_start = .;
 140   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 141   __per_cpu_end = .;
 142   . = ALIGN(4096);
 143   __init_end = .;
 144   /* freed after init ends here */
 145
 146   __bss_start = .;              /* BSS */
 147   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 148         *(.bss.page_aligned)
 149   }
 150   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 151         *(.bss)
 152   }
 153   . = ALIGN(4);
 154   __bss_stop = .;
 155
 156   _end = . ;
 157
 158   /* This is where the kernel creates the early boot page tables */
 159   . = ALIGN(4096);
 160   pg0 = .;
 161
 162   /* Sections to be discarded */
 163   /DISCARD/ : {
 164         *(.exitcall.exit)
 165         }
 166
 167   STABS_DEBUG
 168
 169   DWARF_DEBUG
 170 }