org.handhelds.familiar/classes/kernel.bbclass

   1 inherit module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 inherit kernel-arch
   7
   8 export OS = "${TARGET_OS}"
   9 export CROSS_COMPILE = "${TARGET_PREFIX}"
  10 KERNEL_IMAGETYPE = "zImage"
  11
  12 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  13
  14 KERNEL_CCSUFFIX ?= ""
  15 KERNEL_LDSUFFIX ?= ""
  16
  17 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX}"
  18 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX}"
  19
  20 KERNEL_OUTPUT = "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  21 KERNEL_IMAGEDEST = "boot"
  22
  23 #
  24 # configuration
  25 #
  26 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  27
  28 # parse kernel ABI version out of <linux/version.h>
  29 def get_kernelversion(p):
  30         import re
  31         try:
  32                 f = open(p, 'r')
  33         except IOError:
  34                 return None
  35         l = f.readlines()
  36         f.close()
  37         r = re.compile("#define UTS_RELEASE \"(.*)\"")
  38         for s in l:
  39                 m = r.match(s)
  40                 if m:
  41                         return m.group(1)
  42         return None
  43
  44 def get_kernelmajorversion(p):
  45         import re
  46         r = re.compile("([0-9]+\.[0-9]+).*")
  47         m = r.match(p);
  48         if m:
  49                 return m.group(1)
  50         return None
  51
  52 KERNEL_VERSION = "${@get_kernelversion('${S}/include/linux/version.h')}"
  53 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  54
  55 # kernels are generally machine specific
  56 PACKAGE_ARCH = "${MACHINE_ARCH}"
  57
  58 kernel_do_compile() {
  59         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  60         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  61         oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  62         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  63         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  64                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  65         else
  66                 oenote "no modules to compile"
  67         fi
  68 }
  69
  70 kernel_do_stage() {
  71         ASMDIR=`readlink include/asm`
  72
  73         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  74         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
  75         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
  76
  77         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
  78         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
  79
  80         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
  81         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
  82
  83         mkdir -p ${STAGING_KERNEL_DIR}/include/net
  84         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
  85
  86         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
  87         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
  88
  89         if [ -d drivers/sound ]; then
  90                 # 2.4 alsa needs some headers from this directory
  91                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
  92                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
  93         fi
  94
  95         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
  96         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
  97         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
  98         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
  99         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 100         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 101         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 102         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 103         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 104
 105         # Check if arch/${ARCH}/Makefile exists and install it
 106         if [ -e arch/${ARCH}/Makefile ]; then
 107                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 108                 install -m 0644 arch/${ARCH}/Makefile ${STAGING_KERNEL_DIR}/arch/${ARCH}
 109         fi
 110         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 111         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 112         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 113         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 114
 115         cp -fR scripts ${STAGING_KERNEL_DIR}/
 116 }
 117
 118 kernel_do_install() {
 119         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
 120         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 121                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 122         else
 123                 oenote "no modules to install"
 124         fi
 125
 126         install -d ${D}/${KERNEL_IMAGEDEST}
 127         install -d ${D}/boot
 128         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 129         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 130         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 131         install -d ${D}/etc/modutils
 132
 133         # Check if scripts/genksyms exists and if so, build it
 134         if [ -e scripts/genksyms/ ]; then
 135                 oe_runmake SUBDIRS="scripts/genksyms"
 136         fi
 137
 138         cp -fR scripts ${STAGING_KERNEL_DIR}/
 139 }
 140
 141 kernel_do_configure() {
 142         yes '' | oe_runmake oldconfig
 143 }
 144
 145 pkg_postinst_kernel () {
 146         update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 147 }
 148
 149 pkg_postrm_kernel () {
 150         update-alternatives --remove ${KERNEL_IMAGETYPE} /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 151 }
 152
 153 inherit cml1
 154
 155 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 156
 157 PACKAGES = "kernel kernel-image kernel-dev"
 158 FILES = ""
 159 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 160 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 161 RDEPENDS_kernel = "kernel-image-${KERNEL_MAJOR_VERSION}"
 162 PKG_kernel-image = "kernel-image-${KERNEL_MAJOR_VERSION}"
 163 RPROVIDES_kernel-image = "kernel-image-${KERNEL_VERSION}"
 164 RCONFLICTS_kernel-image = "kernel-image-${KERNEL_VERSION}"
 165 RREPLACES_kernel-image = "kernel-image-${KERNEL_VERSION}"
 166 ALLOW_EMPTY_kernel = "1"
 167 ALLOW_EMPTY_kernel-image = "1"
 168
 169 pkg_postinst_modules () {
 170 if [ -n "$D" ]; then
 171         ${HOST_PREFIX}depmod -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 172 else
 173         depmod -A
 174         update-modules || true
 175 fi
 176 }
 177
 178 pkg_postrm_modules () {
 179 update-modules || true
 180 }
 181
 182 autoload_postinst_fragment() {
 183 if [ x"$D" = "x" ]; then
 184         modprobe %s || true
 185 fi
 186 }
 187
 188 # autoload defaults (alphabetically sorted)
 189 module_autoload_evdev = "evdev"
 190 module_autoload_hidp = "hidp"
 191 module_autoload_ipv6 = "ipv6"
 192 module_autoload_ipsec = "ipsec"
 193 module_autoload_ircomm-tty = "ircomm-tty"
 194 module_autoload_rfcomm = "rfcomm"
 195 module_autoload_sa1100-rtc = "sa1100-rtc"
 196
 197 # alias defaults (alphabetically sorted)
 198 module_conf_af_packet = "alias net-pf-17 af_packet"
 199 module_conf_bluez = "alias net-pf-31 bluez"
 200 module_conf_bnep = "alias bt-proto-4 bnep"
 201 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 202 module_conf_l2cap = "alias bt-proto-0 l2cap"
 203 module_conf_sco = "alias bt-proto-2 sco"
 204 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 205
 206 python populate_packages_prepend () {
 207         def extract_modinfo(file):
 208                 import os, re
 209                 tmpfile = os.tmpnam()
 210                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 211                 os.system(cmd)
 212                 f = open(tmpfile)
 213                 l = f.read().split("\000")
 214                 f.close()
 215                 os.unlink(tmpfile)
 216                 exp = re.compile("([^=]+)=(.*)")
 217                 vals = {}
 218                 for i in l:
 219                         m = exp.match(i)
 220                         if not m:
 221                                 continue
 222                         vals[m.group(1)] = m.group(2)
 223                 return vals
 224
 225         def parse_depmod():
 226                 import os, re
 227
 228                 dvar = bb.data.getVar('D', d, 1)
 229                 if not dvar:
 230                         bb.error("D not defined")
 231                         return
 232
 233                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 234                 kernelver_stripped = kernelver
 235                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 236                 if m and not bb.data.getVar('KERNEL_PRESERVE_HH_MINOR_VER', d, 1):
 237                         kernelver_stripped = m.group(1)
 238                 path = bb.data.getVar("PATH", d, 1)
 239                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 240
 241                 cmd = "PATH=\"%s\" %sdepmod -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, dvar, dvar, kernelver, kernelver_stripped)
 242                 bb.debug (1, cmd)
 243                 f = os.popen(cmd, 'r')
 244
 245                 deps = {}
 246                 pattern0 = "^(.*\.k?o):..*$"
 247                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 248                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 249                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 250                 pattern4 = "^\t(.*\.k?o)\s*$"
 251
 252                 line = f.readline()
 253                 while line:
 254                         if not re.match(pattern0, line):
 255                                 line = f.readline()
 256                                 continue
 257                         m1 = re.match(pattern1, line)
 258                         if m1:
 259                                 deps[m1.group(1)] = m1.group(2).split()
 260                         else:
 261                                 m2 = re.match(pattern2, line)
 262                                 if m2:
 263                                         deps[m2.group(1)] = m2.group(2).split()
 264                                         line = f.readline()
 265                                         m3 = re.match(pattern3, line)
 266                                         while m3:
 267                                                 deps[m2.group(1)].extend(m3.group(1).split())
 268                                                 line = f.readline()
 269                                                 m3 = re.match(pattern3, line)
 270                                         m4 = re.match(pattern4, line)
 271                                         deps[m2.group(1)].extend(m4.group(1).split())
 272                         line = f.readline()
 273                 if f.close() or not deps:
 274                         # depmod returned an error or no deps found (very unlikely)
 275                         raise bb.build.FuncFailed("Failed to extract module dependencies.")
 276                 return deps
 277
 278         def get_dependencies(file, pattern, format):
 279                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 280
 281                 if module_deps.has_key(file):
 282                         import os.path, re
 283                         dependencies = []
 284                         for i in module_deps[file]:
 285                                 m = re.match(pattern, os.path.basename(i))
 286                                 if not m:
 287                                         continue
 288                                 on = legitimize_package_name(m.group(1))
 289                                 dependency_pkg = format % on
 290                                 v = bb.data.getVar("PARALLEL_INSTALL_MODULES", d, 1) or "0"
 291                                 if v == "1":
 292                                         kv = bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1)
 293                                         dependency_pkg = "%s-%s" % (dependency_pkg, kv)
 294                                 dependencies.append(dependency_pkg)
 295                         return dependencies
 296                 return []
 297
 298         def frob_metadata(file, pkg, pattern, format, basename):
 299                 import re
 300                 vals = extract_modinfo(file)
 301
 302                 dvar = bb.data.getVar('D', d, 1)
 303
 304                 # If autoloading is requested, output /etc/modutils/<name> and append
 305                 # appropriate modprobe commands to the postinst
 306                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 307                 if autoload:
 308                         name = '%s/etc/modutils/%s' % (dvar, basename)
 309                         f = open(name, 'w')
 310                         for m in autoload.split():
 311                                 f.write('%s\n' % m)
 312                         f.close()
 313                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 314                         if not postinst:
 315                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 316                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 317                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 318
 319                 # Write out any modconf fragment
 320                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 321                 if modconf:
 322                         name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 323                         f = open(name, 'w')
 324                         f.write("%s\n" % modconf)
 325                         f.close()
 326
 327                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 328                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf" % (files, basename, basename)
 329                 bb.data.setVar('FILES_%s' % pkg, files, d)
 330
 331                 if vals.has_key("description"):
 332                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 333                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 334
 335                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 336                 if rdepends_str:
 337                         rdepends = rdepends_str.split()
 338                 else:
 339                         rdepends = []
 340                 rdepends.extend(get_dependencies(file, pattern, format))
 341                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 342
 343         module_deps = parse_depmod()
 344         module_regex = '^(.*)\.k?o$'
 345         module_pattern = 'kernel-module-%s'
 346
 347         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 348         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 349         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-image-%s' % bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1))
 350
 351         import re, os
 352         metapkg = "kernel-modules"
 353         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 354         bb.data.setVar('FILES_' + metapkg, "", d)
 355         blacklist = [ 'kernel-dev', 'kernel-image' ]
 356         for l in module_deps.values():
 357                 for i in l:
 358                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 359                         blacklist.append(pkg)
 360         metapkg_rdepends = []
 361         packages = bb.data.getVar('PACKAGES', d, 1).split()
 362         for pkg in packages[1:]:
 363                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 364                         metapkg_rdepends.append(pkg)
 365         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 366         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 367         packages.append(metapkg)
 368         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 369
 370         v = bb.data.getVar("PARALLEL_INSTALL_MODULES", d, 1) or "0"
 371         if v == "1":
 372                 kv = bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1)
 373                 packages = bb.data.getVar("PACKAGES", d, 1)
 374                 module_re = re.compile("^kernel-module-")
 375                 repl_vers = bb.data.getVar("PARALLEL_INSTALL_REPLACE_VERSIONS", d, 1)
 376                 for p in packages.split():
 377                         if not module_re.match(p):
 378                                 continue
 379                         pkg = bb.data.getVar("PKG_%s" % p, d, 1) or p
 380                         newpkg = "%s-%s" % (pkg, kv)
 381                         bb.data.setVar("PKG_%s" % p, newpkg, d)
 382                         rprovides = bb.data.getVar("RPROVIDES_%s" % p, d, 1)
 383                         if rprovides:
 384                                 rprovides = "%s %s" % (rprovides, pkg)
 385                         else:
 386                                 rprovides = pkg
 387                         bb.data.setVar("RPROVIDES_%s" % p, rprovides, d)
 388
 389                         # kv was changed from KERNEL_VERSION to KERNEL_MAJOR_VERSION.
 390                         # now fix the upgrade path...
 391                         if repl_vers:
 392                                 repl_pkgs = []
 393                                 for v in repl_vers.split():
 394                                         repl_pkgs.append("%s-%s" % (pkg, v))
 395                                 for i in ["PROVIDES", "CONFLICTS", "REPLACES"]:
 396                                         val = bb.data.getVar("R%s_%s" % (i, p), d, 1)
 397                                         if val:
 398                                                 old = val.split()
 399                                                 add = []
 400                                                 for k in repl_pkgs:
 401                                                         if not k in old:
 402                                                                 add.append(k)
 403                                                 val = "%s %s" % (val, " ".join(add))
 404                                         else:
 405                                                 val = "%s" % " ".join(repl_pkgs)
 406                                         bb.data.setVar("R%s_%s" % (i, p), val, d)
 407                 if repl_vers:
 408                         p = "kernel-image"
 409                         repl_pkgs = []
 410                         for v in repl_vers.split():
 411                                 repl_pkgs.append("%s-%s" % (p, v))
 412                         for i in ["PROVIDES", "CONFLICTS", "REPLACES"]:
 413                                 val = bb.data.getVar("R%s_%s" % (i, p), d, 1)
 414                                 if val:
 415                                         old = val.split()
 416                                         add = []
 417                                         for k in repl_pkgs:
 418                                                 if not k in old:
 419                                                         add.append(k)
 420                                         val = "%s %s" % (val, " ".join(add))
 421                                 else:
 422                                         val = "%s" % " ".join(repl_pkgs)
 423                                 bb.data.setVar("R%s_%s" % (i, p), val, d)
 424 }