org.handhelds.familiar/packages/gnutls/gnutls_1.4.4.bb

   1 DESCRIPTION = "GNU Transport Layer Security Library"
   2 DEPENDS = "zlib libgcrypt lzo"
   3 HOMEPAGE = "http://www.gnu.org/software/gnutls/"
   4 LICENSE = "LGPL"
   5
   6 SRC_URI = "ftp://ftp.gnutls.org/pub/gnutls/gnutls-${PV}.tar.bz2 \
   7            file://gnutls-openssl.patch;patch=1 \
   8            file://gnutls-texinfo-euro.patch;patch=1"
   9
  10 inherit autotools binconfig pkgconfig
  11
  12 PACKAGES =+ "${PN}-openssl ${PN}-extra ${PN}-bin"
  13 FILES_${PN}-openssl = "${libdir}/libgnutls-openssl.so.*"
  14 FILES_${PN}-extra = "${libdir}/libgnutls-extra.so.*"
  15 FILES_${PN} = "${libdir}/libgnutls.so.*"
  16 FILES_${PN}-bin = "${bindir}/gnutls-serv \
  17         ${bindir}/gnutls-cli \
  18         ${bindir}/srptool \
  19         ${bindir}/certtool \
  20         ${bindir}/gnutls-srpcrypt \
  21         ${bindir}/psktool"
  22
  23 FILES_${PN}-dev += "${bindir}/*-config ${bindir}/gnutls-cli-debug"
  24
  25 EXTRA_OECONF="--with-included-opencdk --with-included-libtasn1"
  26
  27 do_stage() {
  28         autotools_stage_includes
  29         oe_libinstall -C lib/.libs -so -a libgnutls ${STAGING_LIBDIR}
  30         oe_libinstall -C libextra/.libs -so -a libgnutls-extra ${STAGING_LIBDIR}
  31         oe_libinstall -C libextra/.libs -so -a libgnutls-openssl ${STAGING_LIBDIR}
  32
  33         install -d ${STAGING_DATADIR}/aclocal
  34         cp ${S}/lib/libgnutls.m4 ${STAGING_DATADIR}/aclocal/
  35 }
  36