org.handhelds.familiar/packages/gnutls/gnutls_1.4.4.bb

   1 DESCRIPTION = "GNU Transport Layer Security Library"
   2 DEPENDS = "zlib libgcrypt lzo"
   3 HOMEPAGE = "http://www.gnu.org/software/gnutls/"
   4 LICENSE = "LGPL"
   5 PR = "r1"
   6
   7 SRC_URI = "ftp://ftp.gnutls.org/pub/gnutls/gnutls-${PV}.tar.bz2 \
   8            file://onceonly.m4 \
   9            file://gnutls-openssl.patch;patch=1 \
  10            file://gnutls-texinfo-euro.patch;patch=1"
  11
  12 inherit autotools binconfig pkgconfig
  13
  14 do_configure() {
  15         cp ${WORKDIR}/onceonly.m4 ${S}/m4/
  16         autotools_do_configure
  17 }
  18
  19 PACKAGES =+ "${PN}-openssl ${PN}-extra ${PN}-bin"
  20 FILES_${PN}-openssl = "${libdir}/libgnutls-openssl.so.*"
  21 FILES_${PN}-extra = "${libdir}/libgnutls-extra.so.*"
  22 FILES_${PN} = "${libdir}/libgnutls.so.*"
  23 FILES_${PN}-bin = "${bindir}/gnutls-serv \
  24         ${bindir}/gnutls-cli \
  25         ${bindir}/srptool \
  26         ${bindir}/certtool \
  27         ${bindir}/gnutls-srpcrypt \
  28         ${bindir}/psktool"
  29
  30 FILES_${PN}-dev += "${bindir}/*-config ${bindir}/gnutls-cli-debug"
  31
  32 EXTRA_OECONF="--with-included-opencdk --with-included-libtasn1"
  33
  34 do_stage() {
  35         autotools_stage_includes
  36         oe_libinstall -C lib/.libs -so -a libgnutls ${STAGING_LIBDIR}
  37         oe_libinstall -C libextra/.libs -so -a libgnutls-extra ${STAGING_LIBDIR}
  38         oe_libinstall -C libextra/.libs -so -a libgnutls-openssl ${STAGING_LIBDIR}
  39
  40         install -d ${STAGING_DATADIR}/aclocal
  41         cp ${S}/lib/libgnutls.m4 ${STAGING_DATADIR}/aclocal/
  42 }
  43